
   PROCEDURE [INLINE] cmp$convert_pp_number (pp_number : dst$iou_resource;
      VAR pp_ordinal : cmt$pp_ordinal);
  {
  {  PURPOSE : Convert a pp number into its equivalent
  {     pp ordinal type. Note, when deleting the type
  {     cmt$pp_ordinal, this procedure will be changed or
  {     potentially deleted.
  {

      IF pp_number.channel_protocol = dsc$cpt_cio THEN
        IF pp_number.number <= 9 THEN
          FOR pp_ordinal := cmc$cio_pp0 TO cmc$cio_pp9 DO
            IF (pp_number.number = ($INTEGER (pp_ordinal) - $INTEGER(cmc$cio_pp0))) THEN
              RETURN;
            IFEND;
          FOREND;
        ELSE
          FOR pp_ordinal := cmc$cio_pp16 TO UPPERVALUE(cmt$pp_ordinal) DO
            IF (pp_number.number = ($INTEGER (pp_ordinal) - $INTEGER(cmc$cio_pp0)) + 6) THEN
              RETURN;
            IFEND;
          FOREND;
        IFEND;
      ELSE
        IF pp_number.number > 9 THEN
          FOR pp_ordinal := cmc$pp10 TO cmc$pp19 DO
            IF ($INTEGER (pp_ordinal) = (pp_number.number - 6)) THEN
              RETURN;
            IFEND;
          FOREND;
        ELSE
          FOR pp_ordinal := cmc$pp0 TO cmc$pp9 DO
            IF ($INTEGER (pp_ordinal) = pp_number.number) THEN
              RETURN;
            IFEND;
          FOREND;
        IFEND;
      IFEND;
    PROCEND cmp$convert_pp_number;

?? PUSH (LISTEXT := ON) ??
*copyc cmt$pp_ordinal
*copyc dst$iou_resource
?? POP ??
