          CTEXT  DSI$DUMP LOAD IDLE PP                                   R123_OS        1
          SPACE  4,10                                                    R123_OS        2
          IF     -DEF,QUAL$,1                                            R123_OS        3
          QUAL   COMPIDP                                                 R123_OS        4
          BASE   M                                                       R123_OS        5
 IDP      SPACE  4,10                                                    R123_OS        6
***              DSI$DUMP LOAD IDLE CONTAINS THE ROUTINES                R123_OS        7
*         USED TO DUMP, LOAD, AND IDLE PPS VIA THE                       R123_OS        8
*         MAINTENANCE CHANNEL.                                           R123_OS        9
*                                                                        DOH_58         1
*         A ROUTINE, *MCH*, TO MASTER CLEAR A SPECIFIC CHANNEL           DOH_58         2
*         IS ALSO AVAILABLE IF THE SYMBOL *MCH$* IS DEFINED.             DOH_58         3
                                                                         DOH_58         4
                                                                         R123_OS       10
 PPNO     BSS    0           PP TYPE AND NUMBER PASSED AS PARAMETER.     R123_OS       11
          VFD    8/0         PP TYPE,                                    R123_OS       12
                               = 0 IMPLIES NONCONCURRENT.                R123_OS       13
                               = 1 IMPLIES CONCURRENT.                   R123_OS       14
          VFD    8/0         PP NUMBER.                                  R123_OS       15
 PPCH     CON    0           PP / CH INDICATOR (0=PP, 1=CH)              DOH_315        1
 PPR      SPACE  4,15                                                    DOH_315        2
**        PPR - PRESET PP ROUTINES.                                      R123_OS       17
*                                                                        R123_OS       18
*         DETERMINES IF NIO OR CIO PP TO BE LOADED AND SETS EC, AND      R123_OS       19
*         STATUS REGISTER NUMBERS ACCORDINGLY.                           R123_OS       20
*                                                                        R123_OS       21
*         ENTRY  (A) = PP NUMBER AND TYPE OF PP.                         R123_OS       22
*                                                                        R123_OS       23
*         USES                                                           R123_OS       26
*                *PPRE* TO HOLD REGISTER NUMBER FOR ENVIRONMENT CONTROL. R123_OS       27
*                *PPRS* TO HOLD REGISTER NUMBER FOR STATUS REGISTER.     R123_OS       28
*                                                                        R123_OS       29
*         CALLS  RII, SPM.                                               KAP_2011       1
                                                                         KAP_87         5
                                                                         R123_OS       30
 PPR      SUBR               ENTRY/EXIT                                  R123_OS       31
          STM    PPNO        SAVE PP TYPE AND NUMBER                     R123_OS       32
          SHN    21-10       GET TYPE                                    R123_OS       33
          PJN    PPR1        IF NIO PP                                   R123_OS       34
          LDM    IOUM                                                    GJF_8138       1
          LMC    0#42                                                    GJF_8140       1
          NJN    PPR0        IF NOT I4S IOU                              KAP_4035       1
          LDN    30B                                                     KAP_4035       2
          RAML   PPNO        BIAS BY 30(8) FOR CIO PP                    KAP_4035       3
          UJN    PPR1                                                    GJF_8138       7
                                                                         GJF_8138       8
 PPR0     LDN    ECIO                                                    GJF_8138       9
          STM    PPRE        SAVE REG NO FOR CIO ENV. CTRL               R123_OS       36
          LDC    SCIO                                                    R123_OS       37
          STM    PPRS        SAVE REG NO FOR CIO STATUS REG              R123_OS       38
          UJN    PPR2        CONTINUE                                    R123_OS       39
                                                                         R123_OS       40
 PPR1     LDN    ENIO                                                    R123_OS       41
          STM    PPRE        REG NO FOR NIO ENV CTRL                     R123_OS       42
          LDC    SNIO                                                    R123_OS       43
          STM    PPRS        REG NO FOR NIO STATUS REG                   R123_OS       44
 PPR2     RJM    SPM         SET PP MODE                                 DOH_315        3
          LDM    I0CC                                                    DOH_315        4
          STD    EC          SET UP CONNECT CODE                         R123_OS       47
          RJM    RII         READ IOU EC REGISTER                        KAP_2011       2
          LDML   PPCH                                                    DOH_315        5
          NJP    PPRX        IF CHANNEL REQUEST                          GJF_8138      10
          LDM    IDPA+4                                                  R123_OS       51
          LPC    0#C0        PRESERVE SYSTEM INITIALIZED BIT             DOH_315        7
          LMM    PPRA                                                    R123_OS       53
          STM    IDPA+4                                                  R123_OS       54
          LJM    PPRX        RETURN                                      R123_OS       55
                                                                         R123_OS       56
 PPRE     CON    0           ENVIRONMENT CONTROL REGISTER NUMBER         R123_OS       57
 PPRA     CON    0           STORAGE FOR ENV CTRL BYTE 4                 R123_OS       58
 PPRS     CON    0           STATUS REGISTER NUMBER                      R123_OS       59
 SPM      SPACE  4,10                                                    R123_OS       60
