          EJECT
*         CTEXT CTP$DFT_DUMP_REGISTERS_930
 DPR      SPACE  4,10
**        DPR - DUMP S0 PP REGISTERS.  THE PP REGISTERS DUMPED ARE P, A, D
*               AND K.
*
*         ENTRY  (PFEA) = PP TYPE AND NUMBER.
*                (W4 - W7) = POINTER TO AREA FOR PP REGISTERS TO BE WRITTEN
*                IN MEMORY, R-POINTER FORMAT.
*
*         EXIT   PP REGISTERS WRITTEN TO SPECIFIED MEMORY.
*                (W4) = OFFSET IN R-POINTER UPDATED TO REFLECT WORDS WRITTEN.
*
*         CALLS  LRP, SPB.
*
*         USES   EC, RN, T1.


 DPR      SUBR               ENTRY/EXIT
          LDM    PPTN        GET PP NUMBER AND TYPE
          LPN    0#1F        ISOLATE PP #
          STD    T1          SAVE PP #
          LDN    I0EC        PP 0 EC REG #
          ADD    T1          ADD PP #
          ADN    I0ST-I0EC   PP 0 STATUS 1 REG #
          STM    DPRSS0
          LDML   I0CC        IOU CONNECT CODE
          STDL   EC

*         DUMP THE P, A, D AND K PP REGISTERS.  EACH REGISTER VALUE IS
*         SAVED IN 2 PP WORDS.

          LDM    DPRSS0      GET PP STATUS 1 REG #
          STD    RN
          READMR DPRC1       READ PP STATUS 1 REG
          LDD    RN          GET PP STATUS 1 REG #
          ADN    40          PP STATUS 2 REG #
          STD    RN
          READMR DPRC2       READ PP STATUS 2 REG
          LDML   DPRC2
          SHN    10
          ADML   DPRC2+1
          STML   DPRRS0+1    P REG
          LDML   DPRC1+3
          SHN    -6
          STML   DPRRS0+2
          LDML   DPRC2+2
          SHN    10
          ADML   DPRC2+3
          STML   DPRRS0+3    A REG
          LDML   DPRC1+1
          LPN    37
          STML   DPRRS0+5    D REG
          LDML   DPRC1+2
          LPC    0#7F
          STML   DPRRS0+7    K REG
          LDML   DPRC1+3
          LPN    37
          STML   DPRRS0+11   S REG

*         LOAD R-REGISTER WITH POINTER TO MEMORY WHERE REGISTERS ARE TO BE SAVED.

          LRD    W5
          LDN    2           S REG NOT DUMPED INITIALLY
          STD    T1          WORD COUNT FOR REGISTER BUFFER SIZE
          LDDL   W4          OFFSET
          LMC    RR
          CWML   DPRRS0,T1   WRITE REGISTER BUFFER TO OUTPUT SEQUENCE
          LDN    2           UPDATE OFFSET IN R POINTER
          RADL   W4
          UJP    DPRX        RETURN

 DPRC1    BSSZ   10          STATUS REGISTER 1 BUFFER
 DPRC2    BSSZ   10          STATUS REGISTER 2 BUFFER
 DPRRS0   BSSZ   14          OUTPUT REGISTER BUFFER
 DPRSS0   CON    0           PP STATUS 1 REGISTER NUMBER

*         END CTP$DFT_DUMP_PP_REGISTERS
