          SPACE  4,10
*         CTEXT  CTP$SCI SET IOU NUMBER.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO
*         SET THE SCI IOU NUMBER AND MODEL NUMBER INTO WORD
*         *D8ST* OF THE EICB.
 SSI      SPACE  4,10
**        SSI - SET *SCI* IOU NUMBER AND MODEL NUMBER.
*
*         ENTRY  (A) = *SCI* IOU NUMBER.
*
*         EXIT   (*D8ST*) UPDATED WITH THE *SCI* IOU NUMBER AND MODEL NUMBER,
*                         AND PP NUMBER.
*
*         USES   T1, CM - CM+3.
*
*         CALLS  IIB, SPB.


 SSI      SUBR               ENTRY/EXIT
          STD    T1          SAVE IOU NUMBER
          LDN    D8ST        READ WORD *D8ST*
          RJM    IIB
          CRDL   CM
          LDDL   CM+2
          LPC    0#FC        CLEAR OLD IOU AND PP NUMBERS
          LMDL   T1          SET IOU NUMBER
          STDL   CM+2
          LDM    PPNO        SET PP NUMBER
          SHN    10
          RADL   CM+2
          LDM    IOUM        SET IOU MODEL NUMBER
          SHN    5
          STDL   T1
          LDDL   CM+1
          LPC    160037
          LMDL   T1
          STDL   CM+1
          RJM    SPB         SET PP BOUNDS
          LDN    D8ST        REWRITE WORD *EICB*
          RJM    IIB
          CWDL   CM
          UJN    SSIX        RETURN

*         ENDX   CTP$SCI BUILD CIP TABLES.