**        SPM - SET PP MODE.                                             R123_OS       61
*                                                                        R123_OS       62
*         SETS PP MODE IN ENVIRONMENT CONTROL FOR 4K OR 8K.              R123_OS       63
                                                                         KAP_87         6
                                                                         KAP_87         7
 SPM1     LDM    PPNO                                                    KAP_2011       3
          LPN    0#1F        MAKE JUST PP NUMBER                         KAP_2011       4
          SCN    40                                                      KAP_2011       5
          LMN    40          SET AUTO BIT                                KAP_2011       6
          STM    PPRA                                                    KAP_2011       7
                                                                         KAP_2011       8
 SPM      SUBR               ENTRY/EXIT                                  R123_OS       65
          LDM    PPNO        GET PP NUMBER                               R123_OS       66
          SHN    21-10                                                   R123_OS       67
          PJN    SPM1        IF NIO PP                                   R123_OS       68
          LDM    PPNO                                                    R123_OS       69
          LPC    0#7F        CLEAR MODE PARAMETER BIT                    R123_OS       70
          STM    PPRA                                                    R123_OS       72
          UJN    SPMX        RETURN                                      DOH_315        8
 IDP      SPACE  4,10                                                    KAP_81         1
**        IDP - IDLE PP.                                                 R123_OS       83
*                                                                        R123_OS       84
*         ENTRY  (A) = PP TYPE AND NUMBER TO IDLE.                       R123_OS       85
*                                                                        R123_OS       86
*         EXIT   PP IDLED.                                               R123_OS       87
*                                                                        R123_OS       88
*         USES   RN, EC, T6.                                             R123_OS       89
*                                                                        KAP_87         8
*         CALLS  CIE, PPR, WFI, WII.                                     KAP_87         9
                                                                         R123_OS       90
                                                                         R123_OS       91
 IDP      SUBR               ENTRY/EXIT                                  R123_OS       92
          RJM    PPR         PRESET PP                                   R123_OS       93
          LDM    IDPA+6      SET IDLE, K REGISTER                        KAP_87        10
          SCN    37                                                      KAP_87        11
          LMN    6                                                       KAP_87        12
          STM    IDPA+6                                                  R123_OS       95
          LDM    IDPA+7                                                  R123_OS       96
          SCN    40                                                      R123_OS       97
          LMN    40          SET ENABLE IDLE, BIT58                      R123_OS       98
          STM    IDPA+7                                                  R123_OS       99
          LDN    16         DUMMY CHANNEL                                R123_OS      100
          STM    IDPA+5                                                  R123_OS      101
          RJM    WII         WRITE IOU REGISTER TO IDLE PP               KAP_87        13
          RJM    WFI         WAIT FOR IDLE                               R123_OS      103
                                                                         R123_OS      104
*         NOTE THE FOLLOWING COMMENTED CODE SHOULD BE USED HOWEVER       R123_OS      105
*         IT IS NOT BECAUSE EXECUTING IT ON AN I2 WILL NOT               R123_OS      106
*         REALLY IDLE THE PP. THERE WAS AN FCO 2705 WHICH SUPPOSEDLY     R123_OS      107
*         FIXES THIS.                                                    R123_OS      108
                                                                         R123_OS      109
