?? TITLE := 'NOS/VE:  BASIC ACCESS METHOD, TASK SERVICES' ??
MODULE bam$us_blk_fixed_rec_fap;
?? RIGHT := 110 ??

?? NEWTITLE := '    Global Declarations Referenced By This Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc amc$condition_code_limits
*copyc bac$minimum_open_ring
*copyc osd$virtual_address
*copyc ame$access_validation_errors
*copyc ame$conflicting_access_level
*copyc ame$device_class_validation
*copyc ame$fap_validation_errors
*copyc ame$file_organization_errors
*copyc ame$get_program_actions
*copyc ame$get_validation_errors
*copyc ame$improper_file_id
*copyc ame$improper_random_access
*copyc ame$improper_wsl
*copyc ame$open_validation_errors
*copyc ame$put_program_actions
*copyc ame$put_validation_errors
*copyc ame$ring_validation_errors
*copyc ame$skip_program_actions
*copyc ame$skip_validation_errors
*copyc ame$unimplemented_request
*copyc ife$error_codes
*copyc amt$fap_declarations
*copyc bat$block_header
*copyc bat$block_info
*copyc bat$global_file_information
*copyc bat$positioning_info
*copyc bat$task_file_table
*copyc ost$caller_identifier
?? POP ??
*copyc pmf$job_mode
*copyc amp$set_file_instance_abnormal
*copyc baf$task_file_entry_p
*copyc bap$close
*copyc bap$fetch
*copyc bap$fetch_access_information
*copyc bap$get_segment_pointer
*copyc bap$set_segment_eoi
*copyc bap$set_segment_position
*copyc bap$store
*copyc bap$write_modified_pages
*copyc mmp$set_segment_length
*copyc osp$set_status_abnormal
*copyc bav$default_block_info
*copyc bav$default_record_info
*copyc bav$task_file_table
*copyc fmv$global_file_information
*copyc i#move
?? OLDTITLE ??
?? NEWTITLE := '[xdcl, #gate] BAP$US_BLK_FIXED_REC_FAP', EJECT ??

  PROCEDURE [XDCL, #GATE] bap$us_blk_fixed_rec_fap
    (    file_identifier: amt$file_identifier;
         call_block: amt$call_block;
         layer_number: amt$fap_layer_number;
     VAR status: ost$status);

    CONST
      error_text = 'BAP$US_BLK_FIXED_REC_FAP - ';

    VAR
      at_eoi: boolean,
      block_header: ^bat$block_header,
      block_info: bat$block_info,
      block_padding_string: string (40),
      caller_id: ost$caller_identifier,
      data_length: amt$file_byte_address,
      data_ptr: ^cell,
      default_padding_string: string (80),
      file_byte_address: amt$file_byte_address,
      file_instance: ^bat$task_file_entry,
      i: integer,
      padding_area: ^cell,
      padding_character: char,
      padding_length: 0 .. amc$maximum_block - 1,
      record_info: bat$record_info,
      working_storage_area: ^char,
      wsa: ^cell,
      wsl: amt$working_storage_length;

?? NEWTITLE := 'ROLLBACK_PROCEDURE', EJECT ??

    PROCEDURE rollback_procedure
      (    condition_status: ost$status);

      status := condition_status;
      file_instance^.rollback_procedure := NIL;
      EXIT bap$us_blk_fixed_rec_fap; {----->

    PROCEND rollback_procedure;
?? OLDTITLE ??
?? NEWTITLE := '[inline] GET_NEXT', EJECT ??

    PROCEDURE [INLINE] get_next;

      IF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

*copy bai$validate_read_access
      IF NOT status.normal THEN
        RETURN; {----->
      IFEND;

    /main_code_get_next/
      BEGIN
*copy   bai$get_positioning_info
        block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
              block_info.current_block_byte_address);
        IF block_info.current_block_byte_address < file_instance^.global_file_information^.
              eoi_byte_address THEN
*copy     bai$validate_block_header
          IF NOT status.normal THEN
            EXIT /main_code_get_next/; {----->
          IFEND;
        IFEND;

        IF (record_info.file_position = amc$mid_record) AND
              (file_instance^.private_read_information = NIL) AND
              (file_instance^.global_file_information^.last_access_operation = amc$put_partial_req) THEN
          pad_record_proc;
          IF (record_info.current_byte_address >= file_instance^.global_file_information^.eoi_byte_address) OR
                (file_instance^.instance_attributes.static_label.file_organization <> amc$byte_addressable)
                THEN
            block_header^.block_length := record_info.current_byte_address -
                  (block_info.current_block_byte_address + #SIZE (bat$block_header));
          IFEND;

          update_eoi;
        IFEND; { mid_record, putp, global }

        IF record_info.file_position = amc$mid_record THEN
          record_info.current_byte_address := record_info.bor_address +
                file_instance^.global_file_information^.max_record_length;
        IFEND;

*copy   bai$get_eoi_check

        IF NOT at_eoi THEN

{ Residual_block_length tracks length of data left to read in a block.
{ Residual_record_length tracks length of data left to read in a record.

          record_info.residual_record_length := file_instance^.global_file_information^.max_record_length;

          IF record_info.current_byte_address MOD file_instance^.global_file_information^.max_block_size <>
                0 THEN
            block_info.residual_block_length := block_info.current_block_byte_address +
                  block_header^.block_length + #SIZE (bat$block_header) - record_info.current_byte_address;
          ELSE { on a block header }
            block_info.residual_block_length := block_header^.block_length;
            record_info.current_byte_address := record_info.current_byte_address + #SIZE (bat$block_header);
          IFEND;

          IF block_info.residual_block_length < file_instance^.global_file_information^.max_record_length THEN

{ Note: must be another record or we would be at_eoi so move to next block.
            block_info.current_block_byte_address := block_info.current_block_byte_address +
                  file_instance^.global_file_information^.max_block_size;
            block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
                  block_info.current_block_byte_address);
*copy       bai$validate_block_header
            IF NOT status.normal THEN
              EXIT /main_code_get_next/; {----->
            IFEND;
            record_info.current_byte_address := block_info.current_block_byte_address +
                  #SIZE (bat$block_header);
            block_info.residual_block_length := block_header^.block_length;
          IFEND;

          IF call_block.getn.working_storage_length >= file_instance^.global_file_information^.
                max_record_length THEN
            record_info.record_length := file_instance^.global_file_information^.max_record_length;
            record_info.file_position := amc$eor;
          ELSE
            record_info.record_length := call_block.getn.working_storage_length;
            record_info.file_position := amc$mid_record;
          IFEND;

          record_info.bor_address := record_info.current_byte_address;
          data_ptr := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
                record_info.current_byte_address);
          i#move (data_ptr, call_block.getn.working_storage_area, record_info.record_length);
          record_info.current_byte_address := record_info.current_byte_address + record_info.record_length;
        ELSE { at eoi }
          record_info.bor_address := record_info.current_byte_address;
          record_info.record_length := 0;
        IFEND; { NOT at eoi }

      END /main_code_get_next/;

*copy bai$save_positioning_info

      call_block.getn.transfer_count^ := record_info.record_length;
      call_block.getn.file_position^ := record_info.file_position;
      IF call_block.operation = amc$get_next_req THEN
        call_block.getn.byte_address^ := record_info.bor_address;
      IFEND;

    PROCEND get_next;
?? OLDTITLE ??
?? NEWTITLE := '[inline] PUT_NEXT', EJECT ??

    PROCEDURE [INLINE] put_next;

      IF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

*copy bai$validate_write_access
      IF NOT status.normal THEN
        RETURN; {----->
      IFEND;

    /main_code_put_next/
      BEGIN
        block_info := file_instance^.global_file_information^.positioning_info.block_info;
        record_info := file_instance^.global_file_information^.positioning_info.record_info;

        block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
              block_info.current_block_byte_address);
        IF block_info.current_block_byte_address < file_instance^.global_file_information^.
              eoi_byte_address THEN
*copy     bai$validate_block_header
          IF NOT status.normal THEN
            EXIT /main_code_put_next/; {----->
          IFEND;
        IFEND;

        IF record_info.file_position = amc$mid_record THEN
          IF file_instance^.global_file_information^.last_access_operation = amc$put_partial_req THEN
            pad_record_proc;
            IF (record_info.current_byte_address >= file_instance^.global_file_information^.
                  eoi_byte_address) OR (file_instance^.instance_attributes.static_label.file_organization <>
                  amc$byte_addressable) THEN
              block_header^.block_length := record_info.current_byte_address -
                    (block_info.current_block_byte_address + #SIZE (bat$block_header));
            IFEND;
          ELSE
            record_info.current_byte_address := record_info.bor_address +
                  file_instance^.global_file_information^.max_record_length;
          IFEND;
        IFEND;

        IF record_info.current_byte_address > block_info.current_block_byte_address THEN
          block_info.residual_block_length := file_instance^.global_file_information^.max_data_size +
                block_info.current_block_byte_address + #SIZE (bat$block_header) -
                record_info.current_byte_address;
        ELSE
          block_info.residual_block_length := 0;
        IFEND;

        IF block_info.residual_block_length < file_instance^.global_file_information^.max_record_length THEN
          IF record_info.current_byte_address <> block_info.current_block_byte_address THEN
            record_info.current_byte_address := block_info.current_block_byte_address +
                  file_instance^.global_file_information^.max_block_size;
            block_info.current_block_byte_address := record_info.current_byte_address;
            block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
                  block_info.current_block_byte_address);
          IFEND;

{ Check to make sure we do not go over the 2 GB file limit.
          IF file_instance^.global_file_information^.file_limit < record_info.current_byte_address +
                #SIZE (bat$block_header) THEN
            amp$set_file_instance_abnormal (file_identifier, ame$put_beyond_file_limit, call_block.operation,
                  error_text, status);
            EXIT /main_code_put_next/; {----->
          IFEND;

*copy     bai$write_block_header
        IFEND;

        record_info.bor_address := record_info.current_byte_address;
        IF call_block.putn.working_storage_length > file_instance^.global_file_information^.
              max_record_length THEN

{ Truncate data without warning if to long for fixed record.
          record_info.record_length := file_instance^.global_file_information^.max_record_length;
        ELSE
          record_info.record_length := call_block.putn.working_storage_length;
        IFEND;

{ Check to make sure we do not go over the 2 GB file limit.
        IF file_instance^.global_file_information^.file_limit <
              record_info.current_byte_address + record_info.record_length THEN
          amp$set_file_instance_abnormal (file_identifier, ame$put_beyond_file_limit, call_block.operation,
                error_text, status);
          EXIT /main_code_put_next/; {----->
        IFEND;

        data_ptr := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
              record_info.current_byte_address);
        i#move (call_block.putn.working_storage_area, data_ptr, record_info.record_length);
        record_info.current_byte_address := record_info.current_byte_address + record_info.record_length;
        pad_record;

        file_instance^.instance_of_open_modified := TRUE;
        record_info.file_position := amc$eor;
        record_info.record_length := file_instance^.global_file_information^.max_record_length;

*copy   bai$update_eoi
        IF (call_block.operation = amc$put_next_req) AND ((record_info.current_byte_address =
              file_instance^.global_file_information^.eoi_byte_address) OR
              (file_instance^.instance_attributes.static_label.file_organization <> amc$byte_addressable))
              THEN
          block_header^.block_length := record_info.current_byte_address -
                (block_info.current_block_byte_address + #SIZE (bat$block_header));
        IFEND;

      END /main_code_put_next/;

      file_instance^.global_file_information^.positioning_info.block_info := block_info;
      file_instance^.global_file_information^.positioning_info.record_info := record_info;

      IF call_block.operation = amc$put_next_req THEN
        call_block.putn.byte_address^ := record_info.bor_address;
      IFEND;

    PROCEND put_next;
?? OLDTITLE ??
?? NEWTITLE := '[inline] GET_PARTIAL', EJECT ??

    PROCEDURE [INLINE] get_partial;

      IF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

*copy bai$validate_read_access
      IF NOT status.normal THEN
        RETURN; {----->
      IFEND;

      IF (call_block.getp.skip_option < LOWERVALUE (amt$skip_option)) OR
            (call_block.getp.skip_option > UPPERVALUE (amt$skip_option)) THEN
        amp$set_file_instance_abnormal (file_identifier, ame$improper_skip_option, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

    /main_code_get_partial/
      BEGIN
*copy   bai$get_positioning_info

        block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
              block_info.current_block_byte_address);
        IF block_info.current_block_byte_address < file_instance^.global_file_information^.
              eoi_byte_address THEN
*copy     bai$validate_block_header
          IF NOT status.normal THEN
            EXIT /main_code_get_partial/; {----->
          IFEND;
        IFEND;

{ Move to start of a fixed record if skip_to_eor, but terminate first if necessary.
        IF (record_info.file_position = amc$mid_record) AND
              (file_instance^.private_read_information = NIL) AND
              (file_instance^.global_file_information^.last_access_operation = amc$put_partial_req) THEN
          pad_record_proc;
          IF (record_info.current_byte_address >= file_instance^.global_file_information^.eoi_byte_address) OR
                (file_instance^.instance_attributes.static_label.file_organization <> amc$byte_addressable)
                THEN
            block_header^.block_length := record_info.current_byte_address -
                  (block_info.current_block_byte_address + #SIZE (bat$block_header));
            update_eoi;
          IFEND;
        IFEND; { mid_record, putp, global }

        IF (record_info.file_position = amc$mid_record) AND
              (call_block.getp.skip_option = amc$skip_to_eor) THEN
          record_info.current_byte_address := record_info.bor_address +
                file_instance^.global_file_information^.max_record_length;
          record_info.file_position := amc$eor;
        IFEND;

*copy   bai$get_eoi_check

        IF NOT at_eoi THEN
          IF record_info.current_byte_address > block_info.current_block_byte_address THEN
            block_info.residual_block_length := block_info.current_block_byte_address +
                  block_header^.block_length + #SIZE (bat$block_header) - record_info.current_byte_address;
          ELSE { must be on the block header }
            block_info.residual_block_length := block_header^.block_length;
            record_info.current_byte_address := record_info.current_byte_address + #SIZE (bat$block_header);
          IFEND;

          IF record_info.file_position <> amc$mid_record THEN
            IF block_info.residual_block_length < file_instance^.global_file_information^.
                  max_record_length THEN

              block_info.current_block_byte_address := block_info.current_block_byte_address +
                    file_instance^.global_file_information^.max_block_size;
              block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
                    block_info.current_block_byte_address);

*copy         bai$validate_block_header
              IF NOT status.normal THEN
                EXIT /main_code_get_partial/; {----->
              IFEND;

              block_info.residual_block_length := block_header^.block_length;
              record_info.current_byte_address := block_info.current_block_byte_address +
                    #SIZE (bat$block_header);
            IFEND;
            record_info.bor_address := record_info.current_byte_address;
          IFEND;

          record_info.residual_record_length := record_info.bor_address +
                file_instance^.global_file_information^.max_record_length - record_info.current_byte_address;
          IF call_block.getp.working_storage_length >= record_info.residual_record_length THEN
            record_info.record_length := record_info.residual_record_length;
            record_info.file_position := amc$eor;
          ELSE
            record_info.record_length := call_block.getp.working_storage_length;
            record_info.file_position := amc$mid_record;
          IFEND;

          data_ptr := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
                record_info.current_byte_address);
          i#move (data_ptr, call_block.getp.working_storage_area, record_info.record_length);
          record_info.current_byte_address := record_info.current_byte_address + record_info.record_length;

          call_block.getp.transfer_count^ := record_info.record_length;
          record_info.record_length := record_info.current_byte_address - record_info.bor_address;

        ELSE { at eoi }
          record_info.bor_address := record_info.current_byte_address;
          record_info.record_length := 0;
          call_block.getp.transfer_count^ := record_info.record_length;
        IFEND; { NOT at eoi }

      END /main_code_get_partial/;

*copy bai$save_positioning_info

      call_block.getp.file_position^ := record_info.file_position;
      call_block.getp.record_length^ := record_info.record_length;
      IF call_block.operation = amc$get_partial_req THEN
        call_block.getp.byte_address^ := record_info.bor_address;
      IFEND;

    PROCEND get_partial;
?? OLDTITLE ??
?? NEWTITLE := '[inline] PUT_PARTIAL', EJECT ??

    PROCEDURE [INLINE] put_partial;

      IF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

*copy bai$validate_write_access
      IF NOT status.normal THEN
        RETURN; {----->
      IFEND;

      IF (call_block.putp.term_option < LOWERVALUE (amt$term_option)) OR
            (call_block.putp.term_option > UPPERVALUE (amt$term_option)) THEN
        amp$set_file_instance_abnormal (file_identifier, ame$improper_term_option, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

    /main_code_put_partial/
      BEGIN
        block_info := file_instance^.global_file_information^.positioning_info.block_info;
        record_info := file_instance^.global_file_information^.positioning_info.record_info;

        IF ((record_info.file_position <> amc$mid_record) AND (call_block.putp.term_option = amc$continue))
              THEN
          amp$set_file_instance_abnormal (file_identifier, ame$improper_continue, call_block.operation,
                error_text, status);
          EXIT /main_code_put_partial/; {----->
        IFEND;

        block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
              block_info.current_block_byte_address);
        IF block_info.current_block_byte_address < file_instance^.global_file_information^.
              eoi_byte_address THEN
*copy     bai$validate_block_header
          IF NOT status.normal THEN
            EXIT /main_code_put_partial/; {----->
          IFEND;
        IFEND;

        IF record_info.current_byte_address <> block_info.current_block_byte_address THEN
          block_info.residual_block_length := block_info.current_block_byte_address +
                #SIZE (bat$block_header) + file_instance^.global_file_information^.max_data_size -
                record_info.current_byte_address;
        ELSE
          block_info.residual_block_length := 0;
        IFEND;

        IF (record_info.file_position = amc$mid_record) AND (call_block.putp.term_option = amc$start) AND
              (file_instance^.global_file_information^.last_access_operation = amc$put_partial_req) THEN
          pad_record_proc;
          update_eoi;
        IFEND;

        IF record_info.file_position <> amc$mid_record THEN
          IF block_info.residual_block_length < file_instance^.global_file_information^.max_record_length THEN
            IF record_info.current_byte_address <> block_info.current_block_byte_address THEN
              IF (record_info.current_byte_address >= file_instance^.global_file_information^.
                    eoi_byte_address) OR (file_instance^.instance_attributes.static_label.file_organization <>
                    amc$byte_addressable) THEN
                block_header^.block_length := record_info.current_byte_address -
                      (block_info.current_block_byte_address + #SIZE (bat$block_header));
              IFEND;

              record_info.current_byte_address := block_info.current_block_byte_address +
                    file_instance^.global_file_information^.max_block_size;
              block_info.current_block_byte_address := record_info.current_byte_address;
            IFEND;

{ Check to make sure we do not go over the 2 GB file limit.

            IF file_instance^.global_file_information^.file_limit < record_info.current_byte_address +
                  #SIZE (bat$block_header) + file_instance^.global_file_information^.max_record_length THEN
              amp$set_file_instance_abnormal (file_identifier, ame$put_beyond_file_limit,
                    call_block.operation, error_text, status);
              EXIT /main_code_put_partial/; {----->
            IFEND;

            block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
                  block_info.current_block_byte_address);
*copy       bai$write_block_header
          IFEND; { rbl < maxrl }
          record_info.bor_address := record_info.current_byte_address;
        IFEND; { NOT mid_record }

        record_info.residual_record_length := record_info.bor_address +
              file_instance^.global_file_information^.max_record_length - record_info.current_byte_address;
        IF call_block.putp.working_storage_length > record_info.residual_record_length THEN
          record_info.record_length := record_info.residual_record_length;
        ELSE
          record_info.record_length := call_block.putp.working_storage_length;
        IFEND;

{ Before starting a record make sure a fixed length record can be written.

        IF file_instance^.global_file_information^.file_limit <
              record_info.bor_address + record_info.record_length THEN
          amp$set_file_instance_abnormal (file_identifier, ame$put_beyond_file_limit, call_block.operation,
                error_text, status);
          EXIT /main_code_put_partial/; {----->
        IFEND;

        data_ptr := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
              record_info.current_byte_address);

        i#move (call_block.putp.working_storage_area, data_ptr, record_info.record_length);
        record_info.current_byte_address := record_info.current_byte_address + record_info.record_length;
        record_info.residual_record_length := record_info.residual_record_length - record_info.record_length;

        file_instance^.instance_of_open_modified := TRUE;
        IF call_block.putp.term_option = amc$terminate THEN
          IF record_info.residual_record_length <> 0 THEN
            pad_record;
          IFEND;
          record_info.file_position := amc$eor;
*copy     bai$update_eoi
        ELSE
          record_info.file_position := amc$mid_record;
        IFEND;

        record_info.record_length := record_info.current_byte_address - record_info.bor_address;

        IF (record_info.current_byte_address >= file_instance^.global_file_information^.eoi_byte_address) OR
              (file_instance^.instance_attributes.static_label.file_organization <> amc$byte_addressable) THEN
          block_header^.block_length := record_info.current_byte_address -
                (block_info.current_block_byte_address + #SIZE (bat$block_header));
        IFEND;
      END /main_code_put_partial/;

      file_instance^.global_file_information^.positioning_info.block_info := block_info;
      file_instance^.global_file_information^.positioning_info.record_info := record_info;

      call_block.putp.byte_address^ := record_info.bor_address;

    PROCEND put_partial;
?? OLDTITLE ??
?? NEWTITLE := '[dnline] SKIP', EJECT ??

    PROCEDURE [INLINE] skip;

      VAR
        skip_count: integer;

*copy bai$get_positioning_info

      skip_count := call_block.skp.count;
      IF file_instance^.instance_attributes.static_label.file_organization <> amc$sequential THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_fo, call_block.operation, error_text,
              status);
        RETURN; {----->
      ELSEIF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

    /main_code_skip/
      BEGIN
        block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
              block_info.current_block_byte_address);
        IF block_info.current_block_byte_address < file_instance^.global_file_information^.
              eoi_byte_address THEN
*copy     bai$validate_block_header
          IF NOT status.normal THEN
            EXIT /main_code_skip/; {----->
          IFEND;
        IFEND;

        CASE call_block.skp.direction OF
        = amc$forward =

{ Start by doing a skip of 0.

          IF record_info.file_position = amc$mid_record THEN
            record_info.current_byte_address := record_info.bor_address +
                  file_instance^.global_file_information^.max_record_length;
            record_info.bor_address := record_info.current_byte_address;
            record_info.file_position := amc$eor;
          ELSEIF record_info.current_byte_address = 0 THEN
            record_info.current_byte_address := #SIZE (bat$block_header);
            record_info.bor_address := record_info.current_byte_address;
          IFEND;

          block_info.residual_block_length := block_info.current_block_byte_address +
                block_header^.block_length + #SIZE (bat$block_header) - record_info.current_byte_address;

          IF skip_count > 0 THEN
            WHILE (skip_count > 0) AND (record_info.current_byte_address <
                  file_instance^.global_file_information^.eoi_byte_address) DO

              IF block_info.residual_block_length < file_instance^.global_file_information^.
                    max_record_length THEN
                IF block_info.current_block_byte_address + file_instance^.global_file_information^.
                      max_block_size <= file_instance^.global_file_information^.eoi_byte_address THEN
                  block_info.current_block_byte_address := block_info.current_block_byte_address +
                        file_instance^.global_file_information^.max_block_size;
                  record_info.current_byte_address := block_info.current_block_byte_address;
                  IF record_info.current_byte_address < file_instance^.global_file_information^.
                        eoi_byte_address THEN
                    block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
                          block_info.current_block_byte_address);
*copy               bai$validate_block_header
                    IF NOT status.normal THEN
                      EXIT /main_code_skip/; {----->
                    IFEND;
                    block_info.residual_block_length := block_header^.block_length;
                    record_info.current_byte_address := record_info.current_byte_address +
                          #SIZE (bat$block_header);
                  IFEND;
                IFEND; { new cbba < eoi }
              IFEND; { rbl < maxrl }

              IF record_info.current_byte_address < file_instance^.global_file_information^.
                    eoi_byte_address THEN
                record_info.current_byte_address := record_info.current_byte_address +
                      file_instance^.global_file_information^.max_record_length;
                block_info.residual_block_length := block_info.residual_block_length -
                      file_instance^.global_file_information^.max_record_length;
                skip_count := skip_count - 1;
              IFEND;
            WHILEND;

            IF skip_count = 0 THEN
              record_info.file_position := amc$eor;
            ELSE
              amp$set_file_instance_abnormal (file_identifier, ame$skip_encountered_eoi, amc$skip_req,
                    ' RECORDS', status);
              record_info.file_position := amc$eoi;
            IFEND;
          IFEND;
          file_instance^.residual_skip_count := skip_count;

        = amc$backward =

{ Start with skip or 0 backward to the start of a fixed record.

          IF record_info.file_position = amc$mid_record THEN
            record_info.current_byte_address := record_info.bor_address;
            record_info.current_byte_address := record_info.current_byte_address;
            record_info.file_position := amc$eor;
          IFEND;

          IF skip_count > 0 THEN
            WHILE (skip_count > 0) AND (record_info.current_byte_address > #SIZE (bat$block_header)) DO
              IF record_info.current_byte_address - #SIZE (bat$block_header) <=
                    block_info.current_block_byte_address THEN
                block_info.current_block_byte_address := block_info.current_block_byte_address -
                      file_instance^.global_file_information^.max_block_size;
                block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
                      block_info.current_block_byte_address);
*copy           bai$validate_block_header
                IF NOT status.normal THEN
                  EXIT /main_code_skip/; {----->
                IFEND;

{ Position to end of data in new block.

                record_info.current_byte_address := block_info.current_block_byte_address +
                      #SIZE (bat$block_header) + block_header^.block_length;
              IFEND;

              record_info.current_byte_address := record_info.current_byte_address -
                    file_instance^.global_file_information^.max_record_length;
              skip_count := skip_count - 1;
            WHILEND;

            IF skip_count = 0 THEN
              record_info.file_position := amc$eor;
            ELSE
              record_info.file_position := amc$boi;
              record_info.current_byte_address := 0;
              amp$set_file_instance_abnormal (file_identifier, ame$skip_encountered_boi, amc$skip_req,
                    ' RECORDS', status);
            IFEND;
          IFEND;
          file_instance^.residual_skip_count := skip_count;

        ELSE
        CASEND; { skip_direction }
      END /main_code_skip/;
      call_block.skp.file_position^ := record_info.file_position;

*copy bai$save_positioning_info

    PROCEND skip;
?? OLDTITLE ??
?? NEWTITLE := '[inline] SEEK_DIRECT', EJECT ??

    PROCEDURE [INLINE] seek_direct;

      IF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

*copy bai$seek_validation
      IF NOT status.normal THEN
        RETURN; {----->
      IFEND;

      terminate_record;

*copy bai$get_positioning_info

      block_info.current_block_byte_address := (file_byte_address DIV
            file_instance^.global_file_information^.max_block_size) *
            file_instance^.global_file_information^.max_block_size;
      IF ((file_byte_address - (block_info.current_block_byte_address + #SIZE (bat$block_header))) MOD
            file_instance^.global_file_information^.max_record_length <> 0) OR
            (((file_byte_address - (block_info.current_block_byte_address + #SIZE (bat$block_header))) DIV
            file_instance^.global_file_information^.max_record_length) + 1 >=
            (file_instance^.global_file_information^.max_data_size DIV
            file_instance^.global_file_information^.max_record_length)) THEN

{ File_byte_address is not at the beginning of a record.

        amp$set_file_instance_abnormal (file_identifier, ame$improper_seek_address, call_block.operation,
              error_text, status);
        RETURN; {----->
      IFEND;

      record_info.bor_address := file_byte_address;
      record_info.current_byte_address := file_byte_address;
      record_info.file_position := amc$eor;

*copy bai$save_positioning_info

    PROCEND seek_direct;
?? OLDTITLE ??
?? NEWTITLE := '[inline] PAD_RECORD', EJECT ??

    PROCEDURE [INLINE] pad_record;

      record_info.residual_record_length := record_info.bor_address +
            file_instance^.global_file_information^.max_record_length - record_info.current_byte_address;

      IF record_info.residual_record_length > 0 THEN
        i := 1;
        wsa := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva), record_info.current_byte_address);
        record_info.current_byte_address := record_info.current_byte_address +
              record_info.residual_record_length;
        IF file_instance^.global_file_information^.padding_character = ' ' THEN
          default_padding_string := ' ';
          IF #SIZE (default_padding_string) > record_info.residual_record_length THEN
            i := record_info.residual_record_length;
          ELSE
            i := #SIZE (default_padding_string);
          IFEND;
          i#move (^default_padding_string, wsa, i);
          record_info.residual_record_length := record_info.residual_record_length - i;
        ELSE
          working_storage_area := wsa;
          working_storage_area^ := file_instance^.global_file_information^.padding_character;
          record_info.residual_record_length := record_info.residual_record_length - 1;
        IFEND;

        WHILE record_info.residual_record_length > 0 DO
          padding_area := #ADDRESS (osc$min_ring, #SEGMENT (wsa), (#OFFSET (wsa) + i));
          IF i <= record_info.residual_record_length THEN
            padding_length := i;
          ELSE
            padding_length := record_info.residual_record_length;
          IFEND;

          i#move (wsa, padding_area, padding_length);

          record_info.residual_record_length := record_info.residual_record_length - padding_length;
          i := i + padding_length;
        WHILEND;
      IFEND;

      record_info.file_position := amc$eor;

    PROCEND pad_record;
?? OLDTITLE ??
?? NEWTITLE := 'PAD_RECORD_PROC', EJECT ??

    PROCEDURE pad_record_proc;

      pad_record;

    PROCEND pad_record_proc;
?? OLDTITLE ??
?? NEWTITLE := 'REPLACE_RECORD', EJECT ??

    PROCEDURE replace_record;

      IF file_instance^.access_level <> amc$record THEN
        amp$set_file_instance_abnormal (file_identifier, ame$conflicting_access_level, call_block.operation,
              error_text, status);
        RETURN; {----->
      ELSEIF NOT ((file_instance^.global_file_information^.positioning_info.record_info.file_position <>
            amc$mid_record) AND (file_instance^.global_file_information^.positioning_info.record_info.
            current_byte_address > 0)) THEN
        amp$set_file_instance_abnormal (file_identifier, ame$improper_file_position, call_block.operation,
              error_text, status);
        RETURN; {----->
      ELSEIF (call_block.putn.working_storage_length < 0) OR
            (call_block.putn.working_storage_length > UPPERVALUE (amt$working_storage_length)) THEN
        amp$set_file_instance_abnormal (file_identifier, ame$improper_wsl_value, call_block.operation,
              error_text, status);
        RETURN; {----->
      ELSEIF caller_id.ring > file_instance^.instance_attributes.static_label.ring_attributes.r1 THEN
        amp$set_file_instance_abnormal (file_identifier, ame$ring_validation_error, call_block.operation,
              error_text, status);
        RETURN; {----->
      ELSEIF NOT (pfc$modify IN file_instance^.instance_attributes.dynamic_label.access_mode) THEN
        amp$set_file_instance_abnormal (file_identifier, ame$improper_access_attempt, call_block.operation,
              ' MODIFY', status);
        RETURN; {----->
      IFEND;

      record_info := file_instance^.global_file_information^.positioning_info.record_info;
      record_info.current_byte_address := record_info.bor_address;

      IF call_block.replace.working_storage_length > file_instance^.global_file_information^.
            max_record_length THEN
        record_info.record_length := file_instance^.global_file_information^.max_record_length;
      ELSE
        record_info.record_length := call_block.replace.working_storage_length;
      IFEND;

      data_ptr := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
            record_info.current_byte_address);

      i#move (call_block.putn.working_storage_area, data_ptr, record_info.record_length);

      record_info.current_byte_address := record_info.current_byte_address + record_info.record_length;
      file_instance^.instance_of_open_modified := TRUE;

      pad_record_proc;

      file_instance^.global_file_information^.positioning_info.record_info := record_info;

    PROCEND replace_record;
?? OLDTITLE ??
?? NEWTITLE := 'TERMINATE_RECORD', EJECT ??

    PROCEDURE terminate_record;

      IF (file_instance^.private_read_information = NIL) AND
            (file_instance^.global_file_information^.last_access_operation = amc$put_partial_req) AND
            (file_instance^.global_file_information^.positioning_info.record_info.file_position =
            amc$mid_record) THEN

        block_info := file_instance^.global_file_information^.positioning_info.block_info;
        record_info := file_instance^.global_file_information^.positioning_info.record_info;

        pad_record_proc;

        IF (record_info.current_byte_address >= file_instance^.global_file_information^.eoi_byte_address) OR
              (file_instance^.instance_attributes.static_label.file_organization <> amc$byte_addressable) THEN
          block_header := #ADDRESS (osc$min_ring, #SEGMENT (file_instance^.file_pva),
                block_info.current_block_byte_address);
          block_header^.block_length := record_info.current_byte_address -
                (block_info.current_block_byte_address + #SIZE (bat$block_header));
          update_eoi;
        IFEND;

        file_instance^.global_file_information^.positioning_info.block_info := block_info;
        file_instance^.global_file_information^.positioning_info.record_info := record_info;
      IFEND; { mid_record, putp, global }

    PROCEND terminate_record;
?? OLDTITLE ??
?? NEWTITLE := 'UPDATE_EOI', EJECT ??

    PROCEDURE update_eoi;

*copy bai$update_eoi

    PROCEND update_eoi;
?? OLDTITLE ??
?? EJECT ??

    #CALLER_ID (caller_id);
    status.normal := TRUE;

  /process_fap_request/
    BEGIN
      file_instance := baf$task_file_entry_p (file_identifier);
      IF file_instance = NIL THEN
        osp$set_status_abnormal (amc$access_method_id, ame$improper_file_id, error_text, status);
        RETURN; {----->
      IFEND;

      file_instance^.rollback_procedure := ^rollback_procedure;
      CASE call_block.operation OF
      = amc$get_next_req =
        get_next;
      = amc$put_next_req =
        put_next;
      = amc$get_partial_req =
        get_partial;
      = amc$put_partial_req =
        put_partial;
      = amc$open_req =
        CASE file_instance^.instance_attributes.dynamic_label.open_position OF
        = amc$open_at_boi =
*copy     bai$get_positioning_info
          block_info := bav$default_block_info;
*copy       bai$save_positioning_info
        = amc$open_at_eoi =
*copy     bai$get_positioning_info
          block_info.current_block_byte_address := (record_info.current_byte_address DIV
                file_instance^.global_file_information^.max_block_size) *
                file_instance^.global_file_information^.max_block_size;
*copy     bai$save_positioning_info
        ELSE
        CASEND;
      = amc$close_req =
        terminate_record;
        bap$close (file_identifier, status);
        EXIT /process_fap_request/; {----->
      = amc$rewind_req =
        terminate_record;
*copy   bai$rewind
      = amc$seek_direct_req =
        file_byte_address := call_block.seekd.byte_address;
        seek_direct;
      = amc$get_direct_req =
        file_byte_address := call_block.getd.byte_address;
        seek_direct;
        IF NOT status.normal THEN
          IF status.condition = ame$position_beyond_eoi THEN
            status.condition := ame$input_after_eoi;
          IFEND;
        ELSE
          get_next;
        IFEND;
      = amc$put_direct_req =
        file_byte_address := call_block.putd.byte_address;
        seek_direct;
        IF status.normal THEN
          put_next;
        IFEND;
      = amc$skip_req =
        IF call_block.skp.unit <> amc$skip_record THEN
          amp$set_file_instance_abnormal (file_identifier, ame$unsupported_skip, call_block.operation, ' ',
                status);
        ELSE
          terminate_record;
          skip;
        IFEND;
      = amc$fetch_access_information_rq =
        bap$fetch_access_information (file_identifier, call_block, layer_number, status);
        EXIT /process_fap_request/; {----->
      = amc$fetch_req =
        bap$fetch (file_identifier, call_block, layer_number, status);
        EXIT /process_fap_request/; {----->
      = amc$get_segment_pointer_req =
        bap$get_segment_pointer (file_identifier, call_block, layer_number, status);
      = amc$set_segment_eoi_req =
        bap$set_segment_eoi (file_identifier, call_block, layer_number, status);
      = amc$set_segment_position_req =
        bap$set_segment_position (file_identifier, call_block, layer_number, status);
      = amc$replace_req =
        replace_record;
      = amc$store_req =
        bap$store (file_identifier, call_block, layer_number, status);
      = amc$write_end_partition_req =
        amp$set_file_instance_abnormal (file_identifier, ame$unsupported_operation, call_block.operation,
              error_text, status);
      = amc$write_tape_mark_req, amc$close_volume_req =
        amp$set_file_instance_abnormal (file_identifier, ame$improper_device_class, call_block.operation,
              'MASS_STORAGE', status);
      = amc$flush_req =
        bap$write_modified_pages (file_instance, file_identifier, status);
      = ifc$fetch_terminal_req, ifc$store_terminal_req =
        IF pmf$job_mode () = jmc$batch THEN
          osp$set_status_abnormal (ifc$interactive_facility_id, ife$current_job_not_interactive,
                'FETCH/STORE_TERMINAL_REQ', status);
        ELSE
          amp$set_file_instance_abnormal (file_identifier, ame$improper_device_class, call_block.operation,
                'MASS STORAGE', status);
        IFEND;
      ELSE
        amp$set_file_instance_abnormal (file_identifier, ame$unimplemented_request, call_block.operation,
              ' for sequential or byte addressable files', status);
      CASEND;

      IF file_instance^.private_read_information = NIL THEN
        IF status.normal THEN
          file_instance^.global_file_information^.error_status := 0;
        ELSE
          file_instance^.global_file_information^.error_status := status.condition;
        IFEND;
        file_instance^.global_file_information^.last_access_operation := call_block.operation;
      ELSE
        IF status.normal THEN
          file_instance^.private_read_information^.error_status := 0;
        ELSE
          file_instance^.private_read_information^.error_status := status.condition;
        IFEND;
        file_instance^.private_read_information^.last_access_operation := call_block.operation;
      IFEND;
    END /process_fap_request/;

    file_instance^.rollback_procedure := NIL;

  PROCEND bap$us_blk_fixed_rec_fap;
?? OLDTITLE ??
MODEND bam$us_blk_fixed_rec_fap;
