
  PROCEDURE [INLINE] clp$search_dictionary_for_code
    (    library: ^SEQ ( * );
         message_module_dictionary: ^llt$message_module_dictionary;
         natural_language: ost$natural_language;
         search_by_language: boolean;
         code: ost$status_condition_code;
     VAR name: ost$status_condition_name;
     VAR severity: ost$message_module_severity;
     VAR template: ^ost$message_template;
     VAR entry_found: boolean;
     VAR saved_default: boolean);

?? PUSH (LISTEXT := ON) ??

    VAR
      language: ost$natural_language,
      ignore_status: ost$status,
      index: llt$message_module_index,
      member_header: ^llt$library_member_header,
      message_module: ^ost$message_template_module;

  /search_dictionary/
    FOR index := 1 TO UPPERBOUND (message_module_dictionary^) DO
      IF NOT ((message_module_dictionary^ [index].lowest_condition_code <=
            code) AND (code <= message_module_dictionary^ [index].
            highest_condition_code)) THEN
        CYCLE /search_dictionary/;
      IFEND;
      IF search_by_language THEN
        language := message_module_dictionary^ [index].language;
        IF ((language = osc$default_natural_language) AND saved_default) OR
              ((language <> natural_language) AND
              (language <> osc$default_natural_language)) THEN
          CYCLE /search_dictionary/;
        IFEND;
      IFEND;
      member_header := #PTR (message_module_dictionary^ [index].message_header,
            library^);
      message_module := #PTR (member_header^.member, library^);
      RESET message_module;
      clp$search_module_for_code (message_module, code, language, name,
            severity, template, entry_found, ignore_status);
      IF entry_found THEN
        IF (NOT search_by_language) OR (language = natural_language) THEN
          RETURN;
        IFEND;
        saved_default := TRUE;
        entry_found := FALSE;
      IFEND;
    FOREND /search_dictionary/;

  PROCEND clp$search_dictionary_for_code;

*copyc llt$library_member_header
*copyc llt$message_module_dictionary
*copyc ost$message_module_severity
*copyc ost$message_template
*copyc ost$message_template_module
*copyc ost$natural_language
*copyc ost$status
*copyc ost$status_condition_code
*copyc ost$status_condition_name
?? POP ??
*copyc clp$search_module_for_code
