          SPACE  4,10
*         CTEXT  CTP$SCI BUILD HARDWARE REG.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO SET UP
*         THE HARDWARE REGISTERS FOR THE INITIAL EXCHANGE PACKAGE
*         AT DEADSTART TIME.
 BHR      SPACE  4,10
**        BHR - BUILD HARDWARE REGISTERS.
*
*         ENTRY  (LA - LA+1) = PAGE TABLE ADDRESS.
*                (BL - BL+1) = NOS/VE LOAD ADDRESS.
*                (HPSM) = PAGE SIZE MASK.
*                (HPTL) = PAGE TABLE LENGTH.
*                (MBUF) = CLEARED.
*
*         EXIT   (*HDWR* IN *SSR*) UPDATED.


 BHR      SUBR               ENTRY/EXIT
          LDD    BL          BUILD PAGE TABLE ADDRESS
          SHN    5-0
          STML   MBUF+0*4+2
          LDD    BL+1
          SHN    0-7
          RAML   MBUF+0*4+2
          LDD    BL+1
          SHN    20-7
          SCN    7
          STML   MBUF+0*4+3
          LDD    LA          BUILD PAGE TABLE ADDRESS
          SHN    5-0
          STML   MBUF+1*4+2
          LDD    LA+1
          SHN    0-7
          RAML   MBUF+1*4+2
          LDD    LA+1
          SHN    20-7
          SCN    7
          STML   MBUF+1*4+3
          LDML   HPTL        FORM PAGE TABLE LENGTH
          SHN    -3
          SBN    1
          STML   MBUF+2*4+3
          LDC    0#7F        FORM PAGE SIZE MASK
          SBM    HPSM
          STML   MBUF+3*4+3
          LDN    4           SET REGISTER COUNT
          STD    T4
          SSRE   HDWR        FIND HARDWARE REGISTER BLOCK
          CWML   BHRA,ON     STORE REGISTER NUMBERS
          CWML   MBUF,T4     WRITE REGISTER VALUES
          LJM    BHRX        RETURN

 BHRA     CON    0#41,0#48,0#49,0#4A

*         ENDX   CTP$SCI BUILD HARDWARE REG.

