?? NEWTITLE := 'NOS/VE : BASIC ACCESS METHOD, RING BRACKETS 2DD' ??
MODULE amm$fetch_fap_pointer;
?? RIGHT := 110 ??

*copyc amh$also

?? NEWTITLE := 'Global Declarations Referenced By This Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc amc$condition_code_limits
*copyc ame$fap_program_actions
*copyc ame$fap_validation_errors
*copyc ame$improper_file_id
*copyc ame$ring_validation_errors
*copyc ost$caller_identifier
*copyc amt$call_block
*copyc amt$fap_layer_number
*copyc amt$fap_pointer
?? POP ??
*copyc baf$task_file_entry_p
*copyc amp$set_file_instance_abnormal
*copyc osp$copy_local_status_to_status
*copyc osp$set_status_abnormal
?? OLDTITLE ??
?? NEWTITLE := '  [XDCL] AMP$FETCH_FAP_POINTER', EJECT ??

*copyc amh$fetch_fap_pointer

  PROCEDURE [XDCL, #GATE] amp$fetch_fap_pointer
    (    file_identifier: amt$file_identifier;
         layer_number: amt$fap_layer_number;
     VAR structure_pointer: ^cell;
     VAR status: ost$status);

    CONST
      interface_name = 'AMP$FETCH_FAP_POINTER';

    VAR
      caller_id: ost$caller_identifier,
      file_instance_p: ^bat$task_file_entry,
      layer_p: ^bat$fap_descriptor;

    #CALLER_ID (caller_id);
    status.normal := TRUE;
    file_instance_p := baf$task_file_entry_p (file_identifier);
    IF file_instance_p = NIL THEN
      osp$set_status_abnormal (amc$access_method_id, ame$improper_file_id, interface_name, status);
      RETURN; {----->
    IFEND;

    IF (file_instance_p^.fap_control_information.fap_array = NIL) AND (layer_number = 0) THEN
      layer_p := ^file_instance_p^.fap_control_information.first_fap;
    ELSEIF (file_instance_p^.fap_control_information.fap_array <> NIL) AND
          (layer_number <= UPPERBOUND (file_instance_p^.fap_control_information.fap_array^)) THEN
      layer_p := ^file_instance_p^.fap_control_information.fap_array^ [layer_number];
    ELSE
      osp$set_status_abnormal (amc$access_method_id, ame$improper_layer_number, interface_name, status);
      RETURN; {----->
    IFEND;

    IF caller_id.ring <= layer_p^.loaded_ring THEN
      structure_pointer := layer_p^.structure_pointer;
      IF structure_pointer = NIL THEN
        amp$set_file_instance_abnormal (file_identifier, ame$nil_structure_pointer, amc$fetch_fap_pointer_req,
              ' ', status);
      IFEND;
    ELSE
      amp$set_file_instance_abnormal (file_identifier, ame$ring_validation_error, amc$fetch_fap_pointer_req,
            ' ', status);
    IFEND;

  PROCEND amp$fetch_fap_pointer;
?? OLDTITLE ??
MODEND amm$fetch_fap_pointer;
