          SPACE  4,10
*         CTEXT  CTP$SCI BUILD PAGE TABLE.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO BUILD
*         THE INITIAL PAGE TABLE AT DEADSTART TIME.
 BPT      SPACE  4,10
**        BPT - BUILD PAGE TABLE.
*
*         ENTRY  (LA - LA+1) = PAGE TABLE ADDRESS.
*                (HPTL) = PAGE TABLE LENGTH.
*
*         EXIT   PAGE TABLE BUILT.
*                (BL - BL+1) = BOOT LOAD ADDRESS.
*
*         USES   BL, T0, CN - CN+3.
*
*         CALLS  CCM, SPB.


 BPT      SUBR               ENTRY/EXIT
          LRD    LA
          RJM    SPB         SET PP BOUNDS
          SRD    CN+1
          LDN    0
          STD    CN

*         ZERO OUT THE PAGE TABLE.  THE PAGE TABLE MAY EXCEED THE
*         MAXIMUM VALUE OF THE *A* REGISTER SO IT HAS TO BE CLEARED
*         IN BLOCKS.

          LDML   HPTL        PAGE TABLE LENGTH/100B IN WORDS
          STDL   BL          SAVE PAGE TABLE LENGTH
 BPT5     ADC    -4000B
          MJN    BPT10       IF LESS THAN BLOCK SIZE
          STDL   BL          SAVE REMAINING PAGE TABLE BLOCK SIZE
          LDC    4000B
          UJN    BPT15       CLEAR PAGE TABLE BLOCK

 BPT10    LDDL   BL          REMAINING BLOCK OF PAGE TABLE TO CLEAR
          STDL   T0
          LDN    0           SET PAGE TABLE CLEARED
          STDL   BL
          LDDL   T0
 BPT15    SHN    6
          RJM    CCM         ZERO OUT PAGE TABLE
          LDDL   BL          REMAINING PAGE TABLE BLOCKS TO CLEAR
          NJN    BPT5        IF PAGE TABLE NOT CLEARED
          LDML   HPTL        ADVANCE LOAD ADDRESS BY PAGE TABLE LENGTH
          ADD    LA+1
          STD    BL+1
          SHN    -14
          ADD    LA
          STD    BL
          LDD    LA+1        STORE PAGE TABLE PAGE 0 PAGE ADDRESS
          STM    BPTA+3
          LDD    LA
          SHN    0-4
          STML   BPTA+2
          LDD    LA
          LPN    17
          SHN    20-4
          RAML   BPTA+3
          LDD    BL+1        STORE BOOT PAGE 0 PAGE ADDRESS
          STM    BPTB+3
          LDD    BL
          SHN    0-4
          STML   BPTB+2
          LDD    BL
          LPN    17
          SHN    20-4
          RAML   BPTB+3
          LRD    LA
          LDC    RR+2
          CWML   BPTA,ON     WRITE PAGE TABLE ENTRY FOR PAGE TABLE
          ADN    1
          CWML   BPTB,ON     WRITE PAGE TABLE ENTRY FOR BOOT
          LJM    BPTX        RETURN

 BPTA     VFD    1/1,1/1,1/0,1/0,16/1,22/0,22/0
 BPTB     VFD    1/1,1/1,1/0,1/0,16/2,22/0,22/0

*         ENDX   CTP$SCI BUILD PAGE TABLE.

