          SPACE  4,10
*         CTEXT  CTP$SCI RELOCATE MPS REGISTERS.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO CREATE
*         ABSOLUTE ADDRESSES FOR THE DEADSTART EXCHANGE PACKAGE.
 RMP      SPACE  4,15
**        RMP - RELOCATE MONITOR PROCESS.
*
*         ENTRY  BOOT LOADED.
*                (BL - BL+1) = R-ADDRESS OF BOOT.
*                (MBUF - MBUF+3) = FBA OF BOOT.
*
*         EXIT   MPS SEGMENT TABLE ADDRESS RELOCATED.
*                MPS POINTER STORED IN HDWR.
*                (IDRA+2 - IDRA+3) = MPS POINTER.
*
*         USES   T5, CM - CM+3, CN - CN+1, MBUF - MBUF+3*4.
*
*         CALLS  SPB, SPR.
*
*         MACROS SSRE.


 RMP      SUBR               ENTRY/EXIT
          LDC    RR+2        FETCH OFFSET TO MPS
          LRD    BL
          CRDL   CM
          LDDL   CM+1        BUILD MPS FOR HDWR AND DFT REQUEST
          ADML   MBUF+3
          STML   IDRA+3
          STDL   CM+3
          SHN    -20
          ADDL   CM
          ADML   MBUF+2
          STML   IDRA+2
          STDL   CM+2
          LDN    0
          STDL   CM
          STDL   CM+1
          LDDL   CM+2        BUILD R-POINTER TO MPS
          SHN    -5
          STD    CN
          LDDL   CM+2
          LPN    37
          SHN    7
          STD    CN+1
          LDN    2
          STD    T5
          LRD    CN
          LDDL   CM+3
          SHN    -3
          ADC    RR+34D
          CRML   MBUF+2*4,T5 FETCH SEGMENT TABLE ADDRESS
          LDML   MBUF+3
          RAML   MBUF+3*4    RELOCATE LOWER PART OF STA
          SHN    -20
          ADML   MBUF+2
          RAML   MBUF+2*4    RELOCATE UPPER PART OF STA
          RJM    SPB         SET PP BOUNDARY
          LDDL   CM+3
          SHN    -3
          ADC    RR+34D
          CWML   MBUF+2*4,T5 WRITE RELOCATED SEGMENT TABLE ADDRESS
          SSRE   HDWR        WRITE THE MPS WORD IN HBUF
          ADN    1
          CWDL   CM
          SBN    1
          RJM    SPR         SET UP PROCESSOR REQUEST
          LJM    RMPX        RETURN

*         ENDX   CTP$SCI RELOCATE MPS REGISTERS.
