?? TITLE := 'NOS/VE :  BASIC ACCESS METHOD' ??
MODULE amm$store;
?? RIGHT := 110 ??

*copyc amh$also

?? NEWTITLE := 'Global Declarations Referenced By This Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc amc$condition_code_limits
*copyc ame$improper_file_id
*copyc amt$call_block
*copyc amt$fap_layer_number
*copyc amt$fap_pointer
?? POP ??
*copyc baf$task_file_entry_p
*copyc osp$set_status_abnormal
?? OLDTITLE ??
?? NEWTITLE := '  [XDCL] AMP$STORE', EJECT ??

*copyc amh$store

  PROCEDURE [XDCL, #GATE] amp$store ALIAS 'amxstor'
    (    file_identifier: amt$file_identifier;
         file_attributes: amt$store_attributes;
     VAR status: ost$status);

    CONST
      interface_name = 'AMP$STORE',
      fap_layer_number = 0;

    VAR
      call_block: amt$call_block,
      file_instance_p: ^bat$task_file_entry,
      store_attributes_p: ^amt$store_attributes;

    status.normal := TRUE;
    file_instance_p := baf$task_file_entry_p (file_identifier);
    IF file_instance_p = NIL THEN
      osp$set_status_abnormal (amc$access_method_id, ame$improper_file_id, interface_name, status);
      RETURN; {----->
    IFEND;

    call_block.operation := amc$store_req;

    PUSH store_attributes_p: [LOWERBOUND (file_attributes) .. UPPERBOUND (file_attributes)];
    store_attributes_p^ := file_attributes;
    call_block.store.file_attributes := store_attributes_p;

    file_instance_p^.fap_control_information.first_fap.access_method^
          (file_identifier, call_block, fap_layer_number, status);

    IF NOT status.normal THEN
      IF (file_instance_p^.instance_attributes.dynamic_label.error_exit_procedure <> NIL) THEN
        file_instance_p^.instance_attributes.dynamic_label.error_exit_procedure^ (file_identifier, status);
      IFEND;
    IFEND;

  PROCEND amp$store;
?? OLDTITLE ??
MODEND amm$store;
