          SPACE  4,10
*         CTEXT  CTP$SCI VERIFY MEMORY BOUNDS.
*
*         THIS DECK CONTAINS A ROUTINE WHICH CAN BE USED TO VERIFY
*         THE NOS/VE MEMORY BOUNDS IN THE EICB.
 VMB      SPACE  4,10
**        VMB - VERIFY MEMORY BOUNDS.
*
*         EXIT   (LA - LA+1) UPDATED IF REQUIRED.
*                (SZ - SZ+1) UPDATED IF REQUIRED.
*
*         CALLS  FMV, UMB.


 VMB20    RJM    UMB         UPDATE MEMORY BOUND VALUES

 VMB      SUBR               ENTRY/EXIT
          RJM    FMV         FETCH MEMORY BOUND VALUES
          LDD    CM+3        CHECK LWA OF NOS/VE
          ADD    CM+2
          ZJN    VMB20       IF NO MEMORY BOUNDS ESTABLISHED
          LDD    SZ          COMPARE OLD AND NEW MEMORY SIZES
          SBD    CM+2
          NJN    VMB5        IF TEST IS SIGNIFICANT
          LDDL   SZ+1
          SBDL   CM+3
 VMB5     MJN    VMB10       IF NEW SYSTEM HAS LESS MEMORY
          LRD    CM+2
          SRD    SZ
          LDM    HPSM        ROUND CM SIZE DOWN TO PAGE BOUNDARY
          LMC    7777
          LPDL   SZ+1
          STD    SZ+1
 VMB10    LDD    LA          COMPARE OLD AND NEW LOAD ADDRESSES
          SBD    CM
          NJN    VMB15       IF TEST IS SIGNIFICANT
          LDD    LA+1
          SBD    CM+1
 VMB15    PJN    VMB20       IF NEW SYSTEM LOAD ADDRESS IS GREATER
          LRD    CM          SET OLD LOAD ADDRESS
          SRD    LA
          UJN    VMB20       UPDATE CM POINTERS AND RETURN

*         ENDX   CTP$SCI VERIFY MEMORY BOUNDS.
