*         CTP$DFT_HANDLE_IOU_BIT57
          QUAL   HB57
**
*         THE FOLLOWING STATEMENT IS USED ONLY TO DERIVE THE OVERLAY NUMBER
*         THAT THIS OVERLAY WILL BE ASSIGNED.  SINCE THE OVERLAY STARTS AT
*         10000 IT CANNOT BE "CALLED".
*
          ROUTINE SCO        USED ONLY TO GET THE OVERLAY NUMBER

 BCA      SUBR               ENTRY
          LDN    1
          STM    BI57        SET BIT 57 FLAG
          RJM    IDI         IDLE DRIVERS IN IOU
 BCA2     FUNCMR I0CC,MRMC   MASTER CLEAR THE CMI/ADU
          READMR RDATA,I0CC,DEMR
          LDM    RDATA+7
          LPC    0#EF        CLEAR TEST MODE ENABLED
          STM    RDATA+7
          WRITMR RDATA,I0CC,DEMR
          UJP    BCAX        RETURN


 IDI      SPACE  4,10
**        IDI - IDLE ALL I/O DRIVERS IN IOU.
*
*         EXIT   ALL PPS AND CHANNELS POSSIBLE ARE IDLED AND
*                MASTER CLEARED.
*
*         USES   T1, T4, T5.
*
*         CALLS  IVP, MCH.


 IDI      SUBR               ENTRY/EXIT

*         THIS SECTION WILL IDLE ALL POSSIBLE PPS IN THE IOU.  IT DEPENDS ON
*         ROUTINE IDP TIMING OUT THE WAIT FOR PP IDLE AND DOING NOTHING ABOUT IT.

          LDN    0           INITIAL PP TO START
          STD    T4
 IDI10    LDM    //PPNO
          LPN    0#1F
          SBD    T4
          ZJN    IDI15       IF DFT DONT IDLE
          LDN    1S5         CIO BIT
          SHN    10-5
          LMD    T4          ADD PP NUMBER
          RJM    IVP         IDLE PP
 IDI15    LDN    11B
          SBD    T4
          ZJN    IDI20       IF AT BREAK TO GO TO PP20
          AOD    T4
          SBN    32B
          MJN    IDI10       IF MORE PPS TO DO
          UJN    IDI30       GO MASTER CLEAR CHANNELS

 IDI20    LDN    20B
          STD    T4
          UJN    IDI10       CONTINUE IDLING PPS

*         THIS SECTION WILL MASTER CLEAR ALL POSSIBLE CHANNELS.

 IDI30    LDN    0
          STD    T4
 IDI80    LDN    1S5         CIO BIT
          SHN    10-5
          LMD    T4          ADD CHANNEL NUMBER
          RJM    MCH         MASTER CLEAR CHANNEL
          LDN    11B
          SBD    T4
          ZJN    IDI100      IF AT BREAK NEXT CHANNEL IS 20(8)
          AOD    T4
          SBN    32B
          MJN    IDI80       IF MORE CHANNELS TO DO
          LJM    IDIX        RETURN

 IDI100   LDN    20B
          STD    T4
          UJN    IDI80


 IVP      SPACE  4,10
**        IVP - IDLE VE PP.
*
*         ENTRY  (A) = PP TO IDLE.
*
*         USES   T3.
*
*         CALLS  IDP, SCF.


 IVP      SUBR               ENTRY/EXIT
          STDL   T3
          LDN    MX
          RJM    SCF         INTERLOCK TWO PORT MUX
 IVP1     LDDL   T3
          RJM    IDP         IDLE PP
 IVP2     CCF    *,MX
          UJN    IVPX        RETURN
 QUAL$    EQU    0

*COPY  DSI$DUMP_LOAD_IDLE_PP

 BI57     CON    0           BIT 57 FLAG
          QUAL   *
*         END    CTP$DFT_HANDLE_IOU_BIT57
