          SPACE  4,10
*         CTEXT  CTP$SCI MOVE AND COMPLETE SSR.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO MOVE THE
*         SSR FROM ITS TEMPORARY LOCATION TO ITS PERMANENT LOCATION
*         AND SET THE SSR POINTER INTO THE EICB.
 MCS      SPACE  4,15
**        MCS - MOVE AND COMPLETE SSR.
*
*         ENTRY  (LA - LA+1) = R-REGISTER OF ADDRESS OF TEMPORARY SSR LOCATION.
*                (SZ - SZ+1) = CURRENT MEMORY SIZE.
*
*         EXIT   (SZ - SZ+1) = UPDATED MEMORY SIZE.
*                SSR POINTER SET IN THE EICB.
*                SSR MOVED TO PERMANENT LOCATION.
*
*         USES   CM - CM+3, CN - CN+3, W0 - W5.
*
*         CALLS  CCM, CPY, CSC, IIB, INS, SPB.
*
*         MACROS SSRE.


*         DETERMINE MEMORY ADDRESS WHERE THE SSR WILL RESIDE.

 MCS      SUBR               ENTRY/EXIT
          LDC    RR+1
          LRD    LA
          CRDL   W0          READ SSR DIRECTORY HEADER
          LDC    1000        NOS STACK FRAME AREA
          ADDL   W1          ADD THE SSR LENGTH
          STDL   CN+3
          ADN    77          ROUND UP TO NEAREST 100B WORD MULTIPLE
          SHN    -6          SUBTRACT SSR LENGTH FROM MEMORY SIZE
          LMC    7777
          ADN    1           FORM TWOS COMPLEMENT AND ADD
          RAD    SZ+1
          SHN    -14
          ADC    7777
          RAD    SZ
          LDM    HPSM
          LMC    7777
          LPDL   SZ+1        ROUND ADDRESS TO A PAGE SIZE
          STD    SZ+1
          LRD    SZ
          SRD    CN+1
          LDN    0
          STD    CM
          STD    CM+3
          STD    CN
          STM    SAAO
          RJM    SPB         SET PP BOUNDARY
          LDDL   CN+3        SSR SIZE
          RJM    CCM         CLEAR SSR AREA
          LRD    SZ          MOVE SSR DIRECTORY TO 170 STACK + 1000
          SRD    SA
          LDN    1000/100
          RAD    SA+1
          STD    CM+2
          SHN    -14
          RAD    SA
          STD    CM+1

*         SET SSR POINTER INTO THE *EICB*.

          LRD    IB+1
          RJM    SPB         SET PP BOUNDARY
          LDN    D8SSR
          RJM    IIB
          CWDL   CM          SET SSR POINTER INTO THE EICB
          LDN    3           SET LOCATION OF DIRECTORY IMAGE
          STD    CN
          LRD    LA
          SRD    CN+1
          RJM    SPB         SET PP BOUNDARY
          LDD    W3          SSR DIRECTORY LENGTH
          RJM    CPY         COPY SSR DIRECTORY TO UPPER MEMORY
          RJM    CSC         CREATE SSR CHECKSUM
          SSRE   SCKS        GET SSR CHECKSUM ENTRY
          LDDL   T3          SET NEW CHECKSUM
          STDL   W5
          LDDL   W1          REWRITE SSR CHECKSUM ENTRY
          RJM    INS
          CWDL   W2
          LJM    MCSX        RETURN

*         ENDX   CTP$SCI MOVE AND COMPLETE SSR.
