
PROC dum$display_asid_trace, display_asid_trace (output, o: file = $output)

  crev stat status
  scr = $unique
  o = $unique
COLT $fname(scr)

  1    Low asids
  2    No asids
  3    Ast reset
  4    Free aste
  5    Assign ASID
  6    Assign specific ASID
  7    Change_asid of swapped job
  8    Change_asid of monitor-only segment
  9    Change_asid of file awaiting recovery
 10    Change asid of template segment
 11    Change asid of global file
 12    Change asid of job file
 13    Reclaim asids
 14    Make page table entry, full
 15    Make page table entry, recovered
 16    Make page table entry, rec1
 17    Make page table entry, rec2
 18    Page table full called
 19    Page table full tried
 20    Page table full failed
 21    Page table full remove
 22    Reassign asid called
 23    Reassign asid in free
 24    Reassign asid make page table entry failed
 25    Reassign asid ok
 26    Reassign asid ok1
 27    Reassign asid ok2
 28    Reassign asid ok3
 29    Reassign asid ok4
 30    Reassign asid failed
 31    Reassign asid failed 1
 32    Reassign asid failed 2
 33    Reassign asid quit
 34      (unused)
 35      (unused)
 36    Reassign asid make page table entry
 37    Delete pte of terminated job for page table full
 38      (unused)
 39      (unused)
 40      (unused)

zzz
**
  rewf $fname(scr)
  setfa $fname(scr) op=$asis
  setfa $fname(o) op=$asis
  crev s string
  rewf $fname(scr)
  accl s i=$fname(scr)


  WHILE s <> 'zzz' DO
    IF $substr(s 1 3) = '  ' THEN
      putl '          '//s o=$fname(o)
    ELSE
      i = $integer($substr(s 1 3))
      j = $mem($sa(mmv$aptm_trace)+i*4 4)
      sj = '           ' // $strrep(j)
      sk = '    '//$strrep(i);sk=$substr(sk $strlen(sk)-3 4)
      putl $substr(sj $strlen(sj)-9 10)//sk//'   '//$substr(s 4 $strlen(s)-3) o=$fname(o)
    IFEND
    accl s i=$fname(scr)
  WHILEND
  copf $fname(o//'.$boi') $value(output)
  delf $fname(scr)
  delf $fname(o)

PROCEND dum$display_asid_trace
