?? TITLE := 'NOS/VE:  BASIC ACCESS METHOD, TASK SERVICES' ??
MODULE bam$sys_blk_undefined_rec_fap;
?? RIGHT := 110 ??

?? NEWTITLE := 'Global Declarations Referenced by This Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc amc$condition_code_limits
*copyc bac$minimum_open_ring
*copyc osd$virtual_address
*copyc ame$access_validation_errors
*copyc ame$conflicting_access_level
*copyc ame$device_class_validation
*copyc ame$fap_validation_errors
*copyc ame$file_organization_errors
*copyc ame$get_program_actions
*copyc ame$get_validation_errors
*copyc ame$improper_file_id
*copyc ame$improper_random_access
*copyc ame$improper_wsl
*copyc ame$open_validation_errors
*copyc ame$put_program_actions
*copyc ame$put_validation_errors
*copyc ame$ring_validation_errors
*copyc ame$skip_validation_errors
*copyc ame$unimplemented_request
*copyc ife$error_codes
*copyc amt$fap_declarations
*copyc bat$global_file_information
*copyc bat$positioning_info
*copyc bat$private_read_information
*copyc bat$record_header_type
*copyc bat$task_file_table
*copyc ost$caller_identifier
?? POP ??
*copyc pmf$job_mode
*copyc amp$set_file_instance_abnormal
*copyc baf$task_file_entry_p
*copyc bap$close
*copyc bap$fetch
*copyc bap$fetch_access_information
*copyc bap$get_segment_pointer
*copyc bap$set_segment_eoi
*copyc bap$set_segment_position
*copyc bap$store
*copyc bap$write_modified_pages
*copyc mmp$set_segment_length
*copyc osp$set_status_abnormal
*copyc bav$task_file_table
*copyc fmv$global_file_information
*copyc i#move
?? OLDTITLE ??
?? NEWTITLE := '[xdcl, #gate] BAP$SYS_BLK_UNDEFINED_REC_FAP', EJECT ??

  PROCEDURE [XDCL, #GATE] bap$sys_blk_undefined_rec_fap
    (    file_identifier: amt$file_identifier;
         call_block: amt$call_block;
         layer_number: amt$fap_layer_number;
     VAR status: ost$status);

    CONST
      error_text = 'BAP$SYS_BLK_UNDEFINED_REC_FAP - ';

    VAR
      at_eoi: boolean,
      caller_id: ost$caller_identifier,
      data_ptr: ^cell,
      file_byte_address: amt$file_byte_address,
      file_instance: ^bat$task_file_entry,
      record_header: bat$record_header,
      record_info: bat$record_info;

?? NEWTITLE := 'rollback_procedure', EJECT ??

    PROCEDURE rollback_procedure
      (    condition_status: ost$status);

      status := condition_status;
      file_instance^.rollback_procedure := NIL;
      EXIT bap$sys_blk_undefined_rec_fap; {----->

    PROCEND rollback_procedure;
?? OLDTITLE ??
?? NEWTITLE := 'GET_NEXT', EJECT ??

    PROCEDURE [INLINE] get_next;

      IF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

*copy bai$validate_read_access
      IF NOT status.normal THEN
        RETURN; {----->
      IFEND;

*copy bai$get_record_info

      IF (record_info.file_position = amc$mid_record) AND (file_instance^.private_read_information = NIL) AND
            (file_instance^.global_file_information^.last_access_operation = amc$put_partial_req) THEN
{ Must have been left mid_record by a put_partial.  EOI needs updating.
*copy   bai$update_eoi
      IFEND;

*copy bai$get_eoi_check

      IF NOT at_eoi THEN
        IF call_block.getn.working_storage_length + record_info.current_byte_address >=
              file_instance^.global_file_information^.eoi_byte_address THEN
          record_info.record_length := file_instance^.global_file_information^.eoi_byte_address -
                record_info.current_byte_address;
        ELSE
          record_info.record_length := call_block.getn.working_storage_length;
        IFEND;

        record_info.bor_address := record_info.current_byte_address;

        data_ptr := #ADDRESS (#RING (file_instance^.file_pva), #SEGMENT (file_instance^.file_pva),
              record_info.current_byte_address);

        i#move (data_ptr, call_block.getn.working_storage_area, record_info.record_length);

        record_info.current_byte_address := record_info.current_byte_address + record_info.record_length;
        record_info.file_position := amc$eor;
      ELSE
        record_info.bor_address := record_info.current_byte_address;
        record_info.record_length := 0;
      IFEND; { NOT at eoi }

*copy bai$save_record_info

      call_block.getn.file_position^ := record_info.file_position;
      call_block.getn.transfer_count^ := record_info.record_length;
      IF call_block.operation = amc$get_next_req THEN
        call_block.getn.byte_address^ := record_info.bor_address;
      IFEND;

    PROCEND get_next;
?? OLDTITLE ??
?? NEWTITLE := 'PUT_NEXT', EJECT ??

    PROCEDURE [INLINE] put_next;

      IF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

*copy bai$validate_write_access
      IF NOT status.normal THEN
        RETURN; {----->
      IFEND;

    /main_code_put_next/
      BEGIN
        record_info := file_instance^.global_file_information^.positioning_info.record_info;

{ Check to make sure we do not go over the 2 GB file limit.
        IF file_instance^.global_file_information^.file_limit <
              record_info.current_byte_address + call_block.putn.working_storage_length THEN
          amp$set_file_instance_abnormal (file_identifier, ame$put_beyond_file_limit, call_block.operation,
                error_text, status);
          EXIT /main_code_put_next/; {----->
        IFEND;

        record_info.record_length := call_block.putn.working_storage_length;
        record_info.bor_address := record_info.current_byte_address;

        data_ptr := #ADDRESS (#RING (file_instance^.file_pva), #SEGMENT (file_instance^.file_pva),
              record_info.current_byte_address);

        i#move (call_block.putn.working_storage_area, data_ptr, record_info.record_length);

        record_info.current_byte_address := record_info.current_byte_address + record_info.record_length;
        record_info.file_position := amc$eor;

*copy   bai$update_eoi

        file_instance^.instance_of_open_modified := TRUE;
        file_instance^.global_file_information^.positioning_info.record_info := record_info;

      END /main_code_put_next/;

      IF call_block.operation = amc$put_next_req THEN
        call_block.putn.byte_address^ := record_info.bor_address;
      IFEND;

    PROCEND put_next;
?? OLDTITLE ??
?? NEWTITLE := 'GET_PARTIAL', EJECT ??

    PROCEDURE [INLINE] get_partial;

      IF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

*copy bai$validate_read_access
      IF NOT status.normal THEN
        RETURN; {----->
      IFEND;

{ Note: since only the user knows where records are, skip_option is ignored.

*copy bai$get_record_info

      IF (record_info.file_position = amc$mid_record) AND (file_instance^.private_read_information = NIL) AND
            (file_instance^.global_file_information^.last_access_operation = amc$put_partial_req) THEN
{ Must have been left mid_record by a put_partial.  EOI needs updating.
        record_info.file_position := amc$eor;
*copy   bai$update_eoi
      IFEND;

*copy bai$get_eoi_check

      IF NOT at_eoi THEN
        IF record_info.file_position <> amc$mid_record THEN
          record_info.bor_address := record_info.current_byte_address;
        IFEND;

        IF call_block.getp.working_storage_length + record_info.current_byte_address >=
              file_instance^.global_file_information^.eoi_byte_address THEN
          record_info.record_length := file_instance^.global_file_information^.eoi_byte_address -
                record_info.current_byte_address;
          record_info.file_position := amc$eor;
        ELSE
          record_info.record_length := call_block.getp.working_storage_length;
          record_info.file_position := amc$mid_record;
        IFEND;

        data_ptr := #ADDRESS (#RING (file_instance^.file_pva), #SEGMENT (file_instance^.file_pva),
              record_info.current_byte_address);

        i#move (data_ptr, call_block.getp.working_storage_area, record_info.record_length);

        record_info.current_byte_address := record_info.current_byte_address + record_info.record_length;

      ELSE { not at eoi }
        record_info.bor_address := record_info.current_byte_address;
        record_info.record_length := 0;
      IFEND;

*copy bai$save_record_info

      call_block.getp.record_length^ := record_info.current_byte_address - record_info.bor_address;
      call_block.getp.transfer_count^ := record_info.record_length;
      call_block.getp.file_position^ := record_info.file_position;
      call_block.getp.byte_address^ := record_info.bor_address;

    PROCEND get_partial;
?? OLDTITLE ??
?? NEWTITLE := 'PUT_PARTIAL', EJECT ??

    PROCEDURE [INLINE] put_partial;

      { This procedure uses globally defined variables and therefore }
      { must be used as a nested procedure. }

      IF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

*copy bai$validate_write_access
      IF NOT status.normal THEN
        RETURN; {----->
      IFEND;

      IF (call_block.putp.term_option < LOWERVALUE (amt$term_option)) OR
            (call_block.putp.term_option > UPPERVALUE (amt$term_option)) THEN
        amp$set_file_instance_abnormal (file_identifier, ame$improper_term_option, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

    /main_code_put_partial/
      BEGIN
        record_info := file_instance^.global_file_information^.positioning_info.record_info;

        IF ((call_block.putp.term_option = amc$continue) AND (record_info.file_position <> amc$mid_record))
              THEN
          amp$set_file_instance_abnormal (file_identifier, ame$improper_continue, call_block.operation, '',
                status);
          EXIT /main_code_put_partial/; {----->
        IFEND;

{ Check to make sure we do not go over the 2 GB file limit.
        IF file_instance^.global_file_information^.file_limit <
              record_info.current_byte_address + call_block.putn.working_storage_length THEN
          amp$set_file_instance_abnormal (file_identifier, ame$put_beyond_file_limit, call_block.operation,
                error_text, status);
          EXIT /main_code_put_partial/; {----->
        IFEND;

        data_ptr := #ADDRESS (#RING (file_instance^.file_pva), #SEGMENT (file_instance^.file_pva),
              record_info.current_byte_address);

        i#move (call_block.putp.working_storage_area, data_ptr, call_block.putp.working_storage_length);

        CASE call_block.putp.term_option OF
        = amc$start =
          IF (record_info.file_position = amc$mid_record) AND
                (file_instance^.private_read_information = NIL) AND
                (file_instance^.global_file_information^.last_access_operation = amc$put_partial_req) THEN

{ Must have been left mid_record by a put_partial.  EOI needs updating.

            record_info.file_position := amc$eor;
*copy   bai$update_eoi
          IFEND;
          record_info.file_position := amc$mid_record;
          record_info.bor_address := record_info.current_byte_address;
          record_info.record_length := call_block.putp.working_storage_length;
        = amc$continue =
          record_info.file_position := amc$mid_record;
          record_info.record_length := record_info.record_length + call_block.putp.working_storage_length;
        = amc$terminate =
          IF record_info.file_position = amc$mid_record THEN
            record_info.record_length := record_info.record_length + call_block.putp.working_storage_length;
          ELSE { writing a full_record using terminate }
            record_info.record_length := call_block.putp.working_storage_length;
            record_info.bor_address := record_info.current_byte_address;
          IFEND;
          record_info.file_position := amc$eor;
        ELSE
        CASEND;

        record_info.current_byte_address := record_info.current_byte_address +
              call_block.putp.working_storage_length;

        IF call_block.putp.term_option = amc$terminate THEN
*copy     bai$update_eoi
        IFEND;

        file_instance^.instance_of_open_modified := TRUE;
        file_instance^.global_file_information^.positioning_info.record_info := record_info;
      END /main_code_put_partial/;

      call_block.putp.byte_address^ := record_info.bor_address;

    PROCEND put_partial;
?? OLDTITLE ??
?? NEWTITLE := 'PROCEDURE [INLINE] SEEK_DIRECT', EJECT ??

    PROCEDURE [INLINE] seek_direct;

      IF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

*copy bai$seek_validation
      IF NOT status.normal THEN
        RETURN; {----->
      IFEND;

*copy bai$get_record_info

      IF (record_info.file_position = amc$mid_record) AND (file_instance^.private_read_information = NIL) AND
            (file_instance^.global_file_information^.last_access_operation = amc$put_partial_req) THEN

{ Must have been left mid_record by a put_partial.  EOI needs updating.
*copy   bai$update_eoi
      IFEND;

      record_info.bor_address := file_byte_address;
      record_info.current_byte_address := file_byte_address;
      record_info.file_position := amc$eor;

*copy bai$save_record_info

    PROCEND seek_direct;
?? OLDTITLE ??
?? NEWTITLE := 'PROCEDURE terminate_record', EJECT ??

    PROCEDURE terminate_record;

      IF (file_instance^.private_read_information = NIL) AND
            (file_instance^.global_file_information^.positioning_info.record_info.file_position =
            amc$mid_record) AND (file_instance^.global_file_information^.last_access_operation =
            amc$put_partial_req) THEN

{ Must have been left mid_record by a put_partial.  EOI needs updating.

        record_info := file_instance^.global_file_information^.positioning_info.record_info;

*copy bai$update_eoi

        file_instance^.global_file_information^.positioning_info.record_info := record_info;
      IFEND;

    PROCEND terminate_record;
?? OLDTITLE ??
?? EJECT ??

    #CALLER_ID (caller_id);
    status.normal := TRUE;

  /process_fap_request/
    BEGIN
      file_instance := baf$task_file_entry_p (file_identifier);
      IF file_instance = NIL THEN
        amp$set_file_instance_abnormal (file_identifier, ame$improper_file_id, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

      file_instance^.rollback_procedure := ^rollback_procedure;
      CASE call_block.operation OF
      = amc$get_next_req =
        get_next;
      = amc$put_next_req =
        put_next;
      = amc$get_partial_req =
        get_partial;
      = amc$put_partial_req =
        put_partial;
      = amc$open_req =
        ;
      = amc$close_req =
        terminate_record;
        bap$close (file_identifier, status);
        EXIT /process_fap_request/; {----->
      = amc$rewind_req =
        terminate_record;
*copy     bai$rewind
      = amc$seek_direct_req =
        file_byte_address := call_block.seekd.byte_address;
        seek_direct;
      = amc$get_direct_req =
        file_byte_address := call_block.getd.byte_address;
        seek_direct;
        IF NOT status.normal THEN
          IF status.condition = ame$position_beyond_eoi THEN
            status.condition := ame$input_after_eoi;
          IFEND;
        ELSE
          get_next;
        IFEND;
      = amc$put_direct_req =
        file_byte_address := call_block.putd.byte_address;
        seek_direct;
        IF status.normal THEN
          put_next;
        IFEND;
      = amc$skip_req =
        amp$set_file_instance_abnormal (file_identifier, ame$unsupported_skip, call_block.operation, ' ',
              status);
      = amc$fetch_access_information_rq =
        bap$fetch_access_information (file_identifier, call_block, layer_number, status);
        EXIT /process_fap_request/; {----->
      = amc$fetch_req =
        bap$fetch (file_identifier, call_block, layer_number, status);
        EXIT /process_fap_request/; {----->
      = amc$get_segment_pointer_req =
        bap$get_segment_pointer (file_identifier, call_block, layer_number, status);
      = amc$set_segment_eoi_req =
        bap$set_segment_eoi (file_identifier, call_block, layer_number, status);
      = amc$set_segment_position_req =
        bap$set_segment_position (file_identifier, call_block, layer_number, status);
      = amc$store_req =
        bap$store (file_identifier, call_block, layer_number, status);
      = amc$replace_req, amc$write_end_partition_req =
        amp$set_file_instance_abnormal (file_identifier, ame$unsupported_operation, call_block.operation,
              error_text, status);
      = amc$write_tape_mark_req, amc$close_volume_req =
        amp$set_file_instance_abnormal (file_identifier, ame$improper_device_class, call_block.operation,
              'MASS_STORAGE', status);
      = amc$flush_req =
        bap$write_modified_pages (file_instance, file_identifier, status);
      = ifc$fetch_terminal_req, ifc$store_terminal_req =
        IF pmf$job_mode () = jmc$batch THEN
          osp$set_status_abnormal (ifc$interactive_facility_id, ife$current_job_not_interactive,
                'FETCH/STORE_TERMINAL_REQ', status);
        ELSE
          amp$set_file_instance_abnormal (file_identifier, ame$improper_device_class, call_block.operation,
                'MASS STORAGE', status);
        IFEND;
      ELSE
        amp$set_file_instance_abnormal (file_identifier, ame$unimplemented_request, call_block.operation,
              ' for sequential or byte addressable files', status);
      CASEND;

      IF file_instance^.private_read_information = NIL THEN
        IF status.normal THEN
          file_instance^.global_file_information^.error_status := 0;
        ELSE
          file_instance^.global_file_information^.error_status := status.condition;
        IFEND;
        file_instance^.global_file_information^.last_access_operation := call_block.operation;
      ELSE
        IF status.normal THEN
          file_instance^.private_read_information^.error_status := 0;
        ELSE
          file_instance^.private_read_information^.error_status := status.condition;
        IFEND;
        file_instance^.private_read_information^.last_access_operation := call_block.operation;
      IFEND;
    END /process_fap_request/;

    file_instance^.rollback_procedure := NIL;

  PROCEND bap$sys_blk_undefined_rec_fap;
?? OLDTITLE ??
MODEND bam$sys_blk_undefined_rec_fap;
