PROCEDURE dum$display_client_access, disca (
  output, o: file = $output
  status)

  "  This procedure displays client_access from the set family table.
  "  This procedure requires RJTs most recent dump anlyzer.
  "  This procedure assumes that osm$family_manager has been added.

  current = $default_module
  crev local_status status
  set_file_attributes output fc=legible pf=continuous
  chadm osm$family_manager
  IF $file(output open_position) = '$BOI' THEN
    rewind_file output status=local_status
  IFEND
  out = output.$eoi

search: ..
  FOR pntr = $pv(LOWERBOUND(osv$family_table^)) TO ..
       $pv(UPPERBOUND(osv$family_table^)) DO
    IF $pv(osv$family_table^[?pntr].family_name) = '   ' THEN
      CYCLE search
    IFEND
    putl ' ------  Family index '//pntr o=out
    dispv osv$family_table^[?pntr] o=out

    next_p = $pv(osv$family_table^[?pntr].p_client_access_list)
    WHILE NOT $nil_pva(next_p) DO
      dispv ?next_p.dft$family_table_client_entry o=out
      next_p = $pv(?next_p.dft$family_table_client_entry.p_next_client)
    WHILEND
  FOREND search

  chadm current

PROCEND dum$display_client_access
