*         CTEXT  CTP$DFT_FIND_WARNING_IN_NRSB
*
 FWE      SPACE  4,10
**        FWE - FIND A WARNING ENTRY.
*
*         EXIT   (A) = 0 WHEN NO ENTRY FOUND.
*                (RTP2) = ORDINAL OF ENTRY FOUND.
*
*         CALLS  IDA.
*
*         USES   T1, W0 - W3, W4 - W7.


 FWE      SUBR               ENTRY/EXIT
          LDN    1
          STM    RTP2
 FWE1     RJM    GBE         GET AN ENTRY
          ZJN    FWEX        IF AT END OF TABLE
          CRDL   CM          GET THE CONTROL WORD IN THE ENTRY
          LDDL   CM+1
          SHN    -10
          LPN    0#F         ISOLATE THE ELEMENT TYPE
          SBN    7
          NJN    FWE1        IF NOT A WARNING ENTRY
          LDD    CM+1
          LPN    0#F
          SBN    4
          PJN    FWE1        IF A WARNING BUT MARKED AS WARNING CLEARED
          UJP    FWEX        RETURN
 GBE      SPACE  4,10
**        GBE - GET A NON REGISTER BUFFER ENTRY.
*
*         ENTRY  (A) = ORDINAL TO SEARCH FROM.
*
*         EXIT   (A)= 0 IF END OF BUFFER.
*
*         CALLS  IDA.
*
*         USES   RTP2, W0 - W3.


 GBE0     LDN    0           END OF BUFFER EXIT CONDITION
 GBE      SUBR               ENTRY/EXIT
          LDN    NRSP
          RJM    IDA         INCREMENT POINTER ADDRESS
          CRDL   W0          READ IN POINTER WORD
          LRD    W1
          LDDL   W0
          ADC    RR
          CRDL   W4          READ IN HEADER WORD
          LDML   RTP2        CURRENT ELEMENT POSITION
          ADD    W7          ELEMENT SIZE
          SBD    W3          LENGTH OF BUFFER
          PJN    GBE0        IF AT END OF BUFFER
          LDD    W7          ELEMENT SIZE
          RAML   RTP2        UPDATE NEXT ELEMENT
          ADDL   W0
          ADC    RR
          LJM    GBEX

*         END    CTP$DFT_FIND_WARNING_IN_NRSB
