          SPACE  4,10
*         CTEXT  CTP$SCI CLEAR CENTRAL MEMORY.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO CLEAR A
*         BLOCK OF CENTRAL MEMORY.
 CCM      SPACE  4,10
**        CCM - CLEAR CENTRAL MEMORY BLOCK.
*
*         ENTRY  (A) = NUMBER OF WORDS TO CLEAR.
*                (CN - CN+2) = R-POINTER TO AREA TO CLEAR.
*
*         USES   T1, T2, T3, CN - CN+2.
*
*         EXIT   (CN - CN+2) = R-POINTER UPDATED FOR NEXT BLOCK TO CLEAR.
*
*         CALLS  ZPB.


 CCM5     LDDL   CN          FORM ADDRESS TO BLOCK TO CLEAR
          LRD    CN+1
          LMC    RR
          CWML   MBUF,T1     CLEAR MEMORY BLOCK
          AOD    CN+2        INCREMENT MEMORY BLOCK BY 100(8) WORDS
          SHN    -14
          RAD    CN+1
          SOD    T2          BLOCKS REMAINING TO BE CLEARED
          MJN    CCMX        IF ALL DATA CLEARED
 CCM10    NJN    CCM5        IF MORE BLOCKS TO BE CLEARED
          LDD    T3          SET LENGTH OF LAST BLOCK
          STD    T1
          NJN    CCM5        IF PARTIAL LAST BLOCK TO BE CLEARED

 CCM      SUBR               ENTRY/EXIT
          SHN    22-6
          STD    T2          SAVE NUMBER OF 100 WORD BLOCKS
          SHN    -14
          STD    T3          SAVE NUMBER OF WORDS TO CLEAR IN LAST BLOCK
          LDC    100
          RJM    ZPB         ZERO PP BUFFER
          LDD    T2
          UJN    CCM10       ENTER CLEAR LOOP

*         ENDX   CTP$SCI CLEAR CENTRAL MEMORY.
