?? RIGHT := 110 ??
?? NEWTITLE := 'NOS/VE SCL Interpreter : Assign Device Command' ??
MODULE clm$assign_device_command;

{  PURPOSE:
{    This module contains the processor for the ASSIGN_DEVICE command.
{

?? NEWTITLE := 'Global Declarations Referenced by This Module', EJECT ??

?? PUSH (LISTEXT := ON) ??
*copyc cle$ecc_file_reference
*copyc jmt$system_supplied_name
*copyc rmc$condition_code_limits
?? POP ??

*copyc clp$evaluate_parameters
*copyc iop$assign_device_command
*copyc jmp$validate_name
*copyc osp$set_status_abnormal
*copyc osp$append_status_parameter
*copyc osv$lower_to_upper
*copyc rmp$validate_ansi_string

?? OLDTITLE ??
?? NEWTITLE := 'clp$assign_device_command', EJECT ??

  PROCEDURE [XDCL, #GATE] clp$assign_device_command
    (    parameter_list: clt$parameter_list;
     VAR status: ost$status);

{   PROCEDURE (clm$assd) assign_device, assd (
{     element_name, en, element, e: name = $required
{     external_vsn, evsn, ev: any of
{         string 1..6
{         name 1..6
{     anyend = $required
{     job_name, jn : name = $optional
{     status)

?? PUSH (LISTEXT := ON) ??
?? FMT (FORMAT := OFF) ??

  VAR
    pdt: [STATIC, READ, cls$declaration_section] record
      header: clt$pdt_header,
      names: array [1 .. 10] of clt$pdt_parameter_name,
      parameters: array [1 .. 4] of clt$pdt_parameter,
      type1: record
        header: clt$type_specification_header,
        qualifier: clt$name_type_qualifier,
      recend,
      type2: record
        header: clt$type_specification_header,
        qualifier: clt$union_type_qualifier,
        type_size_1: clt$type_specification_size,
        element_type_spec_1: record
          header: clt$type_specification_header,
          qualifier: clt$string_type_qualifier,
        recend,
        type_size_2: clt$type_specification_size,
        element_type_spec_2: record
          header: clt$type_specification_header,
          qualifier: clt$name_type_qualifier,
        recend,
      recend,
      type3: record
        header: clt$type_specification_header,
        qualifier: clt$name_type_qualifier,
      recend,
      type4: record
        header: clt$type_specification_header,
      recend,
    recend := [
    [1,
    [92, 11, 19, 13, 16, 7, 931],
    clc$command, 10, 4, 2, 0, 0, 0, 4, 'CLM$ASSD'], [
    ['E                              ',clc$abbreviation_entry, 1],
    ['ELEMENT                        ',clc$alias_entry, 1],
    ['ELEMENT_NAME                   ',clc$nominal_entry, 1],
    ['EN                             ',clc$alias_entry, 1],
    ['EV                             ',clc$abbreviation_entry, 2],
    ['EVSN                           ',clc$alias_entry, 2],
    ['EXTERNAL_VSN                   ',clc$nominal_entry, 2],
    ['JN                             ',clc$abbreviation_entry, 3],
    ['JOB_NAME                       ',clc$nominal_entry, 3],
    ['STATUS                         ',clc$nominal_entry, 4]],
    [
{ PARAMETER 1
    [3, clc$normal_usage_entry, clc$non_secure_parameter,
    $clt$parameter_spec_methods[clc$specify_by_name, clc$specify_positionally],
    clc$pass_by_value, clc$immediate_evaluation,
  clc$standard_parameter_checking, 5, clc$required_parameter, 0, 0],
{ PARAMETER 2
    [7, clc$normal_usage_entry, clc$non_secure_parameter,
    $clt$parameter_spec_methods[clc$specify_by_name, clc$specify_positionally],
    clc$pass_by_value, clc$immediate_evaluation,
  clc$standard_parameter_checking, 33, clc$required_parameter, 0, 0],
{ PARAMETER 3
    [9, clc$normal_usage_entry, clc$non_secure_parameter,
    $clt$parameter_spec_methods[clc$specify_by_name, clc$specify_positionally],
    clc$pass_by_value, clc$immediate_evaluation,
  clc$standard_parameter_checking, 5, clc$optional_parameter, 0, 0],
{ PARAMETER 4
    [10, clc$normal_usage_entry, clc$non_secure_parameter,
    $clt$parameter_spec_methods[clc$specify_by_name],
    clc$pass_by_reference, clc$immediate_evaluation,
  clc$standard_parameter_checking, 3, clc$optional_parameter, 0, 0]],
{ PARAMETER 1
    [[1, 0, clc$name_type], [1, osc$max_name_size]],
{ PARAMETER 2
    [[1, 0, clc$union_type], [[clc$name_type, clc$string_type],
    TRUE, 2],
    8, [[1, 0, clc$string_type], [1, 6, FALSE]],
    5, [[1, 0, clc$name_type], [1, 6]]
    ],
{ PARAMETER 3
    [[1, 0, clc$name_type], [1, osc$max_name_size]],
{ PARAMETER 4
    [[1, 0, clc$status_type]]];

?? FMT (FORMAT := ON) ??
?? POP ??

    CONST
      p$element_name = 1,
      p$external_vsn = 2,
      p$job_name = 3,
      p$status = 4;

    VAR
      pvt: array [1 .. 4] of clt$parameter_value;

    VAR
      candidate_job_name: jmt$name,
      element_name: ost$name,
      external_vsn: rmt$external_vsn,
      job_name: jmt$system_supplied_name,
      verified_job_name: jmt$name,
      vsn_string: ost$string;

    clp$evaluate_parameters (parameter_list, #SEQ (pdt), NIL, ^pvt, status);
    IF NOT status.normal THEN
      RETURN;
    IFEND;

    element_name := pvt [p$element_name].value^.name_value;

    IF pvt [p$external_vsn].value^.kind = clc$string THEN
      external_vsn := pvt [p$external_vsn].value^.string_value^;
    ELSEIF pvt [p$external_vsn].value^.kind = clc$name THEN
      external_vsn := pvt [p$external_vsn].value^.name_value;
    IFEND;
    rmp$validate_ansi_string (external_vsn, external_vsn, status);
    IF NOT status.normal THEN
      osp$set_status_abnormal (rmc$resource_management_id, cle$improper_vsn_value, external_vsn, status);
      osp$append_status_parameter (osc$status_parameter_delimiter, 'EXTERNAL_VSN', status);
      RETURN;
    IFEND;

    IF pvt [p$job_name].specified THEN
      candidate_job_name.kind := jmc$system_supplied_name;
      candidate_job_name.system_supplied_name := pvt [p$job_name].value^.name_value;
      jmp$validate_name (candidate_job_name, verified_job_name, status);
      IF NOT status.normal THEN
        RETURN;
      IFEND;
      job_name := verified_job_name.system_supplied_name;
    ELSE
      job_name := jmc$blank_system_supplied_name;
    IFEND;

    iop$assign_device_command (job_name, element_name, external_vsn, status);

  PROCEND clp$assign_device_command;

MODEND clm$assign_device_command;
