          SPACE  4,10
*         CTEXT  CTP$SCI FETCH CM BOUND VALUES.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO FETCH THE
*         NOS/VE MEMORY BOUND VALUES FROM THE EICB.
 FMV      SPACE  4,10
**        FMV - FETCH MEMORY VALUES FROM EI CONTROL BLOCK.
*
*         EXIT   (CM - CM+1) = CURRENT LOAD ADDRESS IN R-REGISTER FORMAT.
*                (CM+2 - CM+3) = CURRENT LWA OF USABLE MEMORY IN R
*                                 REGISTER FORMAT.
*
*         USES   CM - CM+3, CN - CN+3.
*
*         CALLS  IIB.


 FMV      SUBR               ENTRY/EXIT
          LDN    D7CM+1
          RJM    IIB
          CRDL   CN

*         CONVERT THE MEMORY VALUES IN THE EICB INTO R-REGISTER FORMAT.
*         THE VALUES IN THE EICB ARE WORD ADDRESSES/1000(8) AND 16 BITS
*         PER PPU WORD.  CONVERT INTO WORD ADDRESSES/100(8) AND 12 BITS
*         PER PPU WORD.  CONVERT LAST WORD ADDRESS.

          LDD    CN+3        LOW ORDER 12 BITS OF LWA
          SHN    3           LWA * 100(8)
          STD    CM+3        SSSSSSSSS000
          LDDL   CN+3
          SHN    0-11        7 BITS OF HIGH ORDER 12 BITS OF LWA
          STD    CM+2        00000SSSSSSS
          LDD    CN+2        OTHER 5 BITS OF HIGH ORDER 12 BITS OF LWA
          LPN    37
          SHN    7-0
          RAD    CM+2        SSSSSSSSSSSS, HIGH ORDER 12 BITS OF LWA

*         CONVERT NOS/VE FWA.

          LDDL   CN+2        GET LOW ORDER 11 BITS OF FWA
          SHN    3-10
          SCN    7           FWA * 100(8)
          STD    CM+1        0LLLLLLLL000
          LDD    CN+1        GET OTHER LOW ORDER BIT OF FWA
          LPN    1
          SHN    13-0
          RAD    CM+1        LLLLLLLLL000
          LDDL   CN+1        HIGH ORDER 12 BITS OF FWA
          SHN    0-1
          STD    CM          LLLLLLLLLLLL
          UJN    FMVX        RETURN

*         ENDX   CTP$SCI FETCH CM BOUND VALUES.
