          EJECT
*         CTEXT  CTP$DFT_PRESET_DUAL_I4
*
*         THIS DECK CONTAINS PRESET CODE NECESSARY FOR DUAL
*         IOU SUPPORT.
 PDI      SPACE  4,10
**        PDI - PRESET DUAL IOU.
*
*         USES   IOUN.
*
*         CALLS  *BSB*, SOS, SPB.


 PDI1     LRD    DP+1        PUT *DFT-S* ON SIDE OF BOUNDS WITH BUFFER
          RJM    SPB         SET OS BOUNDS
          CALL   BSB         BUILD SECONDARY DFT BUFFER

 PDI      SUBR               ENTRY/EXIT
          LDM    IOUN
          ZJN    PDIX        IF *DFT*

*         IF NOT DUAL STATE, THEN DO NOT INITIALIZE OS BOUNDS CHECKING.
*         NOTE THAT THIS CODE IS ONLY EXECUTED IN IOU1 AND THEN VE
*         MUST BE UP (SINCE IT IS THE ONE TO MAKE THE REQUEST TO START
*         UP DFT IN IOU1).  SO, IT IS ONLY NECESSARY TO CHECK FOR
*         THE PRESENCE OF A 170 OS.

          LDN    D7TY        EXTRACT 170 OS TYPE FIELD
          RJM    IIB
          CRDL   W0
          LDDL   W3
          SHN    -14
          STDL   T1
          LDDL   W2
          LPN    3
          SHN    4
          LMDL   T1
          ZJP    PDI1        IF NOT DUAL STATE

*         SET OS BOUNDS FOR ALL PP-S.

          RJM    SOS         SET OS BOUNDS
          UJP    PDI1        BUILD SECONDARY DFT BUFFER
 ISD      SPACE  4,10
**        ISD - IDLE SECONDARY DRIVERS.
*
*         USES   IOUN.
*
*         CALLS  *IAD*.


 ISD      SUBR               ENTRY/EXIT

*         WHEN RUNNING IN THE SECONDARY IOU, IDLE ALL PP'S,
*         MASTER CLEAR AND DCN CHANNELS.

          LDM    IOUN
          ZJN    ISDX        IF IOU0
          CALL   IAD         IDLE ALL DRIVERS
          UJN    ISDX        RETURN
 SOS      SPACE  4,10
**        SOS - SET OS BOUNDS.
*
*         ENTRY  (PRSC - PRSC+2) = OS BOUNDS.


 SOS      SUBR               ENTRY/EXIT
          LDN    IOSB
          STDL   RN
          LDM    I0CC
          RJM    RMR         READ MAINTENANCE REGISTER
          LDN    0           SET ALL PPS TO BE UPPER PPS
          STML   RDATA+0     BARREL 0
          STML   RDATA+1     BARREL 1
          STML   RDATA+2     BARREL 2
          STML   RDATA+3     BARREL 3
          LDML   RDATA+5
          LPC    0#FFFC
          STML   RDATA+5
          LDML   PRSC
          LPN    3
          RAML   RDATA+5
          LDML   PRSC+1
          STML   RDATA+6
          LDML   PRSC+2
          STML   RDATA+7
          WRITMR RDATA,I0CC
          LDML   IOUM
          LMC    0#43
          ZJP    SOSX        IF MODEL 43 IOU
          LMN    0#44&0#43
          ZJP    SOSX        IF MODEL 44 IOU
          LDN    OIMR        CHECK IF CIO SUBSYSTEM IS PRESENT
          STDL   RN
          LDM    I0CC
          RJM    RMR         READ MAINTENANCE REGISTER
          LDML   RDATA+7
          SHN    21-7
          PJP    SOSX        IF CIO SUBSYSTEM IS NOT PRESENT
          LDN    CIFSM
          STDL   RN
          LDM    I0CC
          RJM    RMR         READ MAINTENANCE REGISTER
          LDN    0
          STML   RDATA+0
          STML   RDATA+1
          WRITMR RDATA,I0CC
          UJP    SOSX        RETURN

*         END    CTP$DFT_PRESET_DUAL_I4



