?? NEWTITLE := 'NOS/VE :  ADVANCED ACCESS METHOD, RING 4DD' ??
MODULE amm$get_segment_pointer;
?? RIGHT := 110 ??

?? NEWTITLE := 'Global Declarations Referenced By This Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc amc$condition_code_limits
*copyc ame$improper_file_id
*copyc amt$call_block
*copyc amt$fap_layer_number
*copyc amt$fap_pointer
*copyc amt$file_identifier
?? POP ??
*copyc baf$task_file_entry_p
*copyc osp$set_status_abnormal
?? OLDTITLE ??
?? NEWTITLE := '  [XDCL] AMP$GET_SEGMENT_POINTER' ??
*copyc amh$also
*copyc amh$get_segment_pointer

  PROCEDURE [XDCL, #GATE] amp$get_segment_pointer ALIAS 'amxgsgp'
    (    file_identifier: amt$file_identifier;
         pointer_kind: amt$pointer_kind;
     VAR segment_pointer: amt$segment_pointer;
     VAR status: ost$status);

    CONST
      interface_name = 'AMP$GET_SEGMENT_POINTER',
      fap_layer_number = 0;

    VAR
      call_block: amt$call_block,
      file_instance_p: ^bat$task_file_entry;

    status.normal := TRUE;
    file_instance_p := baf$task_file_entry_p (file_identifier);
    IF file_instance_p = NIL THEN
      osp$set_status_abnormal (amc$access_method_id, ame$improper_file_id, interface_name, status);
      RETURN; {----->
    IFEND;

    call_block.operation := amc$get_segment_pointer_req;
    call_block.getsegp.pointer_kind := pointer_kind;
    call_block.getsegp.segment_pointer := ^segment_pointer;

    file_instance_p^.fap_control_information.first_fap.access_method^
          (file_identifier, call_block, fap_layer_number, status);

    IF (NOT status.normal)
{ } AND (file_instance_p^.instance_attributes.dynamic_label.error_exit_procedure <> NIL) THEN
      file_instance_p^.instance_attributes.dynamic_label.error_exit_procedure^ (file_identifier, status);
    IFEND;

  PROCEND amp$get_segment_pointer;
?? OLDTITLE ??
MODEND amm$get_segment_pointer;