*         NJN    IDP1        IF NOT SUCESSFUL                            R123_OS      110
*         RJM    CIE         CLEAR IOU EC REGISTER                       R123_OS      111
*         LJM    IDPX                                                    R123_OS      112
                                                                         R123_OS      113
*         DEADSTART PP INTO IDLE MODE.                                   R123_OS      114
*                                                                        KAP_81         2
*         IF AT THE TIME THE PP WAS IDLED, IT WAS HUNG AT A CHANNEL      KAP_81         3
*         FUNCTION INSTRUCTION, THE DUMP IDLE WILL CAUSE A FORCED EXIT   KAP_81         4
*         OF THE INSTRUCTION.  BECAUSE THIS IS DONE WITH AN OAM          KAP_81         5
*         INSTRUCTION, THE P ADDRESS (AFTER THE PP IS DUMP IDLED) WILL   KAP_81         6
*         BE SET TO WHATEVER HAPPENS TO BE IN PP ADDRESS 0 + 1.          KAP_81         7
                                                                         R123_OS      115
 IDP1     LDM    IDPA+6      SET DUMP, IDLE, K REGISTER                  KAP_87        14
          SCN    37                                                      KAP_87        15
          LMN    16                                                      KAP_87        16
          STM    IDPA+6                                                  R123_OS      117
          LDM    IDPA+7                                                  R123_OS      118
          SCN    40                                                      R123_OS      119
          LMN    40          SET ENABLE                                  R123_OS      120
          STM    IDPA+7                                                  R123_OS      121
          LDM    PPRE                                                    R123_OS      122
          STD    RN                                                      R123_OS      123
          RJM    WII         WRITE IOU EC REGISTER                       KAP_87        17
          RJM    WFI         WAIT FOR IDLE                               R123_OS      125
          RJM    CIE         CLEAR IOU EC REGISTER                       R123_OS      126
          LJM    IDPX        RETURN                                      R123_OS      127
                                                                         R123_OS      128
 IDPA     BSS    10                                                      R123_OS      129
 WFI      SPACE  4,15                                                    KAP_87        18
**        WFI - WAIT FOR IDLE.                                           R123_OS      131
*                                                                        R123_OS      132
*         ENTRY  (IDPA - IDPA+7) = CURRENT EC REGISTER.                  R123_OS      133
*                                                                        R123_OS      134
*         EXIT   (A) = 0 IF PP IS IDLING.                                R123_OS      135
*                                                                        R123_OS      136
*         USES   RN, T6.                                                 R123_OS      137
*                                                                        KAP_87        19
*         CALLS  WII.                                                    KAP_87        20
*                                                                        KAP_87        21
*         MACROS LOCKMR, READMR.                                         KAP_87        22
                                                                         R123_OS      138
                                                                         R123_OS      139
 WFI      SUBR               ENTRY/EXIT                                  R123_OS      140
          LDC    4096D/5                                                 R123_OS      141
          STD    T1                                                      R123_OS      142
          LDM    IDPA+6      SELECT K REGISTER                           KAP_87        23
          SCN    37                                                      KAP_87        24
          LMN    2                                                       KAP_87        25
          STM    IDPA+6                                                  R123_OS      144
          LDM    IDPA+7      CLEAR DUMP/LOAD/IDLE ENABLE BIT             R123_OS      145
          SCN    40                                                      R123_OS      146
          STM    IDPA+7                                                  R123_OS      147
 WFI1     LOCKMR SET                                                     R123_OS      148
          LDM    PPRE                                                    R123_OS      149
          STD    RN                                                      R123_OS      150
          RJM    WII         SET K REGISTER DISPLAY                      KAP_87        26
          LDM    PPRS                                                    R123_OS      152
          STD    RN                                                      R123_OS      153
          READMR WFIA        READ STATUS REGISTER                        R123_OS      154
          LOCKMR CLEAR                                                   R123_OS      155
          LDM    WFIA+4                                                  R123_OS      156
          LPN    3                                                       R123_OS      157
          SHN    10                                                      R123_OS      158
          ADM    WFIA+5                                                  R123_OS      159
          SHN    10                                                      R123_OS      160
          ADM    WFIA+6                                                  R123_OS      161
          SHN    -6          INTERNAL REGISTER CONTENT OF SELECTED PP    R123_OS      162
          LMC    1077                                                    R123_OS      163
          ZJN    WFI3        IF IDLED                                    R123_OS      164
          SOD    T1                                                      R123_OS      165
          ZJN    WFI2        IF TIMED OUT                                R123_OS      166
          LJM    WFI1        TRY AGAIN                                   R123_OS      167
                                                                         R123_OS      168
 WFI2     LDN    77                                                      R123_OS      169
 WFI3     LJM    WFIX        RETURN                                      R123_OS      170
                                                                         R123_OS      171
 WFIA     BSSZ   10                                                      R123_OS      172
 DLP      SPACE  4,10                                                    R123_OS      173
