?? TITLE := 'NOS/VE :  BASIC ACCESS METHOD' ??
MODULE amm$get_next;
?? RIGHT := 110 ??

*copyc amh$also

?? NEWTITLE := 'Global Declarations Referenced By This Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc amc$condition_code_limits
*copyc ame$improper_file_id
*copyc amt$call_block
*copyc amt$fap_layer_number
*copyc amt$fap_pointer
?? POP ??
*copyc baf$task_file_entry_p
*copyc amp$call_fap_access_condition
*copyc osp$set_status_abnormal
?? OLDTITLE ??
?? NEWTITLE := '  [XDCL] AMP$GET_NEXT', EJECT ??

*copyc amh$get_next

  PROCEDURE [XDCL, #GATE] amp$get_next ALIAS 'amxgetn'
    (    file_identifier: amt$file_identifier;
         working_storage_area: ^cell;
         working_storage_length: amt$working_storage_length;
     VAR transfer_count: amt$transfer_count;
     VAR byte_address: amt$file_byte_address;
     VAR file_position: amt$file_position;
     VAR status: ost$status);


    CONST
      interface_name = 'AMP$GET_NEXT',
      fap_layer_number = 0;

    VAR
      call_block: amt$call_block,
      file_instance_p: ^bat$task_file_entry;

    status.normal := TRUE;
    file_instance_p := baf$task_file_entry_p (file_identifier);
    IF file_instance_p = NIL THEN
      osp$set_status_abnormal (amc$access_method_id, ame$improper_file_id, interface_name, status);
      RETURN; {----->
    IFEND;

    call_block.operation := amc$get_next_req;

    call_block.getn.working_storage_area := working_storage_area;
    call_block.getn.working_storage_length := working_storage_length;
    call_block.getn.transfer_count := ^transfer_count;
    call_block.getn.byte_address := ^byte_address;
    call_block.getn.file_position := ^file_position;

    file_instance_p^.fap_control_information.first_fap.access_method^
          (file_identifier, call_block, fap_layer_number, status);

    IF NOT status.normal THEN
      amp$call_fap_access_condition (file_identifier, fap_layer_number, call_block, file_instance_p^, status);
    IFEND;

  PROCEND amp$get_next;
?? OLDTITLE ??
MODEND amm$get_next;


