*         CTEXT  CTP$DFT_RETURN_ERROR_CODE
 ERR      SPACE  4,10
**        ERR - RESPOND TO REQUEST WITH ERROR.
*
*         ENTRY  VIA *LJM*.
*
*         EXIT   TO *DFT10*.
*
*         USES   *JOBF*.
*
*         CALLS  RCS, SRS.


 ERR      LDC    0#200

*         *ERR10* IS AN ENTRY POINT.  (A) = RESPONSE CODE TO RETURN.

 ERR10    STM    JOBF

*         RESET THE STACK.

          UJP    ERR1        UNTIL ALL ERRORS REPORTED ARE UNDERSTOOD QUIT LOGGING
          LDN    VER5
          RJM    VCK         CHECK VERSION
          MJP    ERR1        IF LESS THAN VERSION 5
          LRD    DP+1
          RJM    SPB         SET OS BOUNDS
          LDN    BC
          RJM    CLR
          LDN    0
          STD    ET          RESET ET FOR THE DFT ANALYSIS CODE FORMATION
          SETDAN (EPUN,DABOR)
          SETFLG (BC.FL)
          RJM    LRP
          CRDL   CM          READ IN OS REQUEST WORD
          LDML   CALB+1      GET 2AP RESPONSE
          STDL   CM+1
          LDML   JOBF
          STDL   CM+2
          LDN    0
          STDL   CM+3
          LDN    NRSP
          RJM    IDA
          CRDL   W0          READ IN NON REGISTER BUFFER POINTER
          LRD    W1
          LDDL   W0
          ADC    RR+NRSBL+1
          CWDL   CM          WRITE REQUEST RESPONSE TO SCRATCH BUFFER
          LDN    NRSBL
          STML   LLOG
          LDN    4
          STD    ET          INITIALIZE ELEMENT TYPE TO DFT INTERNAL ERROR
          LDN    1
          STM    RTP1
          CALL   LOG         LOG THE RESPONSE TO THE NON REGISTER STATUS BUFFER
 ERR1     RJM    RCS         RESET CALL STACK
          RJM    SRS         SET REQUEST STATUS
          LJM    DFT10       GO BACK TO PROCESSING
 RCS      SPACE  4,10
**        RCS - RESET CALL STACK.
*
*         USES   ST, T1, *CUOV*, *STAK*, *STKD*.


 RCS      SUBR               ENTRY/EXIT
          LDC    STAK
          STD    ST          POINTER TO STACK
          LDN    0
          STM    STKD        RESET CURRENT STACK DEPTH
          STM    CUOV        RESET CURRENT OVERLAY
          UJN    RCSX

*         END    CTP$DFT_RETURN_ERROR_CODE

