**        SPP - SCAN PFS PARITY
*
*         METHOD             LOAD THE APPROPRIATE PFS BYTES OUT OF
*                            MAINTENANCE REGISTER BUFFER 0 AND MASK.
*                            IF PFS BIT IS SET, SET THE RESPECTIVE BIT
*                            IN CTIB TO INDICATE A PARITY ERROR IN A
*                            CONTROL MEMORY.
*
*         CALLED             BY RJM TO SPP
*
*         ENTRY              PFS REGISTERS ARE LOGGED IN MAINTENANCE
*                            REGISTER BUFFER 0
*
*         EXIT               (CTIB) :  A SET BIT INDICATES PARITY ERROR
*                                    IN RESPECTIVE CONTROL MEMORY.


 SPP      SUBR               ENTRY/EXIT
          LDN    0
          STML   CTIB        INITIALIZE
          STDL   T5          INDEXES TABLES
          LDN    1
          STDL   T6          SLIDING BIT - USED TO MASK CTIB
 SPP0     LDML   SPPA,T5     LOAD RGTR EQUATE TO MRB
          RJM    FMB         SET UP R-RGTR
          CRDL   CM          READ PFS WORD INTO CM
          LDML   SPPC,T5     LOAD CORRECT BYTE
          STDL   T1
          LDML   0,T1        LOAD BYTE OFFSET
          LPML   SPPB,T5     MASK
          ZJN    SPP1        IF NO PE
          LDDL   T6          SET APPROPRIATE BIT TO RELOAD MEMORY
          LMC    0#FFFF
          LPML   CTIB
          LMDL   T6
          STML   CTIB        SAVE BIT IN CTIB
 SPP1     AODL   T5
          SBN    8D
          ZJP    SPP2        IF CW2
          SBN    3
          ZJP    SPP2        IF BP32
          SBN    1
          ZJP    SPPX        IF DONE
          LDDL   T6
          SHN    1
          STDL   T6          SHIFT MASK BIT
 SPP2     LJM    SPP0        CHECK NEXT MEMORY


*         REGISTER EQUATE LIST

 SPPA     BSS    0
          CON    0#86
          CON    0#86
          CON    0#84
          CON    0#83
          CON    0#8E
          CON    0#8E
          CON    0#8A
          CON    0#81
          CON    0#81
          CON    0#81
          CON    0#86
          CON    0#86

*         PFS BIT MASK LIST.

 SPPB     BSS    0
          CON    0#0004
          CON    0#0002
          CON    0#0100
          CON    0#00C0
          CON    0#800E
          CON    0#FF00
          CON    0#00C6
          CON    0#FFFF
          CON    0#FF00
          CON    0#FFFF
          CON    0#0023
          CON    0#02C0

*         EQUATES HOLDING PP WORD OFFSETS
*         (IN RELATION TO CM)

 SPPC     BSS    0
          CON    OACUM2
          CON    OACUM3
          CON    OACUM4
          CON    OBDP
          CON    OEPN
          CON    OIMAP
          CON    OLSU
          CON    OCW1
          CON    OCW2
          CON    OCST
          CON    OBP31
          CON    OBP32