***       DLP - DEADSTART LOAD PP.                                       R123_OS      174
*                                                                        R123_OS      175
*         ENTRY  (A) = PP TYPE AND NUMBER.                               R123_OS      176
*                (T1) = CHANNEL NUMBER TO DEADSTART PP TO.               R123_OS      177
*                                                                        R123_OS      178
*         EXIT   PP DOING BLOCK INPUT ON CHANNEL (T1).                   R123_OS      179
*                                                                        R123_OS      180
*         USES   EC, RN, T1, T6.                                         R123_OS      181
*                                                                        KAP_87        27
*         CALLS  CIE, PDC, PPR, WII.                                     KAP_87        28
                                                                         R123_OS      182
                                                                         R123_OS      183
 DLP      SUBR               ENTRY/EXIT                                  R123_OS      184
          RJM    PPR                                                     R123_OS      185
          LDD    T1                                                      R123_OS      186
          STM    IDPA+5                                                  R123_OS      187
          LDM    IDPA+6      SET LOAD MODE                               KAP_87        29
          SCN    37          PRESERVE UPPER BITS                         KAP_87        30
          ADN    20                                                      KAP_87        31
          STM    IDPA+6                                                  R123_OS      189
          LDM    IDPA+7                                                  R123_OS      190
          SCN    40                                                      R123_OS      191
          LMN    40                                                      R123_OS      192
          STM    IDPA+7                                                  R123_OS      193
          RJM    PDC         PREPARE DEADSTART CHANNEL                   R123_OS      194
          RJM    WII         DEADSTART LOAD IOU                          KAP_87        32
          RJM    CIE         CLEAR IOU EC REGISTER                       R123_OS      196
          UJN    DLPX        RETURN                                      KAP_87        33
 DDP      SPACE  4,10                                                    R123_OS      198
***       DDP - DEADSTART DUMP PP.                                       R123_OS      199
*                                                                        R123_OS      200
*         ENTRY  (A) = PP TYPE AND NUMBER.                               R123_OS      201
*                (T1) = CHANNEL NUMBER ON DEADSTART PP ON.               R123_OS      202
*                                                                        R123_OS      203
*         EXIT   PP DOING BLOCK OUTPUT ON CHANNEL (T1).                  R123_OS      204
*                                                                        R123_OS      205
*         USES   EC, RN, T1, T6.                                         R123_OS      206
*                                                                        KAP_87        34
*         CALLS  CIE, PDC, PPR, WII.                                     KAP_87        35
                                                                         R123_OS      207
                                                                         R123_OS      208
 DDP      SUBR               ENTRY/EXIT                                  R123_OS      209
          RJM    PPR                                                     R123_OS      210
          LDD    T1                                                      R123_OS      211
          STM    IDPA+5                                                  R123_OS      212
          LDM    IDPA+6      SET DUMP + IDLE MODE                        KAP_87        36
          SCN    37                                                      KAP_87        37
          LMN    14                                                      KAP_87        38
          STM    IDPA+6                                                  R123_OS      214
          LDM    IDPA+7                                                  R123_OS      215
          SCN    40                                                      R123_OS      216
          LMN    40                                                      R123_OS      217
          STM    IDPA+7                                                  R123_OS      218
          RJM    PDC         PREPARE DEADSTART CHANNEL                   R123_OS      219
          RJM    WII         DEADSTART LOAD IOU                          KAP_87        39
          RJM    CIE         CLEAR IOU EC REGISTER                       R123_OS      221
          UJN    DDPX        RETURN                                      R123_OS      222
 .A       IF     DEF,MCH$                                                DOH_58         7
 MCH      SPACE  4,10                                                    DOH_55         6
