?? NEWTITLE := 'NOS/VE :  ADVANCED ACCESS METHOD, RING 4DD' ??
MODULE amm$create_key_definition;
?? RIGHT := 110 ??

*copyc amh$also

?? NEWTITLE := 'Global Declarations Referenced By This Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc amc$condition_code_limits
*copyc ame$improper_file_id
*copyc amt$call_block
*copyc amt$fap_layer_number
*copyc amt$fap_pointer
?? POP ??
*copyc baf$task_file_entry_p
*copyc osp$set_status_abnormal
?? OLDTITLE ??
?? NEWTITLE := '  [XDCL] AMP$CREATE_KEY_DEFINITION', EJECT ??

  PROCEDURE [XDCL, #GATE] amp$create_key_definition
    (    file_identifier: amt$file_identifier;
         key_name: amt$key_name;
         key_position: amt$key_position;
         key_length: amt$key_length;
         optional_attributes: ^amt$optional_key_attributes;
     VAR status: ost$status);

    CONST
      interface_name = 'AMP$CREATE_KEY_DEFINITION',
      fap_layer_number = 0;

    VAR
      call_block: amt$call_block,
      file_instance_p: ^bat$task_file_entry;

    status.normal := TRUE;
    file_instance_p := baf$task_file_entry_p (file_identifier);
    IF file_instance_p = NIL THEN
      osp$set_status_abnormal (amc$access_method_id, ame$improper_file_id, interface_name, status);
      RETURN; {----->
    IFEND;

    call_block.operation := amc$create_key_definition;

    call_block.create_key_definition.key_name := key_name;
    call_block.create_key_definition.key_position := key_position;
    call_block.create_key_definition.key_length := key_length;
    call_block.create_key_definition.optional_attributes := optional_attributes;
    file_instance_p^.fap_control_information.first_fap.access_method^
          (file_identifier, call_block, fap_layer_number, status);

    IF NOT status.normal THEN
      IF (file_instance_p^.instance_attributes.dynamic_label.error_exit_procedure <> NIL) THEN
        file_instance_p^.instance_attributes.dynamic_label.error_exit_procedure^ (file_identifier, status);
      IFEND;
    IFEND;

  PROCEND amp$create_key_definition;
?? OLDTITLE ??
MODEND amm$create_key_definition;
