          CTEXT  CTP$SCI VPB IDLE IOU0
          SPACE  4,10
          BASE   M
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC. 1992
 IAD      SPACE  4,15
**        IAD - IDLE ALL I/O DRIVERS IN IOU 0.
*
*         ENTRY  (CBUF) = PP/CHANNEL MAP.
*
*         EXIT   FOR IOU 0, ALL PPS IN THE MAP IDLED AND CHANNELS
*                DCN-D.
*
*         NOTE   ON AN S0/S0E, CHANNELS IN CLUSTER 2 ARE *NOT* DCN-D.
*
*         CALLS  IVP.
*
*         USES   T3, T4, T5, T7.


 IAD      SUBR               ENTRY/EXIT
          LDN    34          INITIALIZE TABLE SIZE
          STD    T7
          SHN    1
          STD    T5
          LDN    0
          STD    T4
 IAD10    LDM    CBUF,T4
          SHN    21-7
          PJN    IAD40       IF PP IS NOT USED
          LDD    T4
          SBD    T7
          PJN    IAD20       IF CIO PP
          LDD    T4
          UJN    IAD30       IDLE VE PP

 IAD20    LDN    1S5         CIO BIT
          SHN    10-5
          LMD    T4          ADD PP NUMBER
          SBD    T7
 IAD30    RJM    IVP         IDLE VE PP
          LDML   CBUF,T4
          LPC    0#FF00
          STML   CBUF,T4
 IAD40    AOD    T4          INCREMENT TO NEXT PP IN TABLE
          SBD    T5
          NJN    IAD10       IF MORE PP-S TO IDLE
*         LDN    0
          STD    T3
 IAD50    LDML   CBUF,T3     CHECK CHANNEL STATUS
          SHN    21-17
          PJN    IAD70       IF UNUSED CHANNEL
          LDD    T3
          SBD    T7
          PJN    IAD60       IF CIO CHANNEL
          LDD    T3
          ADC    DCNI+40     DEACTIVATE POSSIBLE ACTIVE CHANNEL
          STM    IADA
 IADA     DCN    **+40
 IAD60    LDML   CBUF,T3
          LPC    0#00FF
          STML   CBUF,T3
 IAD70    AOD    T3          INCREMENT TO NEXT CHANNEL IN TABLE
          SBD    T5
          NJN    IAD50       IF MORE CHANNELS TO DEACTIVATE
          LJM    IADX        RETURN
 IVP      SPACE  4,10
**        IVP - IDLE VE PP.
*
*         ENTRY  (A) = PP TO IDLE.
*
*         USES   T3.
*
*         CALLS  IDP, SCF.


 IVP10    LDD    T3
          RJM    IDP         IDLE PP
 IVP20    CCF    *,MX

 IVP      SUBR               ENTRY/EXIT
          STD    T3
          LDN    MX
          RJM    SCF         INTERLOCK TWO PORT MUX
          LDM    S0FLG       TEST IOU TYPE
          ZJN    IVP10       IF NOT AN S0/S0E
          LDD    T3
          RJM    /"PRGNAM"AD/IDP
          UJN    IVP20       CLEAR CHANNEL FLAG AND EXIT


          BASE   *
          ENDX

