.PROC,RUNDSC*I,
C   "- COMMAND DECK"                   = (*N=,*S2(01234567)),
W   "- WAIT FOR OPERATOR INTERVENTION" = (*N=,FALSE=F,TRUE=T,F,T),
T   "- DEADSTART TYPE"                 = (*N=,CR,DISK,TAPE),
S   "- SCD PORT"                       = (*N=,0,1),
N   "- NVE SUBSYSTEM CPU PRIORITY"     = (*N=,*S2(01234567)),
.
.HELP
  THIS PROCEDURE SEQUENCES THROUGH THE VARIOUS DEADSTARTS AND
  RECOVERIES REQUIRED TO BRING UP NOS/VE AND TERMINATE IT
  WITH INTEGRITY IN THE PERMANENT FILE BASE.

.ENDHELP
.*
.*   JOB CONTROL REGISTER USAGE
.*
.*   EFG = 0,   NO ERRORS
.*         1    TO
.*         76B, NOS ERROR NUMBERS,
.*         77B, NOS/VE ERROR, R1G CONTAINS THE ERROR NUMBER.
.*
SET(R1G=0)
COMMENT.
COMMENT. START NVE DEADSTART/RECOVERY
COMMENT.
.IFE,SYS.NE.NOSB,NOSSYS1.
  SETTL,*.
  SETASL,*.
  SETJSL,*.
  .IF,$N$.NE.$$.SETPR(N)
.ENDIF,NOSSYS1.
SET(EFG=0)
DSTCMDS,C,W,T,S.
SET(R2=1)
WHILE,R2.NE.0.AND.EFG.EQ.0,PROCESS.
  DST180.
  TRM180.
  SET(R2=R1G)
  DISPLAY(R1G)
ENDW,PROCESS.
COMMENT.
COMMENT. COMPLETED NVE RUN.
COMMENT.
REVERT. END RUNDSC
/EOR