**        MCH - MASTER CLEAR CHANNEL.                                    DOH_55         7
*                                                                        DOH_55         8
*         ENTRY  (A) = CHANNEL TYPE AND NUMBER.                          DOH_55         9
*                                                                        DOH_55        10
*         EXIT   CHANNEL MASTER CLEARED.                                 DOH_55        11
*                                                                        KAP_87        40
*         CALLS  CIE, PPR, WII.                                          KAP_87        41
                                                                         DOH_55        12
                                                                         DOH_55        13
 MCH      SUBR               ENTRY/EXIT                                  DOH_55        14
          STDL   T1                                                      DOH_315        9
          LDN    1           SET CHANNEL PROCESSING                      DOH_315       10
          STML   PPCH                                                    DOH_315       11
          LDDL   T1                                                      DOH_315       12
          RJM    PPR         PRESET PP ROUTINES                          DOH_55        19
          LDML   IDPA+5      SET CHANNEL NUMBER                          DOH_55        20
          LPC    0#FFE0                                                  DOH_55        21
          STML   IDPA+5                                                  DOH_55        22
          LDML   PPNO                                                    DOH_55        23
          LPC    0#1F                                                    DOH_55        24
          RAML   IDPA+5                                                  DOH_55        25
          LDML   IDPA+7      SET INDIVIDUAL CHANNEL MASTER CLEAR         DOH_221        1
          SCN    2                                                       DOH_55        27
          LMN    2                                                       DOH_55        28
          STML   IDPA+7                                                  DOH_55        29
          RJM    WII         MASTER CLEAR CHANNEL                        KAP_87        42
          RJM    CIE         CLEAR IOU EC REGISTER                       DOH_55        31
          LDN    0           SET DEFAULT MODE                            DOH_315       13
          STML   PPCH                                                    DOH_315       14
          UJP    MCHX        RETURN                                      DOH_55        34
 .A       ENDIF                                                          DOH_58         8
 CIE      SPACE  4,10                                                    R123_OS      223
**        CIE - CLEAR IOU EC REGISTER.                                   R123_OS      224
*                                                                        R123_OS      225
*         ENTRY  (EC) = I0CC.                                            R123_OS      226
*                                                                        R123_OS      227
*         EXIT   IOU EC REGISTER RESET.                                  R123_OS      228
*                                                                        KAP_87        43
*         CALLS  RII, WII.                                               KAP_2011       9
                                                                         R123_OS      229
                                                                         R123_OS      230
 CIE      SUBR               ENTRY/EXIT                                  R123_OS      231
          RJM    RII         READ IOU EC REGISTER                        KAP_2011      10
          LDN    0                                                       R123_OS      235
          STM    IDPA+5                                                  R123_OS      236
          LDM    IDPA+6                                                  KAP_87        47
          SCN    37                                                      KAP_87        48
          STM    IDPA+6                                                  R123_OS      237
          LDM    IDPA+7                                                  R123_OS      238
          SCN    40                                                      R123_OS      239
          STM    IDPA+7      CLEAR ENABLE DUMP/LOAD/IDLE                 R123_OS      240
          LDM    IDPA+4                                                  R123_OS      241
          LPC    0#C0        SAVE UPPER BITS                             DOH_315       15
          STM    IDPA+4                                                  R123_OS      243
          RJM    WII         WRITE IOU EC REGISTER                       KAP_87        49
          UJN    CIEX        RETURN                                      KAP_2011      11
 PDC      SPACE  4,10                                                    R123_OS      246
