
PROC dum$display_entry_status_trace, display_entry_status_trace, disest (output, o: file = $output)

  crev stat status
  crev id (string 25) d=0..11
  id(00) = 'FREE                    '
  id(01) = 'TERMINATING             '
  id(02) = 'NON_SWAPPABLE           '
  id(03) = 'IN MEMORY               '
  id(04) = 'SWAPIN_IN_PROGRESS      '
  id(05) = 'SWAPPED                 '
  id(06) = 'OPERATOR_FORCE_OUT      '
  id(07) = 'SYSTEM_FORCE_OUT        '
  id(08) = 'JOB_DAMAGED             '
  id(09) = 'READY_TASK              '
  id(10) = 'SWAPIN_CANDIDATE        '
  crev in integer d=0..30 v=0
  crev out integer d=0..30 v=0
  oo = $string($value(output)) // '.$eoi'
  b = $sa(jmv$ijl_entry_status_statistics)
  FOR f = 0 TO 10 DO
    FOR t = 0 TO 10 DO
      c = $mem(b+f*11*4+t*4 4)
      IF c > 0 THEN
        in(t) = in(t)+c
        out(f) = out(f)+c
        putl ' '//id(f)//'--> '//id(t)//'  '//$strrep(c) o=$fname(oo)
      IFEND
    FOREND
  FOREND
  putl ' ' o=$fname(oo)
  putl ' ' o=$fname(oo)
  FOR i = 0 TO 10 DO
    if (in(i)>0) OR (out(i)>0) then
      ic = '          '//$strrep(in(i))
      ic = $substr(ic $strlen(ic)-7 8)
      oc = '          '//$strrep(out(i))
      oc = $substr(oc $strlen(oc)-7 8)
      if in(i)=out(i) then
        dif = '.'
      else
        dif = ', difference = '//$strrep(in(i)-out(i))
      ifend
      putl ' '//id(i)//', in= '//ic//',   out = '//oc//dif o=$fname(oo)
    ifend
  FOREND

PROCEND dum$display_entry_status_trace
