?? NEWTITLE := 'NOS/VE :  ADVANCED ACCESS METHOD, RING 4DD' ??
MODULE amm$replace_key;
?? RIGHT := 110 ??

*copyc amh$also

?? NEWTITLE := 'Global Declarations Referenced By This Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc amc$condition_code_limits
*copyc ame$improper_file_id
*copyc amt$call_block
*copyc amt$fap_layer_number
*copyc amt$fap_pointer
?? POP ??
*copyc baf$task_file_entry_p
*copyc osp$set_status_abnormal
?? OLDTITLE ??
?? NEWTITLE := '  [XDCL] AMP$REPLACE_KEY', EJECT ??

  PROCEDURE [XDCL, #GATE] amp$replace_key
    (    file_identifier: amt$file_identifier;
         working_storage_area: ^cell;
         working_storage_length: amt$working_storage_length;
         key_location: ^cell;
         wait: ost$wait;
     VAR status: ost$status);

    CONST
      interface_name = 'AMP$REPLACE_KEY',
      fap_layer_number = 0;

    VAR
      call_block: amt$call_block,
      file_instance_p: ^bat$task_file_entry;

    status.normal := TRUE;
    file_instance_p := baf$task_file_entry_p (file_identifier);
    IF file_instance_p = NIL THEN
      osp$set_status_abnormal (amc$access_method_id, ame$improper_file_id, interface_name, status);
      RETURN; {----->
    IFEND;

    call_block.operation := amc$replace_key_req;

    call_block.repk.working_storage_area := working_storage_area;
    call_block.repk.working_storage_length := working_storage_length;
    call_block.repk.key_location := key_location;
    call_block.repk.wait := wait;

    file_instance_p^.fap_control_information.first_fap.access_method^
          (file_identifier, call_block, fap_layer_number, status);

    IF NOT status.normal THEN
      IF (file_instance_p^.instance_attributes.dynamic_label.error_exit_procedure <> NIL) THEN
        file_instance_p^.instance_attributes.dynamic_label.error_exit_procedure^ (file_identifier, status);
      IFEND;
    IFEND;

  PROCEND amp$replace_key;
?? OLDTITLE ??
MODEND amm$replace_key;
