          SPACE  4,10
*         CTEXT  CTP$SCI CREATE SSR CHECKSUM.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO CREATE A
*         CHECKSUM OF THE SSR DIRECTORY.
 CSC      SPACE  4,20
**        CSC - CREATE SSR CHECKSUM.
*
*         THIS ROUTINE CREATES A NEW SSR CHECKSUM FROM THE SSR AS IT EXISTS IN
*         MEMORY.  IT ALSO SAVES THE PREVIOUS CHECKSUM FOUND IN SSR ENTRY
*         *SCKS*.  IF THE *SCKS* ENTRY IS NOT FOUND, THEN *SCI* MUST RELOAD THE
*         SSR.
*
*         THE SSR CHECKSUM IS CREATED BY ADDING THE LEFT TWO BYTES OF EACH WORD
*         IN THE SSR DIRECTORY.  THE RESULT IS A 16 BIT CHECKSUM.
*
*         EXIT   (T3) = NEWLY CREATED SSR CHECKSUM.
*                (W5) = PREVIOUS SSR CHECKSUM FROM THE *SCKS* SSR ENTRY.
*                (T4) = 0 IF *SCKS* SSR ENTRY NOT FOUND.
*
*         USES   CN - CN+3, W0 - W0+3.
*
*         CALLS  SSR.


 CSC      SUBR               ENTRY/EXIT
          RJM    SSR         SET UP SSR ADDRESS
          LDM    SAAO        READ SSR FIRST WORD
          ADC    RR
          CRDL   W0          (W0+2) = DIRECTORY LENGTH
          LDN    0           INITIALIZE CHECKSUM
          STD    T3
          STD    T4          PRESET *SCKS* ENTRY NOT FOUND
 CSC5     SOD    W0+2        DECREMENT WORD COUNT
          MJN    CSCX        IF END OF DIRECTORY
          ADC    RR
          CRDL   CN
          LDDL   CN          ADD THIS DIRECTORY ENTRY TO CHECKSUM
          ADDL   CN+1
          RADL   T3
          LDDL   CN          CHECK IF *SCKS* ENTRY
          LMC    2RSC
          ADDL   CN+1
          LMC    2RKS
          NJN    CSC5        IF NOT *SCKS* ENTRY
          AOD    T4          SET *SCKS* ENTRY FOUND FLAG
          LDDL   CN+3        SAVE PREVIOUS SSR CHECKSUM
          STDL   W5
          UJN    CSC5        CONTINUE

*         ENDX   CTP$SCI CREATE SSR CHECKSUM.
