 RSP      SPACE  4,10
**        RSP - RESTART SCI PP.
*

          ROUTINE RSP
          RJM    LRP
          CRDL   W0          GET PARAMETERS
          LDDL   W1
          LPC    0#FF
          SHN    10
          STDL   T1
          LDDL   W2          GET PP NUMBER
          SHN    -10
          LMDL   T1
          STML   PPTN
          RJM    IDP         IDLE EXISTING COPY OF *SCI*
          CCF    *,MX        CLEAR CHANNEL 15 FLAG TO CLEANUP SCI ENVIRONMENT

          LOCKMR SET
          READMR RDATA,I0CC,ITMR
          LDN    0
          STM    RDATA+7     CLEAR PORT RESERVES THAT MAY EXIST
          WRITMR RDATA,I0CC,ITMR
          LOCKMR CLEAR

*         INITIALIZE DIRECT CELLS IN BOOTSTRAP IMAGE.

          FINDCM SCI         LOCATE *SCI* IN THE CIP DIRECTORY
          ADN    1
          STML   RSCB+DE     SAVE ADDRESS OF *SCI* DIRECTORY ENTRY
          CRML   RSCB+T1,ON
          LDD    CM+1
          STML   RSCB+DE+1
          LDD    CM+2
          STML   RSCB+DE+2
          LDN    DSEBP       SAVE ADDRESS OF *CIP* DIRECTORY
          RJM    IIB
          CRML   RSCB+CD,ON
          LDM    RSCA        SAVE PP NUMBER
          LMC    4000        SET RESTART FLAG
          STM    RSCB+27

*         ACTIVATE NEW COPY OF *SCI*.

          LDML   PPTN
          RJM    IDP         IDLE PP
          LDN    MX          GET MUX CHANNEL INTERLOCK
          RJM    SCF
          LDN    MX          USE MUX CHANNEL FOR DEADSTARTING THE PP
          STD    T1
          LDML   PPTN        LOAD SELECTED PP
          RJM    DLP
          LDN    RSCBL       OUTPUT BOOTSTRAP TO PP
          OAM    RSCB,MX
          FJM    *,MX        WAIT FOR PP TO ACCEPT DATA
          DCN    MX+40
          CCF    *,MX        RELEASE CHANNEL INTERLOCK
          LJM    RSPX        RETURN

 RSCA     BSS    2

 RSCB     BSS    0           BOOTSTRAP PROGRAM
          LOC    0

          CON    BTS-1       ADDRESS - 1 TO EXECUTE

 T1       BSS    4           DIRECTORY ENTRY

 BTS      LDD    T1          SET PP LOAD ADDRESS
          STD    BTSA
          LDD    DE          SET CM LOAD ADDRESS
          ADC    RR+1
          LRD    DE+1
          CRML   **,T2       READ PROGRAM INTO PP
 BTSA     EQU    *-1         (LOAD ADDRESS)
          LJM    100         ENTER *SCI* PRESET

          BSS    30-*

 DE       BSS    3           ADDRESS OF *SCI* DIRECTORY ENTRY
          BSS    1           (USED ONLY FOR CTI/MDD LOADS)
 CD       BSS    3           ADDRESS OF *CIP* DIRECTORY
          BSS    1           (UNUSED - REQUIRED BY *CRML* INTO *CD*)
          LOC    *O
 RSCBL    EQU    *-RSCB      LENGTH OF BOOTSTRAP
 PPTN     CON    0           PP TYPE AND NUMBER

*         END    CTP$DFT_RESTART_SCI
