PROC fs_confidence_test, fsct (served_family, sf:  name= testing
 pf_number, pn: integer 0 .. 1000000 = 2
 ckb_number, cn: integer 0 .. 1000000 = 0
 establish_condition_handler, ech: boolean = true
 compare_times, ct: boolean = TRUE
 save_print, sp: boolean = false
 status)

  IF $value(compare_times) AND (($mainframe(id) = '$SYSTEM_0860_0302') OR ..
        ($mainframe(id) = '$SYSTEM_0830_0604')) THEN
    generate_ptu_summary size=10000000 family=$value(served_family) user=$system ..
          write_modified_pages=TRUE free_pages=TRUE loop_count=1 collect_mmio_data=TRUE ..
          compare_times=TRUE allocation_size=#16k
  IFEND

  IF $value(ckb_number) > 0 THEN
    ckbm nj=$value(ckb_number)  ic=3  sf=$value(served_family) cc=true ..
        $value(establish_condition_handler)
  IFEND
  family = $string($value(served_family))
  handler = $strrep($value(establish_condition_handler))
  save_output = $strrep($value(save_print))
  FOR i = 1 to $value(pf_number) DO
    JOB jn =$name('PF_TEST'//$strrep(i))   sm ='?'
       IF ?handler? THEN
         WHEN any_fault do
           reqoa ' PF_TEST?$strrep(i)? failed  '//$condition_name(osv$status.condition)
           display_value osv$status
           logout
         WHENEND
       IFEND

      " Clean up - just in case
      " Enter system_operator_utility to get system privilege
      system_operator_utility
      crev ignore status
      delete_file  $fname(':?family?.$system.scu?$strrep(i)?') status=ignore
      delete_file  $fname(':?family?.$system.scq?$strrep(i)?') status=ignore


      " test allocate
      copy_file $system.scu.bound_product ..
         $fname(':?family?.$system.scu?$strrep(i)?')
      " test write
      copy_file $system.scu.bound_product ..
         $fname(':?family?.$system.scu?$strrep(i)?')
      " test permanent files
      crefp $fname(':?family?.$system.scu?$strrep(i)?') g=public
      disce $fname(':?family?.$system.scu?$strrep(i)?') do=c
      " test read - write
      copy_file $fname(':?family?.$system.scu?$strrep(i)?')  ..
           $fname(':?family?.$system.scq?$strrep(i)?')
      compare_file $system.scu.bound_product ..
           $fname(':?family?.$system.scq?$strrep(i)?')
      delete_file  $fname(':?family?.$system.scu?$strrep(i)?')
      delete_file  $fname(':?family?.$system.scq?$strrep(i)?')
      disc $fname(':?family?.$system')
      quit " system_operator_utility "
       IF NOT ?save_output? THEN
         terp output
      IFEND
    JOBEND
  FOREND

PROCEND fs_confidence_test

