?? RIGHT := 110 ??
?? NEWTITLE := 'NOS/VE SCL Interpreter: Default UNSEEN_MAIL Condition Handler' ??
MODULE clm$default_unseen_mail_handler;

{
{ PURPOSE:
{   This module contains the default unseen_mail condition handler.
{

?? NEWTITLE := 'Global Declarations Referenced in this Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc clc$standard_file_names
*copyc cle$unseen_mail_condition
*copyc clt$unseen_mail_action
*copyc clt$when_conditions
*copyc ost$status
*copyc pmt$condition
?? POP ??
*copyc amp$flush
*copyc clp$find_unseen_mail_action
*copyc clp$get_system_file_id
*copyc osp$generate_message
*copyc osp$set_status_condition
*copyc pmp$post_unseen_mail
?? OLDTITLE ??
?? NEWTITLE := '[XDCL] clp$default_unseen_mail_handler', EJECT ??

{
{ PURPOSE:
{   This procedure is the default unseen_mail condition handler.
{

  PROCEDURE [XDCL] clp$default_unseen_mail_handler
    (    ignore_condition: pmt$condition;
     VAR status: ost$status);

    VAR
      action: ^clt$unseen_mail_action,
      condition_status: ost$status,
      file_id: amt$file_identifier;


    status.normal := TRUE;

    clp$find_unseen_mail_action (action);
    IF action^ = clc$post_unseen_mail THEN
      pmp$post_unseen_mail;
      RETURN;
    IFEND;

    osp$set_status_condition (cle$unseen_mail_condition, condition_status);
    osp$generate_message (condition_status, status);
    IF NOT status.normal THEN
      RETURN;
    IFEND;
    clp$get_system_file_id (clc$job_command_response, file_id, status);
    IF NOT status.normal THEN
      RETURN;
    IFEND;
    amp$flush (file_id, osc$wait, status);

  PROCEND clp$default_unseen_mail_handler;

MODEND clm$default_unseen_mail_handler;
