
{
{ CLP$SCAN_TO_LEXICAL_LIMIT is called to advance its PARSE parameter to its
{ established limit (usually to "end of line").
{ This procedure requires that the UNITS_ARRAY field of the PARSE parameter be
{ non-NIL.
{

  PROCEDURE [INLINE] clp$scan_to_lexical_limit
    (VAR parse {input, output} : clt$parse_state);

?? PUSH (LISTEXT := ON) ??


    WHILE parse.unit_index < parse.index_limit DO
      IF NOT parse.unit_is_space THEN
        parse.previous_non_space_unit := parse.unit;
        parse.previous_non_space_unit_index := parse.unit_index;
      IFEND;

      parse.previous_unit_is_space := parse.unit_is_space;
      parse.unit_index := parse.index;
      parse.units_array_index := parse.units_array_index + 1;
      parse.unit := parse.units_array^ [parse.units_array_index];
      parse.index := parse.index + parse.unit.size;

      parse.unit_is_space := parse.unit.kind IN
            $clt$lexical_unit_kinds [clc$lex_space, clc$lex_comment,
            clc$lex_unterminated_comment];
    WHILEND;

    IF parse.unit.kind = clc$lex_beginning_of_line THEN
      parse.units_array_index := 2;
      parse.unit.kind := clc$lex_end_of_line;
    IFEND;

  PROCEND clp$scan_to_lexical_limit;

*copyc clt$lexical_unit_kinds
*copyc clt$parse_state
?? POP ??