**        PDC - PREPARE DEADSTART CHANNEL.                               R123_OS      247
*                                                                        R123_OS      248
*         ENTRY  (T1) = CHANNEL NUMBER TO DEADSTART PP ON.               R123_OS      249
*                                                                        R123_OS      250
*         EXIT   CHANNEL ACTIVE AND EMPTY.                               R123_OS      251
                                                                         R123_OS      252
                                                                         R123_OS      253
 PDC      SUBR               ENTRY/EXIT                                  R123_OS      254
          LDC    DCNI+40                                                 R123_OS      255
          LMD    T1                                                      R123_OS      256
          STM    PCHA                                                    R123_OS      257
          LMC    ACNI&DCNI                                               R123_OS      258
          STM    PCHB                                                    R123_OS      259
 PCHA     DCN    CH+40       DROP POSSIBLE ACTIVE CHANNEL                R123_OS      260
 PCH1     SBN    1                                                       R123_OS      261
          PJN    PCH1        WAIT A BIT                                  R123_OS      262
 PCHB     ACN    CH+40       ACTIVATE EMPTY CHANNEL                      R123_OS      263
          UJN    PDCX        RETURN                                      R123_OS      264
 RII      SPACE  4,10                                                    KAP_2011      12
**        RII - READ IOU EC REGISTER INTO *IDPA*.                        KAP_2011      13
*                                                                        KAP_2011      14
*         ENTRY  (EC) = IOCC.                                            KAP_2011      15
*                (PPRE) = REGISTER NUMBER.                               KAP_2011      16
*                                                                        KAP_2011      17
*         EXIT   (IDPA - IDPA+7) = IOU EC REGISTER.                      KAP_2011      18
*                                                                        KAP_2011      19
*         USES   RN.                                                     KAP_2011      20
*                                                                        KAP_2011      21
*         MACROS READMR.                                                 KAP_2011      22
                                                                         KAP_2011      23
                                                                         KAP_2011      24
 RII      SUBR               ENTRY/EXIT                                  KAP_2011      25
          LDM    PPRE        SET REGISTER NUMBER                         KAP_2011      26
          STD    RN                                                      KAP_2011      27
          READMR IDPA        READ IOU EC REGISTER                        KAP_2011      28
          UJN    RIIX        RETURN                                      KAP_2011      29
 WII      SPACE  4,10                                                    KAP_87        50
**        WII - WRITE IOU EC REGISTER FROM *IDPA*.                       KAP_2011      30
*                                                                        KAP_87        52
*         ENTRY  (RN) = IOU EC REGISTER NUMBER.                          KAP_87        53
*                (EC) = CONNECT CODE.                                    KAP_87        54
*                                                                        KAP_87        55
*         EXIT   IOU EC REGISTER WRITTEN.                                KAP_87        56
*                                                                        KAP_87        57
*         MACROS WRITMR.                                                 KAP_87        58
                                                                         KAP_87        59
                                                                         KAP_87        60
 WII      SUBR               ENTRY/EXIT                                  KAP_87        61
          WRITMR IDPA                                                    DOH_315       16
          UJN    WIIX        RETURN                                      KAP_87        63
          SPACE  4,10                                                    R123_OS      265
          BASE   *                                                       R123_OS      266
 QUAL$    IF     -DEF,QUAL$                                              R123_OS      267
          QUAL   *                                                       R123_OS      268
 DDP      EQU    /COMPIDP/DDP                                            R123_OS      269
 DLP      EQU    /COMPIDP/DLP                                            R123_OS      270
 IDP      EQU    /COMPIDP/IDP                                            R123_OS      271
 PPRE     EQU    /COMPIDP/PPRE                                           GJF_8055       1
 CIE      EQU    /COMPIDP/CIE                                            GJF_8055       2
 .B       IF     DEF,MCH$                                                DOH_58         9
 MCH      EQU    /COMPIDP/MCH                                            DOH_55        35
 .B       ENDIF                                                          DOH_58        10
 QUAL$    ENDIF                                                          R123_OS      272
          SPACE  4,10                                                    R123_OS      273
          ENDX                                                           R123_OS      274
