          EJECT
*         CTEXT  CTP$DFT_WRITE_FSC_TO_BUFFER
*
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC. 1992
          SPACE  4,10
**        DATA GLOBAL TO THIS COMMON DECK.


 FSCB     BSS    0           FAULT SYMPTOM CODE BUFFER
 RFU      BSSZ   2           RESERVED FOR FUTURE USE
 SFS      BSSZ   2           START OF FAULT SYMPTOM CODE
 CDIF     BSSZ   21          COMMON DECK INTERFACE BUFFER
 FSCBL    EQU    *-FSCB-5    LENGTH OF FAULT SYMPTOM CODE BUFFER
 WFS      SPACE  4,10
**        WFS - WRITE FAULT SYMPTOM CODE TO SUPPORTIVE STATUS BUFFER.
*
*         ENTRY  (A) = ELEMENT IDENTIFIER.
*                (CDIF - CDIF+3) = FAULT SYMPTOM CODE.
*                (RTP1) = 0 LOG TO SUPPORTIVE STATUS.
*                (RTP1) = 1 LOG TO NRSB.
*
*         USES   CM - CM+3, T1.
*
*         CALLS  CDA, IDA.


 WFS      SUBR               ENTRY/EXIT
          STDL   T1          SAVE ELEMENT IDENTIFIER
          LDN    3           HEADER WORDS FOR SUPPORTIVE STATUS
          STM    WFSA
          LDM    RTP1
          ZJN    WFS1        IF TO LOG TO SUPPORTIVE STATUS
          AOM    WFSA        NON REGISTER STATUS HAS ONE MORE HEADER WORD
          LDN    NRSP
          UJN    WFS2

*         READ FIRST WORD OF FAULT SYMPTOM CODE TO PRESERVE FIRST TWO BYTES.

 WFS1     LDN    SSBP        GET ADDRESS OF SCRATCH BUFFER
 WFS2     RJM    IDA
          CRDL   CM
          LDM    WFSA        SKIP HEADER WORDS
          RADL   CM
          LRD    CM+1
          ADC    RR
          CRML   FSCB,ON
          LDDL   T1          SET ELEMENT IDENTIFIER
          STML   FSCB+2

*         SET MODEL NUMBER.

          LDD    MD
          RJM    CDA         CONVERT TWO DIGITS TO ASCII
          STML   FSCB+3

*         WRITE FAULT SYMPTOM CODE TO SCRATCH SUPPORTIVE STATUS.

          LDN    2           SET NUMBER OF CM WORDS TO WRITE
          STD    T1
          LDDL   CM          LOAD ADDRESS OF SCRATCH BUFFER
          ADC    RR
          CWML   FSCB,T1     WRITE TO SCRATCH BUFFER
          UJP    WFSX        RETURN

 WFSA     CON    0
*         CTP$DFT_WRITE_FSC_TO_BUFFER.

