.PROC,SYNCACC*I,\
  UN"NOS/VE FAMILY ADMINISTRATOR'S USERNAME" = (*F,*N=ADMINUN),
  PW"NOS/VE FAMILY ADMINISTRATOR'S PASSWORD" = (*F,*N=ADMINPW),
  FM"NOS/VE FAMILY"                          = (*F,*N=NVE),
  LID"NOS/VE LID"                            = (*F,*N=NVE),
  NOSFM"NOS FAMILY"                          = (*F,*N=),
.ENDPARM.
.HELP.
   SYNCACC GENERATES A PROFILE SOURCE FILE FOR THE DEFAULT FAMILY
   AND SUBMITS A JOB TO NOS/VE THAT SYNCHRONIZES NOS/VE PROJECT
   VALIDATIONS WITH NOS.
.HELP,UN.
   SPECIFIES THE USERNAME FOR NOS/VE'S FAMILY ADMINISTRATOR.
.HELP,PW.
   SPECIFIES THE PASSWORD FOR NOS/VE'S FAMILY ADMINISTRATOR.
.HELP,FM.
   SPECIFIES THE NOS/VE FAMILY FOR WHICH SYNCACC IS BEING RUN.  FM DEFAULTS
   TO THE NOS/VE FAMILY NVE.
.HELP,LID.
   SPECIFIES THE LID FOR NOS/VE.  THE DEFAULT LID IS NVE.
.HELP,NOSFM.
   SPECIFIES THE NOS FAMILY.  NOSFM DEFAULTS TO THE NOS DEFAULT FAMILY AND
   HAS NO EFFECT WHEN SYNCACC IS NOT RUN FROM SYSTEM ORIGIN.
.ENDHELP.
.IFE,OT.EQ.SYO,ISSUEUSER.
  USER,UN,PW,NOSFM.
.ENDIF,ISSUEUSER.
RETURN,SOURCE,NVEJOB.
PROFILE,OP=S.
REWIND,SOURCE,NVEJOB,FRONT,BACK.
COPY,FRONT,NVEJOB.
COMPASS,I=SQUASH,L=0,S,S=PSSTEXT.
LGO,SOURCE,NVEJOB.
COPY,BACK,NVEJOB.
PACK,NVEJOB.
ROUTE,NVEJOB,DC=IN,ST=LID,UJN=SYNCACC.
REVERT. NVE JOB SUBMITTED
.DATA,FRONT.
LOGIN USER=UN PASSWORD=PW FAMILY#_NAME=FM JOB#_CLASS=BATCH JOB#_NAME=SYNCACC
SET#_WORKING#_CATALOG $LOCAL
COLLECT#_TEXT PROFILE#_SOURCE UNTIL='**END SOURCE**'
.DATA,BACK.
**END SOURCE**
$SYSTEM.ACCOUNTING#_AND#_VALIDATION.COMMAND#_LIBRARY.GENERATE#_PROJECT#_UPDATES ..
      PS=PROFILE#_SOURCE AD=ADMV#_DIRECTIVES
SYSTEM#_OPERATOR#_UTILITY
  ADMINISTER#_VALIDATIONS
    INCLUDE#_FILE F=ADMV#_DIRECTIVES
  END#_ADMINISTER#_VALIDATIONS
QUIT
LOGOUT
.DATA,SQUASH
SQUASH
          IDENT  SQUASH
          ENTRY  SQUASH
          SST
          SYSCOM B1
          SPACE  4,10
****      SQUASH READS THE SOURCE OUTPUT FROM PROFILE AND PRODUCES AND
*         OUTPUT FILE THAT CONTAINS ONLY THE PROFILE DIRECTIVES NEEDED
*         BY THE NOS/VE GENERATE_PROJECT_UPDATES PROGRAM.
          SPACE  4,10
***       CALLING SEQUENCE.
*
*         SQUASH,SOURCE,NSOURCE.
*
*         SOURCE IS THE NAME OF THE PROFILE SOURCE FILE, SOURCE IS THE
*         DEFAULT NAME.
*
*         NSOURCE IS THE NAME OF THE SQAUSH OUTPUT, NSOURCE IS THE
*         DEFAULT NAME.
          SPACE  4,10
 BUFL     EQU    1001B
          SPACE  4,10
**        FETS.

 SOURCE   FILEB  IBUF,BUFL
 NSOURCE  FILEB  OBUF,BUFL
          SPACE  4,10
**        MAIN PROGRAM.
 SQUASH   SB1    1
          SA1    ARGR
          MX0    42
          BX7    X0*X1
          ZR     X7,SQU1     IF DEFAULT SOURCE FILE NAME
          SETFET SOURCE,(LFN=X7)
 SQU1     SA1    ARGR+1
          BX7    X0*X1
          ZR     X7,SQU2     IF DEFAULT NSOURCE FILE NAME
          SETFET NSOURCE,(LFN=X7)
 SQU2     READ   SOURCE
          WRITE  NSOURCE,*
 SQU3     READC  SOURCE,WBUF,8
          NZ     X1,SQU7     IF EOR/EOF/EOI
          SA1    WBUF
          SA2    SQUA        LIST OF VALID KEYWORDS
          MX3    60          KEYWORD MASK
 SQU4     BX6    X1-X2
          BX6    X3*X6
          ZR     X6,SQU6     IF KEYWORD MATCH
          SA2    A2+1
          ZR     X2,SQU5     IF END OF LIST
          EQ     SQU4        CHECK NEXT KEYWORD

 SQU5     MX4    -6          MASK FOR ACCUMULATOR/LIMIT NUMBER
          LX4    3*6
          BX6    X3-X4
          LX3    X4
          ZR     X6,SQU3     IF ACCUMULATOR/LIMITS CHECKED
          SA2    SQUB        ACCUMULATOR/LIMIT KEYWORDS
          EQ     SQU4        PERFORM KEYWORD MATCH

 SQU6     WRITEC NSOURCE,WBUF
          EQ     SQU3        READ NEXT SOURCE LINE

 SQU7     WRITER NSOURCE,R
          MESSAGE  (=C* PROFILE SOURCE SQUASHED.*),1
          ENDRUN

 SQUA     CON    10H    ACN =
          CON    10H    APN =
          CON    10H    AUN =
          CON    10H    MU  =
          CON    10H    SML =
          CON    10H    SMA =
          CON    10H    SIL =
          CON    10H    SIA =
          CON    0

 SQUB     CON    10H    AR* =
          CON    10H    LR* =
          CON    0
          SPACE  4,10
**        BUFFERS.


 WBUF     BSS    8
 IBUF     BSS    BUFL
 OBUF     BSS    BUFL
          END    SQUASH
/EOR
