          EJECT
*         CTEXT  CTP$DFT_UPDATE_170_MEMORY
*
*         THIS DECK DEFINES PROCEDURES TO UPDATE THE SCD BLOCK
*         IN CENTRAL MEMORY
 UCM      SPACE  4,10
**        UCM - UPDATE C170 MEMORY.
*
*         CLEARS THE VE CONSOLE STATUS.
*
*         CALLS  IIB, SPB.


          ROUTINE UCM

          LDN    D7RS+2
          RJM    IIB         FIND OFFSET TO SCD INFORMATION
          CRDL   T2
          LDDL   T4          BUILD R-REGISTER TO ACCESS SCD BLOCK
          SHN    -2+22
          STD    T6
          SHN    2-22
          SHN    6+4
          STD    T7
          LDDL   T4          CHECK FOR NOS SCD BLOCK
          ADDL   T5
          ZJP    UCM4        IF NO BLOCK DEFINED
 UCM1     LDN    0           INTERLOCK SCD BLOCK
          STDL   CM
          STDL   CM+2
          STDL   CM+3
          LDC    10000
          STDL   CM+1
          LRD    T6
          RJM    SPB         SET PP BOUNDARY
          LDDL   T5
          LMC    RR
          RDSL   CM          SET INTERLOCK
          LDDL   CM+1
          LPC    10000
          NJN    UCM1        IF INTERLOCK ALREADY SET
          LDDL   CM+1        SET CONSOLE DEFINITION CHANGED BIT
          LPC    0#BFFF
          LMC    0#4000
          STDL   CM+1
          LDDL   CM+2        CHECK IF NOS/SCD ACTIVE
          SHN    21-11
          PJN    UCM2        IF NOT ACTIVE
          LDDL   CM+2        CLEAR VE CONSOLE BIT
          LPC    0#FBFF
          UJN    UCM3        CLEAR BIT

 UCM2     LDN    0           CLEAR ENTIRE *SCD* BYTE
 UCM3     STDL   CM+2
          LDDL   T5          WRITE FIRST WORD AND CLEAR INTERLOCK
          LMC    RR
          CWDL   CM
 UCM4     LJM    UCMX        RETURN
 IMM      SPACE  4,10
**        IMM - ISSUE MONITOR TIMED OUT MESSAGE.
*
*         CALLS  *ERRH*.


          ROUTINE IMM        ENTRY/EXIT
          LDN    0
          RJM    IDA         GET DFT HEADER FLAGS BIT 50
          CRDL   CM
          LDDL   CM+3
          SHN    21-15
          PJN    IMM2        IF NOT SET DONT HAMMER SYSTEM
          LDN    0
          STM    CPUO
          LDN    PROCID
 IMM1     RJM    FHE
          MJP    IMM2        IF DONE PROCESSING CPUS
          CALL   HPR
          CALL   DMP
          AOM    CPUO
          SBN    2
          PJN    IMM2        IF NO MORE CPUS TO DO
          LDC    PROCID1
          UJN    IMM1

 IMM2     SOM    DFTD        CLEAR MESSAGE NEEDED FLAG
          LDN    0
          STD    ET
          LDN    BC
          RJM    CLR

*         DFT ANALYSIS - MONITOR TIMED OUT ON HANDSHAKE.

          SETDAN (EPUN,DAMT)
          LDC    DAMT        SET ANALYSIS CODE
          STML   RTP1
          CALL   ERRH        ISSUE MESSAGE
          UJP    IMMX        RETURN


*         END    CTP$DFT_UPDATE_170_MEMORY
