          CTEXT  CTP$DFT ZERO SUPPORTIVE STATUS.
          SPACE  4,10
 QUAL$    IF     -DEF,QUAL$
          QUAL   CTPZSS
 QUAL$    ENDIF
          BASE   M
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC. 1992
 ZSS      SPACE  4,10
**        ZSS - ZERO SUPPORTIVE STATUS BUFFER.
*
*         EXIT   THE SCRATCH SUPPORTIVE STATUS BUFFER WILL BE ZEROED.
*
*         USES   CM - CM+3, W0 - W3.
*
*         CALLS  CLR, IDA, VCK.


 ZSS      SUBR               ENTRY/EXIT
          LDN    VER4
          RJM    VCK         CHECK VERSION OF THE CM INTERFACE
          MJP    ZSSX        IF INTERFACE LESS THAN VERSION 4
          LDM    RTP1        FLAG TO USE SUPPORTIVE STATUS OR NON REGISTER STATUS
          ZJN    ZSS1        IF SUPPORTIVE STATUS
          LDN    NRSP        ADDRESS OF SCRATCH NON REGISTER STATUS BUFFER
          UJN    ZSS2

 ZSS1     LDN    SSBP
 ZSS2     RJM    IDA         INDEX DFT ADDRESS
          CRDL   W0          SSB POINTER WORD
          LRD    W1
          LDD    W0
          ADC    RR
          CRDL   CM          (CM+3) = ELEMENT SIZE
          SODL   CM+3
          AODL   W0
          LDN    W4
          RJM    CLR         CLEAR W4 - W7
 ZSS3     LDDL   W0
          ADC    RR
          CWDL   W4          ZERO SUPPORTIVE STATUS BUFFER ENTRY
          AODL   W0
          SODL   CM+3
          PJN    ZSS3        IF MORE ENTRIES TO DO
          LJM    ZSSX        RETURN


          BASE   *
 QUAL$    IF     -DEF,QUAL$
          QUAL   *
 ZSS      EQU    /CTPZSS/ZSS
 QUAL$    ENDIF
          ENDX
