
  PROCEDURE [INLINE] clp$recognize_cobol_name
    (    text: clt$string_value;
     VAR cobol_name_size: ost$name_size;
     VAR is_only_cobol_name: boolean;
     VAR is_cobol_name: boolean);

?? PUSH (LISTEXT := ON) ??

    VAR
      ignore_scan_found_char: boolean,
      scan_index: integer;

    #SCAN (clv$non_cobol_name_char, text, scan_index, ignore_scan_found_char);
    IF (1 <= (scan_index - 1)) AND ((scan_index - 1) <=
          clc$max_cobol_name_size) AND (text (1) <> '-') AND
          (text (scan_index - 1) <> '-') THEN
      cobol_name_size := scan_index - 1;
      IF ('0' <= text (1)) AND (text (1) <= '9') THEN
        #SCAN (clv$letter_char, text (1, cobol_name_size), scan_index,
              is_cobol_name);
        is_only_cobol_name := is_cobol_name;
      ELSE
        is_cobol_name := TRUE;
        #SCAN (clv$non_letter_or_digit, text (1, cobol_name_size), scan_index,
              is_only_cobol_name);
      IFEND;
    ELSE
      is_cobol_name := FALSE;
      is_only_cobol_name := FALSE;
    IFEND;

  PROCEND clp$recognize_cobol_name;

*copyc clc$max_cobol_name_size
*copyc clt$string_value
*copyc ost$name
?? POP ??
*copyc clv$letter_char
*copyc clv$non_cobol_name_char
*copyc clv$non_letter_or_digit
