
  PROCEDURE [INLINE] bap$verify_file_connection_attr (verify_for_open: boolean;
        subject_file_name: amt$local_file_name;
        target_file_name: amt$local_file_name;
        subject_contents: amt$file_contents;
        target_contents: amt$file_contents;
        subject_structure: amt$file_structure;
        target_structure: amt$file_structure;
    VAR status: ost$status);

    status.normal := TRUE;

    IF (subject_contents <> target_contents) AND (subject_contents <>
          amc$unknown_contents) AND (target_contents <> amc$unknown_contents)
          THEN
      IF verify_for_open THEN
        amp$set_local_name_abnormal (subject_file_name,
              ame$incompatible_file_connect, amc$open_req, target_file_name,
              status);
      ELSE
        osp$set_status_abnormal ('CL', cle$incompatible_file_connect,
              subject_file_name, status);
        osp$append_status_parameter (osc$status_parameter_delimiter,
              target_file_name, status);
      IFEND;
      osp$append_status_parameter (osc$status_parameter_delimiter,
        'FILE_CONTENTS', status);
    IFEND;

    IF (subject_structure <> target_structure) AND (subject_structure <>
          amc$unknown_structure) AND (target_structure <>
          amc$unknown_structure) THEN
      IF status.normal THEN
        IF verify_for_open THEN
          amp$set_local_name_abnormal (subject_file_name,
                ame$incompatible_file_connect, amc$open_req, target_file_name,
                status);
        ELSE
          osp$set_status_abnormal ('CL', cle$incompatible_file_connect,
                subject_file_name, status);
          osp$append_status_parameter (osc$status_parameter_delimiter,
                target_file_name, status);
        IFEND;
        osp$append_status_parameter (osc$status_parameter_delimiter,
          'FILE_STRUCTURE', status);
      ELSE
        osp$append_status_parameter (' ', 'FILE_STRUCTURE', status);
      IFEND;
    IFEND;

  PROCEND bap$verify_file_connection_attr;

?? PUSH (LISTEXT := ON) ??
*copyc amc$condition_code_limits
*copyc amt$file_contents
*copyc amt$file_structure
*copyc ame$open_validation_errors
*copyc amt$local_file_name
*copyc cle$ecc_connected_file
*copyc ost$status
?? POP ??
*copyc amp$set_local_name_abnormal
*copyc osp$append_status_parameter
*copyc osp$set_status_abnormal
