          CTEXT  CTP$CONVERT DIGITS TO ASCII
          SPACE  4,10
          BASE   M
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC. 1992
 CDA      SPACE  4,10
**        CDA - CONVERT TWO DIGITS TO ASCII.
*
*         ENTRY (A) = NUMBER TO CONVERT.
*
*         EXIT   (A) = ASCII REPRESENTATION OF NUMBER.
*
*         USES   T1.
*
*         CALLS  CSD.


 CDA      SUBR               ENTRY/EXIT
          STD    T0          SAVE CONSTANT
          SHN    -4
          RJM    CSD         CONVERT SINGLE DIGIT
          SHN    10
          STDL   T1
          LDD    T0
          RJM    CSD         CONVERT SINGLE DIGIT
          LMDL   T1
          UJN    CDAX        RETURN
 CSD      SPACE  4,10
**        CSD - CONVERT SINGLE DIGIT.
*
*         ENTRY  (A) = NUMBER BETWEEN 0 AND 15.
*
*         EXIT   (A) = 10/0,8/ASCII REPRESENTATION OF NUMBER.


 CSD      SUBR               ENTRY/EXIT
          LPN    17
          SBN    10D
          MJN    CSD10       IF 0 - 9
          ADN    1RA-1R0-10D
 CSD10    ADN    1R0+10D
          UJN    CSDX        RETURN


          BASE   *

          ENDX
