          SPACE  4,10
*         CTEXT  CTP$SCI COPY TO SAVE AREA.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO SAVE THE
*         MEMORY WHERE VCB WILL BE LOADED.
 CTS      SPACE  4,20
**        CTS - COPY TO SAVE AREA.
*
*         COPIES MEMORY WHERE THE CP BOOT IS TO BE LOADED TO THE SAVE AREA
*         AND COMPRESSES THE PAGE TABLE.  THE CP BOOT IS LOADED STARTING AT
*         THE PAGE TABLE ADDRESS.  COMPRESSING THE PAGE TABLE SAVES THE
*         NECESSARY INFORMATION FROM IT (MODIFY BITS) TO RECONSTRUCT IT
*         DURING THE RECOVERY PROCESS.  THE AMOUNT OF MEMORY TO COPY IS
*         DETERMINED BY THE LENGTH OF THE SAVE AREA.
*
*         ENTRY  (LA - LA+1) = R-REGISTER VALUE OF THE PAGE TABLE.
*
*         USES   T4, CM - CM+3, CN - CN+3.
*
*         CALLS  CPT, CPY, INS.
*
*         MACROS SSRE.


 CTS      SUBR               ENTRY/EXIT
          SSRE   IMGS        FETCH IMAGE STATUS
          LDDL   W5
          SBN    1
          PJN    CTSX        IF COPY ALREADY DONE
          RJM    CPT         COMPRESS THE PAGE TABLE
          SSRE   MEMB        FETCH BOOT MEMORY BOUNDS, DEFINES THE SAVE AREA
          CRDL   CM
          LDD    CM+2        GET COPY LENGTH/100
          SHN    12D
          ADD    CM+3
          SHN    -11
          STD    T4          COUNT OF 1000 100 WORD BLOCKS TO MOVE
          LDN    0
          LRD    LA          SET UP R-POINTER FOR COPY SOURCE
          SRD    CN+1
          STD    CN
          LRD    CM          COPY DESTINATION
          SRD    CM+1
          STD    CM
          LDML   HPTL        INCREMENT PAST THE PAGE TABLE
          RAD    CN+2
          SHN    -12D
          RAD    CN+1
          LDD    CM+3        REMAINING BLOCK COUNT
          LPC    777
          SHN    6
 CTS5     RJM    CPY         COPY MEMORY TO THE SAVE AREA
          SOD    T4
          MJN    CTS10       IF ENOUGH MEMORY HAS BEEN COPIED
          LDC    100000
          UJN    CTS5        COPY ANOTHER 1000 100 WORD BLOCKS

 CTS10    SSRE   IMGS        UPDATE IMAGE STATUS
          LDN    1           RECORD THAT THE SAVE AREA HAS BEEN COPIED
          STD    W5
          LDDL   W1
          RJM    INS
          CWDL   W2          UPDATE IMGS FLAG
          LJM    CTSX        RETURN

*         ENDX   CTP$SCI COPY TO SAVE AREA.

