?? RIGHT := 110 ??
?? NEWTITLE := 'NOS/VE Dump Analyzer : Display CTI Level Command' ??
MODULE dum$display_cti_level_command;

{ PURPOSE:
{   This module contains the code for the display_cti_level command.

?? NEWTITLE := 'Global Declarations Referenced by This Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc due$exception_condition_codes
?? POP ??
*copyc clp$close_display
*copyc clp$evaluate_parameters
*copyc clp$open_display_reference
*copyc clp$put_display
*copyc dup$new_page_procedure
*copyc dup$retrieve_cip_program
*copyc osp$disestablish_cond_handler
*copyc osp$establish_block_exit_hndlr
*copyc osp$set_status_abnormal
?? EJECT ??
*copyc duv$dump_environment_p
*copyc duv$execution_environment
*copyc duv$title_data
?? OLDTITLE ??
?? NEWTITLE := 'dup$display_cti_level_command', EJECT ??

{ PURPOSE:
{   This procedure displays the CTI level from EIC record.

  PROCEDURE [XDCL] dup$display_cti_level_command
    (    parameter_list: clt$parameter_list;
     VAR status: ost$status);

{ PROCEDURE display_cti_level, disctil (
{   output, o: file = $optional
{   title, t: string 1..31 = 'display_cti_level'
{   status)

?? PUSH (LISTEXT := ON) ??
?? FMT (FORMAT := OFF) ??
  VAR
    pdt: [STATIC, READ, cls$declaration_section] record
      header: clt$pdt_header,
      names: array [1 .. 5] of clt$pdt_parameter_name,
      parameters: array [1 .. 3] of clt$pdt_parameter,
      type1: record
        header: clt$type_specification_header,
      recend,
      type2: record
        header: clt$type_specification_header,
        qualifier: clt$string_type_qualifier,
        default_value: string (19),
      recend,
      type3: record
        header: clt$type_specification_header,
      recend,
    recend := [
    [1,
    [90, 4, 18, 8, 48, 54, 341],
    clc$command, 5, 3, 0, 0, 0, 0, 3, ''], [
    ['O                              ',clc$abbreviation_entry, 1],
    ['OUTPUT                         ',clc$nominal_entry, 1],
    ['STATUS                         ',clc$nominal_entry, 3],
    ['T                              ',clc$abbreviation_entry, 2],
    ['TITLE                          ',clc$nominal_entry, 2]],
    [
{ PARAMETER 1
    [2, clc$normal_usage_entry, clc$non_secure_parameter,
    $clt$parameter_spec_methods[clc$specify_by_name, clc$specify_positionally],
    clc$pass_by_value, clc$immediate_evaluation, clc$standard_parameter_checking, 3, clc$optional_parameter, 0
  , 0],
{ PARAMETER 2
    [5, clc$normal_usage_entry, clc$non_secure_parameter,
    $clt$parameter_spec_methods[clc$specify_by_name, clc$specify_positionally],
    clc$pass_by_value, clc$immediate_evaluation, clc$standard_parameter_checking, 8,
  clc$optional_default_parameter, 0, 19],
{ PARAMETER 3
    [3, clc$normal_usage_entry, clc$non_secure_parameter,
    $clt$parameter_spec_methods[clc$specify_by_name],
    clc$pass_by_reference, clc$immediate_evaluation, clc$standard_parameter_checking, 3,
  clc$optional_parameter, 0, 0]],
{ PARAMETER 1
    [[1, 0, clc$file_type]],
{ PARAMETER 2
    [[1, 0, clc$string_type], [1, 31, FALSE],
    '''display_cti_level'''],
{ PARAMETER 3
    [[1, 0, clc$status_type]]];
?? FMT (FORMAT := ON) ??
?? POP ??

    CONST
      p$output = 1,
      p$title = 2,
      p$status = 3;

    VAR
      pvt: array [1 .. 3] of clt$parameter_value;

    TYPE
      t$ascii_code = PACKED RECORD
        CASE boolean OF
        = TRUE =
          data_1: string (6),
          data_2: string (6),
        = FALSE =
          number: ARRAY [1 .. 12] OF 0 .. 0ff(16),
        CASEND,
      RECEND,

      t$display_code = PACKED RECORD
        unused: 0 .. 0f(16),
        char_1: 0 .. 077(8),
        char_2: 0 .. 077(8),
      RECEND;

    VAR
      ascii_code: t$ascii_code,
      char_index: 0 .. 0ff(16),
      cip_program_available: boolean,
      cip_program_cell_p: ^cell,
      display_code_p: ^t$display_code,
      display_code: ARRAY [1 .. 12] OF 0 .. 0ff(16),
      display_control: clt$display_control,
      display_string: string (osc$max_string_size),
      index: 0 .. 0ff(16),
      ignore_status: ost$status,
      level_address_size: integer,
      output_display_opened: boolean,
      restart_file_seq_p: ^SEQ ( * ),
      ring_attributes: amt$ring_attributes,
      skip_integer_p: ^integer,
      skip_p: ^SEQ ( * ),
      size_p: ^0 .. 0ffff(16),
      string_length: integer;

*copy dup$abort_handler
?? NEWTITLE := 'clean_up', EJECT ??

{ PURPOSE:
{   This procedure is called from the abort handler to close the file.

    PROCEDURE [INLINE] clean_up;

      VAR
        ignore_status: ost$status;

      IF output_display_opened THEN
        clp$close_display (display_control, ignore_status);
      IFEND;

    PROCEND clean_up;

?? OLDTITLE, EJECT ??

    status.normal := TRUE;
    clp$evaluate_parameters (parameter_list, #SEQ (pdt), NIL, ^pvt, status);
    IF NOT status.normal THEN
      RETURN;  {---->
    IFEND;

    IF duv$dump_environment_p = NIL THEN
      osp$set_status_abnormal (duc$dump_analyzer_id, due$no_restart_file, '', status);
      RETURN;  {---->
    IFEND;

    output_display_opened := FALSE;
    osp$establish_block_exit_hndlr (^abort_handler);

   /display_opened/
    BEGIN

      { Prepare the output display file.

      IF pvt [p$output].specified THEN
        ring_attributes.r1 := #RING (^ring_attributes);
        ring_attributes.r2 := #RING (^ring_attributes);
        ring_attributes.r3 := #RING (^ring_attributes);
        clp$open_display_reference (pvt [p$output].value^.file_value^, ^dup$new_page_procedure, fsc$list,
              ring_attributes, display_control, status);
        IF NOT status.normal THEN
          EXIT /display_opened/;  {---->
        IFEND;
        output_display_opened := TRUE;
      ELSE
        display_control := duv$execution_environment.output_file.display_control;
        display_control.line_number := display_control.page_length + 1;
      IFEND;

      duv$title_data.build_title := TRUE;
      duv$title_data.command_name := pvt [p$title].value^.string_value^;

      restart_file_seq_p := duv$execution_environment.data_file_p^.segment_pointer.sequence_pointer;
      dup$retrieve_cip_program ('2AP ', cip_program_available, cip_program_cell_p);
      IF NOT cip_program_available THEN
        clp$put_display (display_control, ' ERROR - Cannot retrieve the 2AP CIP program.', clc$trim,
              ignore_status);
        EXIT /display_opened/;  {---->
      IFEND;
      RESET restart_file_seq_p TO cip_program_cell_p;
      NEXT skip_integer_p IN restart_file_seq_p;
      IF skip_integer_p = NIL THEN
        osp$set_status_abnormal (duc$dump_analyzer_id, due$nil_pointer, '', status);
        EXIT /display_opened/;  {---->
      IFEND;
      NEXT size_p IN restart_file_seq_p;
      IF size_p = NIL THEN
        osp$set_status_abnormal (duc$dump_analyzer_id, due$nil_pointer, '', status);
        EXIT /display_opened/;  {---->
      IFEND;
      level_address_size := (size_p^ * 2) + 8 - 12;
      RESET restart_file_seq_p TO cip_program_cell_p;
      NEXT skip_p: [[REP level_address_size OF cell]] IN restart_file_seq_p;
      IF skip_p = NIL THEN
        osp$set_status_abnormal (duc$dump_analyzer_id, due$nil_pointer, '', status);
        EXIT /display_opened/;  {---->
      IFEND;

      char_index := 1;
      FOR index := 1 TO 6 DO
        NEXT display_code_p IN restart_file_seq_p;
        IF display_code_p = NIL THEN
          osp$set_status_abnormal (duc$dump_analyzer_id, due$nil_pointer, '', status);
          EXIT /display_opened/;  {---->
        IFEND;
        display_code [char_index] := display_code_p^.char_1;
        char_index := char_index + 1;
        display_code [char_index] := display_code_p^.char_2;
        char_index := char_index + 1;
      FOREND;

      FOR index := 1 TO 12 DO
        IF (display_code [index] >= 1) AND (display_code [index] <= 26) THEN
          ascii_code.number [index] := display_code [index] + 64;
        ELSEIF (display_code [index] >= 27) AND (display_code [index] <= 36) THEN
          ascii_code.number [index] := display_code [index] + 21;
        ELSE
          ascii_code.number [index] := 32;
        IFEND;
      FOREND;

      clp$put_display (display_control, '  CTI/CIP Levels in Central Memory:', clc$trim, ignore_status);
      STRINGREP (display_string, string_length, '    CTI Internal Level = ', ascii_code.data_1);
      clp$put_display (display_control, display_string (1, string_length), clc$trim, ignore_status);
      STRINGREP (display_string, string_length, '    CIP Release  Level = ', ascii_code.data_2);
      clp$put_display (display_control, display_string (1, string_length), clc$trim, ignore_status);

    END /display_opened/;

    IF output_display_opened THEN
      clp$close_display (display_control, ignore_status);
    IFEND;
    osp$disestablish_cond_handler;

  PROCEND dup$display_cti_level_command;
MODEND dum$display_cti_level_command;
