          SPACE  4,10
*         CTEXT  CTP$SCI PRESET EICB MSG BUFFER.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO PRESET THE
*         EICB MESSAGE BUFFER AT DEADSTART TIME.
 PEM      SPACE  4,25
**        PEM - PRESET EICB MESSAGE BUFFER.
*
*         MOVE THE CURRENT EICB MESSAGE BUFFER (DFCM+1 - DFCM+3) TO THE SAVE
*         AREA FOR THE EICB MESSAGE BUFFER (DFCM+4 - DFCM+6) AND ENTER BLANKS
*         IN THE CURRENT MESSAGE BUFFER.  IF THE CURRENT EICB MESSAGE BUFFER
*         CONTAINS ZEROS (EICB HAS JUST BEEN INITIALIZED), THEN SIMPLY ENTER
*         BLANKS INTO BOTH BUFFERS.
*
*         EXIT   EICB MESSAGE BUFFER CONTAINS BLANKS.
*                EICB SAVED MESSAGE BUFFER CONTAINS EITHER THE PREVIOUS MESSAGE
*                OR BLANKS.
*
*         USES   CM - CM+3.
*
*         CALLS  IIB.


 PEM      SUBR               ENTRY/EXIT
          LDN    DFCM        SET MESSAGE ID = 1, LENGTH = 24
          RJM    IIB
          CWML   PEMA,ON
          CRDL   CM          READ FIRST WORD OF CURRENT MESSAGE
          ADN    3           INITIALIZE SAVE AREA TO BLANKS
          CWML   PEMB,ON
          CWML   PEMB,ON
          CWML   PEMB,ON
          LDDL   CM
          ZJN    PEM10       IF CURRENT MESSAGE CONTAINS ZEROS
          LDN    DFCM+4      SAVE FIRST WORD
          RJM    IIB
          CWDL   CM
          SBN    2           GET SECOND WORD
          CRDL   CM
          ADN    3           SAVE SECOND WORD
          CWDL   CM
          SBN    2           GET THIRD WORD
          CRDL   CM
          ADN    3           SAVE THIRD WORD
          CWDL   CM
 PEM10    LDN    DFCM+1      BLANK CURRENT MESSAGE BUFFER
          RJM    IIB
          CWML   PEMB,ON
          CWML   PEMB,ON
          CWML   PEMB,ON
          LJM    PEMX        RETURN

 PEMA     VFD    16/,16/24D,16/,16/1
 PEMB     DATA   8H

*         ENDX   CTP$SCI PRESET EICB MSG BUFFER.
