          SPACE  4,10
*         CTEXT  CTP$SCI ISSUE DFT REQUEST.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO ISSUE A
*         REQUEST TO DFT.
 IDR      SPACE  4,15
**        IDR - ISSUE DFT REQUEST.
*
*         ENTRY  (A) = PARAMETER FOR DFT.
*                (VP - VP+3) = DFT REQUEST POINTER.
*                (IDRB) CHANGED TO *INPN* INSTRUCTION IF THETA E MAINFRAME.
*
*         EXIT   REQUEST ISSUED TO DFT.
*                (A) = DFT RESPONSE CODE.
*
*         USES   CM - CM+3.
*
*         CALLS  IVB, SPB.


 IDR      SUBR               ENTRY/EXIT
          STDL   CM          SAVE PARAMETER WORD
          LRD    VP+1
          RJM    SPB         SET PP BOUNDARY FOR NOS/VE REQUEST BLOCK
          LDD    VP+3
          RJM    IVB         INDEX TO VPB BLOCK
          CWDL   CM          WRITE DFT REQUEST
          STDL   CM
          ADN    1
          CWML   IDRA,ON     WRITE ADDITIONAL PARAMETERS
          SRD    CM+1        BUILD REQUEST POINTER
          LDN    2
          STD    CM+3
          LDN    0
          RJM    IVB         INDEX NOS/VE BLOCK
          CWDL   CM          WRITE DFT REQUEST POINTER

*         ON A THETA E MAINFRAME, THE SERVICE PROCESSOR *DFT* MUST BE TOLD
*         THAT THERE IS A *DFT* REQUEST PENDING.  THIS IS ACCOMPLISHED BY
*         SENDING AN INTERRUPT TO IOU0.

          PSN
 IDRB     EQU    *-1
*         INPN   2           (INTERRUPT IOU0 ON THETA E)
 IDR5     LDD    VP+3        INDEX TO VPB REQUEST
          RJM    IVB
          CRDL   W0          READ STATUS WORD
          LDDL   W0
          SHN    -10
          ZJN    IDR5        IF NOT COMPLETE
          UJN    IDRX        RETURN

 IDRA     CON    0,0,0,0

*         ENDX   CTP$SCI ISSUE DFT REQUEST.
