          CTEXT  CTP$DFT IDLE IOU1
          SPACE  4,10
          BASE   M
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC. 1992
 IDI      SPACE  4,10
**        IDI - IDLE ALL I/O DRIVERS IN IOU1.
*
*         EXIT   FOR IOU1, ALL LOGICALLY ON PP-S IN THE MRT
*                ARE IDLED.  ALL LOGICALLY ON CHANNELS ARE
*                MASTER CLEARED AND DCN-D (EXCEPT FOR CIO
*                CHANNELS, WHICH ARE NOT DCN-D).
*
*         USES   T1, T4, T5.
*
*         CALLS  FHE, IVP, MCH.


 IDI      SUBR               ENTRY/EXIT
          LDC    10000+IOUID FETCH IOU1 DESCRIPTOR FROM MRT
          RJM    FHE

*         FORCE *DFT-S* PP TO BE LOGICALLY OFF.

          LDM    //PPNO
          LPC    0#FF
          SBN    20          TEST FOR UPPER PP
          MJN    IDI10       IF LOWER
          ADC    SHNI
          STM    IDIA
          LDN    1
 IDIA     SHN    **
          RAM    HBUF+CIOPLM+1  FORCE PP TO BE LOGICALLY OFF
          UJN    IDI20       CONTINUE

 IDI10    LDM    //PPNO
          LPC    0#FF
          ADC    SHNI
          STM    IDIB
          LDN    1
 IDIB     SHN    **
          RAM    HBUF+CIOPLM FORCE PP TO BE LOGICALLY OFF

 IDI20    LDML   IOUM        CHECK IOU MODEL NUMBER
          LMC    0#43
          ZJP    IDI110      IF MODEL 43 IOU
          LMN    0#44&0#43
          NJN    IDI25       IF NOT MODEL 44 IOU
          LJM    IDI110      PRESET FOR MODEL 44 IOU

 IDI25    LDN    2           SET GROUP OFFSET
          STD    T5
 IDI30    LDM    IDID,T5     GET PP OFFSET
          STD    T1
          LDM    HBUF,T1
          LPC    1777
          LMC    1777
          STM    IDIG        PP STATUS
          LDM    IDIE,T5     GET CHANNEL OFFSET
          STD    T1
          LDM    HBUF,T1
          LMC    7777
          STM    IDIH        CHANNEL STATUS
          LDM    IDIF,T5     FIRST PP/CHANNEL NUMBER OF GROUP
          STD    T4
 IDI40    LDM    IDIG
          SHN    21-0
          STM    IDIG
          PJN    IDI70       IF PP IS LOGICALLY OFF
          LDD    T5
          SBN    2
 IDIJ     ZJN    IDI50       IF CIO PP
*         UJN    IDI50       (MODEL 44 IOU)
          LDD    T4
          UJN    IDI60       IDLE PP

 IDI50    LDN    1S5         CIO BIT
          SHN    10-5
          LMD    T4
 IDI60    RJM    IVP         IDLE PP
 IDI70    LDM    IDIH
          SHN    21-0
          STM    IDIH
          PJN    IDI100      IF CHANNEL IS LOGICALLY OFF
          LDD    T5
          SBN    2
 IDIK     ZJN    IDI80       IF CIO CHANNEL
*         UJN    IDI80       (MODEL 44 IOU)
          LDD    T4
          UJN    IDI90       MASTER CLEAR CHANNEL

 IDI80    LDN    1S5         CIO BIT
          SHN    10-5
          LMD    T4          ADD CHANNEL NUMBER
 IDI90    RJM    MCH         MASTER CLEAR CHANNEL
          LDD    T5
          SBN    2
 IDIL     ZJN    IDI100      IF CIO CHANNEL
*         UJN    IDI100      (MODEL 44 IOU)
          LDD    T4
          ADC    DCNI+40     DEACTIVATE POSSIBLE ACTIVE CHANNEL
          STM    IDIC
          PSN
 IDIC     DCN    **+40
 IDI100   AOD    T4          INCREMENT TO NEXT PP/CHANNEL IN TABLE
          SBK    46
          MJP    IDI40       IF NOT FINISHED WITH GROUP
          SOD    T5
          PJP    IDI30       IF ANOTHER GROUP TO PROCESS
          LJM    IDIX        RETURN

*         PRESET FOR MODEL 44 IOU.

 IDI110   ISTORE IDIJ,(UJN IDI50)
          ISTORE IDIK,(UJN IDI80)
          ISTORE IDIL,(UJN IDI100)
          LDN    1           SET GROUP OFFSET
          STDL   T5
          LJM    IDI30       GET PP OFFSET

 IDID     CON    7,10,15     OFFSETS TO PP STATUS
 IDIE     CON    12,13,15    OFFSETS TO CHANNEL STATUS
 IDIF     CON    0,20,0      STARTING PP NUMBERS FOR GROUPS
 IDIG     BSS    1           PP STATUS OF CURRENT GROUP
 IDIH     BSS    1           CHANNEL STATUS OF CURRENT GROUP
 IVP      SPACE  4,10
**        IVP - IDLE VE PP.
*
*         ENTRY  (A) = PP TO IDLE.
*
*         USES   T3.
*
*         CALLS  IDP, SCF.


 IVP      SUBR               ENTRY/EXIT
          STDL   T3
          LDN    MX
          RJM    SCF         INTERLOCK TWO PORT MUX
 IVP1     LDDL   T3
          RJM    IDP         IDLE PP
 IVP2     CCF    *,MX
          UJN    IVPX        RETURN


          BASE   *
          ENDX

