 DPR      SPACE  4,10
**        DPR - DUMP S0/S0E PP REGISTERS.  THE PP REGISTERS DUMPED ARE P, A, D
*               AND K.
*
*         ENTRY  (A) = PP TYPE AND NUMBER.
*                (W4 - W7) = POINTER TO AREA FOR PP REGISTERS TO BE WRITTEN
*                IN MEMORY, R-POINTER FORMAT.
*
*         EXIT   PP REGISTERS WRITTEN TO SPECIFIED MEMORY.
*                (W4) = OFFSET IN R-POINTER UPDATED TO REFLECT WORDS WRITTEN.
*
*         CALLS  LRP, SPB.
*
*         USES   EC, RN, T1.


 DPR      SUBR               ENTRY/EXIT
          LDM    PPTN        GET PP NUMBER AND TYPE
          LPN    37          ISOLATE PP NUMBER
          ADC    S0IST       SET STATUS-1 REGISTER NUMBER
          STD    RN
          LDML   I0CC        SET CONNECT CODE
          STDL   EC

*         DUMP THE P, Q, K, A REGISTERS.  EACH REGISTER VALUE IS
*         SAVED IN 2 PP WORDS.

          READMR DPRC1       READ PP STATUS-1 REGISTER
          LDN    0#20        SET PP STATUS-2 REGISTER
          RAD    RN
          READMR DPRC2       READ PP STATUS-2 REGISTER
          LDML   DPRC2
          SHN    10
          ADML   DPRC2+1
          STML   DPRRS0+1    P-REGISTER
          LDML   DPRC1+1
          LPN    37
          STML   DPRRS0+3    D (OR Q)-REGISTER
          LDML   DPRC1+2
          LPC    0#7F
          STML   DPRRS0+5    K-REGISTER
          LDML   DPRC1+3
          SHN    -6
          STML   DPRRS0+6
          LDML   DPRC2+2
          SHN    10
          ADML   DPRC2+3
          STML   DPRRS0+7    A-REGISTER

*         LOAD R-REGISTER WITH POINTER TO MEMORY WHERE REGISTERS ARE TO BE SAVED.

          LRD    W5
          LDN    2           SET WORD COUNT (NO S-REGISTER)
          STD    T1
          LDDL   W4          OFFSET
          LMC    RR
          CWML   DPRRS0,T1   WRITE REGISTER BUFFER TO OUTPUT SEQUENCE
          LDN    2           UPDATE OFFSET IN R-POINTER
          RADL   W4
          LJM    DPRX        RETURN

 DPRC1    BSSZ   10          STATUS-1 BUFFER
 DPRC2    BSSZ   10          STATUS-2 BUFFER
 DPRRS0   BSSZ   14          OUTPUT REGISTER BUFFER

