PROC dfm$submit_maxtr_jobs, submtrj (
  jobs, j                          : integer 0..1000000 = 16
  size, s                          : integer = 409600
  mode, m                          : key normal, n, sequential, s = N
  number_of_passes, nop, number, n : integer = 1000
  file_name_seed, fns              : file = :testing.$system.test_
  allocation_size, as              : key #16K, #32K, #65K, #131K, #262K = #16K
  status                           : var of status = $optional
  )

  mode = $string($value(mode))
  size = $strrep($value(size))
  number_of_passes = $strrep($value(number_of_passes))
  file_name_seed = $string($value(file_name_seed))
  as_value = $string($value(allocation_size))
  IF as_value = '#16K' THEN
    alloc_size = '16384'
  ELSEIF as_value = '#32K' THEN
    alloc_size = '32768'
  ELSEIF as_value = '#65K' THEN
    alloc_size = '65536'
  ELSEIF as_value = '#131K' THEN
    alloc_size = '131072'
  ELSEIF as_value = '#262K' THEN
    alloc_size = '262144'
  IFEND

  FOR i = 1 TO $value(jobs) DO
     job jn=$name('MAXTR'//$strrep(i)) sm='?'
        create_variable ign kind=status
        system_operator_utility
        copf $system.osf$builtin_library $local.built  status=ign
        setcl a=$local.built status=ign
        setpa al=$local.cyf$run_time_library status=ign
        exet  sp=rmp$request_mass_storage_cmd ..
              p='F=?file_name_seed??$STRREP(i)?  ALLOCATION_SIZE=?alloc_size?'
        detf F=?file_name_seed??$STRREP(i)? status=ign
        dfp$mtr ?file_name_seed??$STRREP(i)? ..
           mode=?mode? size=?size? number_of_passes=?number_of_passes?
    jobend
  FOREND

PROCEND dfm$submit_maxtr_jobs
